configure.ac 37.2 KB
Newer Older
1
dnl == autoconf source for the Glasgow FP tools ==
2
dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
sof's avatar
sof committed
3
dnl  (or some such) to see the outline of this file)
4 5
dnl
#
6
# (c) The University of Glasgow 1994-2012
7
#
8
# Configure script template for GHC
9
#
10
# Process with 'autoreconf' to get a working configure script.
11
#
sof's avatar
sof committed
12 13 14 15
# For the generated configure script, do "./configure --help" to
# see what flags are available. (Better yet, read the documentation!)
#

16
AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17

18
# Set this to YES for a released version, otherwise NO
19
: ${RELEASE=NO}
20

21
# The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22
# above.  If this is not a released version, then we will append the
23
# date to the version number (e.g. 7.4.20111220).  The date is
24
# constructed by finding the date of the most recent patch in the
25
# git repository.  If this is a source distribution (not a git
26 27 28
# checkout), then we ship a file 'VERSION' containing the full version
# when the source distribution was created.

29
if test ! -f mk/config.h.in; then
30
   echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31 32 33
   exit 1
fi

34 35
AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])

36
dnl ----------------------------------------------------------
37
dnl ** Find unixy sort and find commands,
38 39 40 41
dnl ** which are needed by FP_SETUP_PROJECT_VERSION

dnl ** Find find command (for Win32's benefit)
FP_PROG_FIND
42
FP_PROG_SORT
43 44

dnl ----------------------------------------------------------
45 46 47 48
FP_SETUP_PROJECT_VERSION

# Hmmm, we fix the RPM release number to 1 here... Is this convenient?
AC_SUBST([release], [1])
49

50
# First off, a distrib sanity check..
51
AC_CONFIG_SRCDIR([mk/config.mk.in])
52

Gabor Greif's avatar
Gabor Greif committed
53
dnl * We require autoconf version 2.60
54 55
dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
Gabor Greif's avatar
Gabor Greif committed
56 57 58 59
dnl Using autoconf 2.59 started to give nonsense like this
dnl  #define SIZEOF_CHAR 0
dnl recently.
AC_PREREQ([2.60])
60

61 62 63
# -------------------------------------------------------------------------
# Prepare to generate the following header files
#
64 65
#
AC_CONFIG_HEADER(mk/config.h)
66

sof's avatar
sof committed
67
# No, semi-sadly, we don't do `--srcdir'...
68
if test x"$srcdir" != 'x.' ; then
69
    echo "This configuration does not support the \`--srcdir' option.."
70 71 72
    exit 1
fi

sof's avatar
sof committed
73 74 75 76 77 78 79 80 81 82
dnl --------------------------------------------------------------
dnl * Project specific configuration options
dnl --------------------------------------------------------------
dnl What follows is a bunch of options that can either be configured
dnl through command line options to the configure script or by
dnl supplying defns in the build tree's mk/build.mk. Having the option to
dnl use either is considered a Feature.

dnl ** What command to use to compile compiler sources ?
dnl --------------------------------------------------------------
83

84
AC_ARG_WITH([ghc],
85
[AC_HELP_STRING([--with-ghc=ARG],
86 87 88 89
  [Use ARG as the path to GHC  [default=autodetect]])],
  [WithGhc="$withval"],
  [if test "$GHC" = ""; then
    AC_PATH_PROG([GHC], [ghc])
90
  fi
91
  WithGhc="$GHC"])
92

93
dnl ** Tell the make system which OS we are using
94
dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 96
AC_SUBST(OSTYPE)

Ian Lynagh's avatar
Ian Lynagh committed
97 98 99 100 101 102 103
AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
[AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
                [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
        EnableBootstrapWithDevelSnaphost=YES,
        EnableBootstrapWithDevelSnaphost=NO
)

104 105 106 107 108 109
AC_ARG_ENABLE(tarballs-autodownload,
[AC_HELP_STRING([--enable-tarballs-autodownload],
                [Automatically download Windows distribution binaries if needed.])],
        TarballsAutodownload=YES,
        TarballsAutodownload=NO
)
110 111
if test "$WithGhc" != ""; then
  FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
Ian Lynagh's avatar
Ian Lynagh committed
112

113 114
  if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
     AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
Ian Lynagh's avatar
Ian Lynagh committed
115 116
  fi

117 118 119 120
  AC_SUBST(GhcVersion)dnl
  AC_SUBST(GhcMajVersion)dnl
  AC_SUBST(GhcMinVersion)dnl
  AC_SUBST(GhcPatchLevel)dnl
121 122
  GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
  GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123

124
  BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
Simon Marlow's avatar
Simon Marlow committed
125 126 127
  dnl ToDo, once "ld command" is reliably available.
  dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
  dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128 129 130
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
  BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 132
fi

133
dnl ** Must have GHC to build GHC
ian@well-typed.com's avatar
ian@well-typed.com committed
134 135 136 137
if test "$WithGhc" = ""
then
    AC_MSG_ERROR([GHC is required.])
fi
138 139
FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
    [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
Simon Marlow's avatar
Simon Marlow committed
140

ian@well-typed.com's avatar
ian@well-typed.com committed
141 142 143 144
if test `expr $GhcMinVersion % 2` = "1"
then
    if test "$EnableBootstrapWithDevelSnaphost" = "NO"
    then
Simon Marlow's avatar
Simon Marlow committed
145 146 147 148 149
        AC_MSG_ERROR([
     $WithGhc is a development snapshot of GHC, version $GhcVersion.
     Bootstrapping using this version of GHC is not supported, and may not
     work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
     or --with-ghc to specify a different GHC to use.])
ian@well-typed.com's avatar
ian@well-typed.com committed
150 151
    fi
fi
152

153
GHC_PACKAGE_DB_FLAG=package-db
ian@well-typed.com's avatar
ian@well-typed.com committed
154
AC_SUBST(GHC_PACKAGE_DB_FLAG)
Simon Marlow's avatar
Simon Marlow committed
155

156 157 158 159 160
FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
                    SUPPORTS_THIS_UNIT_ID=NO,
                    SUPPORTS_THIS_UNIT_ID=YES)
AC_SUBST(SUPPORTS_THIS_UNIT_ID)

161 162 163
# GHC is passed to Cabal, so we need a native path
if test "${WithGhc}" != ""
then
164
    ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
165

166
    if test "$ghc_host_os" = "mingw32"
167 168 169 170 171 172
    then
        if test "${OSTYPE}" = "msys"
        then
            WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
        else
            # Canonicalise to <drive>:/path/to/ghc
173
            WithGhc=`cygpath -m "${WithGhc}"`
174 175 176 177 178 179
        fi
        echo "GHC path canonicalised to: ${WithGhc}"
    fi
fi
AC_SUBST([WithGhc])

180 181 182
dnl ** Without optimization some INLINE trickery fails for GHCi
SRC_CC_OPTS="-O"

183 184 185
dnl--------------------------------------------------------------------
dnl * Choose host(/target/build) platform
dnl--------------------------------------------------------------------
186 187
dnl If we aren't explicitly told what values to use with configure flags,
dnl we ask the bootstrapping compiler what platform it is for
188

189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204
if test "${WithGhc}" != ""
then
        bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        if test "$bootstrap_host" != "$bootstrap_target"
        then
                echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
        fi
fi

# We have to run these unconditionally, but we may discard their
# results in the following code
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

205
FPTOOLS_SET_PLATFORM_VARS
206

207 208
# Verify that the installed (bootstrap) GHC is capable of generating
# code for the requested build platform.
ian@well-typed.com's avatar
ian@well-typed.com committed
209 210 211 212 213 214 215
if test "$BuildPlatform" != "$bootstrap_target"
then
    echo "This GHC (${WithGhc}) does not generate code for the build platform"
    echo "   GHC target platform    : $bootstrap_target"
    echo "   Desired build platform : $BuildPlatform"
    exit 1
fi
216

217 218
# Testing if we shall enable shared libs support on Solaris.
# Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
219

220
SOLARIS_BROKEN_SHLD=NO
221

222 223 224 225 226
case $host in
     i386-*-solaris2)
     # here we go with the test
     MINOR=`uname -r|cut -d '.' -f 2-`
     if test "$MINOR" -lt "11"; then
227
         SOLARIS_BROKEN_SHLD=YES
228 229 230
     fi
     ;;
esac
231

232 233
AC_SUBST(SOLARIS_BROKEN_SHLD)

234 235 236
dnl ** Do an unregisterised build?
dnl --------------------------------------------------------------
case "$HostArch" in
237
    i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256
        UnregisterisedDefault=NO
        ;;
    *)
        UnregisterisedDefault=YES
        ;;
esac
AC_ARG_ENABLE(unregisterised,
[AC_HELP_STRING([--enable-unregisterised],
[Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
[ if test x"$enableval" = x"yes"; then
        Unregisterised=YES
  else
        Unregisterised=NO
  fi
],
[Unregisterised="$UnregisterisedDefault"]
)
AC_SUBST(Unregisterised)

257 258 259 260 261 262 263 264 265
AC_ARG_WITH(hc,
[AC_HELP_STRING([--with-hc=ARG],
        [Use ARG as the path to the compiler for compiling ordinary
         Haskell code  (default= value of --with-ghc)])],
[WithHc="$withval"],
[WithHc=$WithGhc]
)
AC_SUBST(WithHc)

266 267 268
# Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
FP_FIND_ROOT

269
fail() {
270 271 272 273 274
    echo >&2
    echo "$1" >&2
    exit 1
}

275

276 277
if test "$HostOS" = "mingw32"
then
278 279 280 281 282 283 284 285 286 287 288 289 290 291 292
    # Find the mingw-w64 7z file to extract.
    # NB. If you update the tarballs to a new version of gcc, don't
    # forget to tweak the paths in driver/gcc/gcc.c.
    if test "$HostArch" = "i386"
    then
        mingw_arch="i686"
        tarball_dest_dir="mingw-w64/x86"
        tarball_mingw_dir="mingw32"
    else
        mingw_arch="x86_64"
        tarball_dest_dir="mingw-w64/x86_64"
        tarball_mingw_dir="mingw64"
    fi
fi

293 294 295 296
set_up_tarballs() {
    AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
    local action
    if test "$TarballsAutodownload" = "NO"
297
    then
298
        action="verify"
299
    else
300
        action="download"
301
    fi
302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326
    mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
    case $? in
        0)
           rm missing-win32-tarballs
           ;;
        2)
           echo
           echo "Error:"
           echo "Needed msys2 tarballs are missing. You have a few options to get them,"
           echo
           echo "  * run configure with the --enable-tarballs-autodownload option"
           echo
           echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
           echo
           echo "  * manually download the files listed in ./missing-win32-tarballs and place"
           echo "    them in the ghc-tarballs directory."
           echo
           exit 1
           ;;
        *)
           echo
           echo "Error fetching msys2 tarballs; see errors above."
           exit 1
           ;;
    esac
327 328 329 330 331 332

    # Extract all the tarballs in one go
    if ! test -d inplace/mingw
    then
        AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
        rm -rf inplace/mingw
333
        local base_dir="../ghc-tarballs/${tarball_dest_dir}"
334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359
        ( cd inplace &&
        find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
        rm ".MTREE" &&
        rm ".PKGINFO" &&
        cd .. ) || fail "Error: Could not extract Windows toolchains."

        mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
        touch inplace/mingw

        # NB. Now since the GCC is hardcoded to use /mingw32 we need to
        # make a wrapper around it to give it the proper paths
        mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
        PATH=`pwd`/inplace/mingw/bin:$PATH
        inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe

        AC_MSG_NOTICE([In-tree MingW-w64 tree created])
    fi
}

if test "$HostOS" = "mingw32"
then
    test -d inplace || mkdir inplace

    # NB. Download and extract the MingW-w64 distribution if required
    set_up_tarballs

360
    mingwbin="$hardtop/inplace/mingw/bin/"
361 362 363
    CC="${mingwbin}gcc.exe"
    LD="${mingwbin}ld.exe"
    NM="${mingwbin}nm.exe"
364
    RANLIB="${mingwbin}ranlib.exe"
365
    OBJDUMP="${mingwbin}objdump.exe"
Ian Lynagh's avatar
Ian Lynagh committed
366
    fp_prog_ar="${mingwbin}ar.exe"
367

368
    # NB. Download the perl binaries if required
369 370 371 372 373 374 375 376 377 378 379 380
    if ! test -d inplace/perl ||
         test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
    then
        AC_MSG_NOTICE([Making in-tree perl tree])
        rm -rf inplace/perl
        mkdir inplace/perl
        (
            cd inplace/perl &&
            tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
        )
        AC_MSG_NOTICE([In-tree perl tree created])
    fi
381 382
fi

Ian Lynagh's avatar
Ian Lynagh committed
383 384
FP_ICONV
FP_GMP
385
FP_CURSES
Ian Lynagh's avatar
Ian Lynagh committed
386

387
XCODE_VERSION()
Ian Lynagh's avatar
Ian Lynagh committed
388 389 390 391 392 393 394 395 396 397

SplitObjsBroken=NO
if test "$TargetOS_CPP" = "darwin"
then
    # Split objects is broken (#4013) with XCode < 3.2
    if test "$XCodeVersion1" -lt 3
    then
        SplitObjsBroken=YES
    else
        if test "$XCodeVersion1" -eq 3
398
        then
Ian Lynagh's avatar
Ian Lynagh committed
399
            if test "$XCodeVersion2" -lt 2
400
            then
Ian Lynagh's avatar
Ian Lynagh committed
401
                SplitObjsBroken=YES
402
            fi
403
        fi
404 405 406 407
    fi
fi
AC_SUBST([SplitObjsBroken])

408 409 410 411
dnl ** Building a cross compiler?
dnl --------------------------------------------------------------
CrossCompiling=NO
# If 'host' and 'target' differ, then this means we are building a cross-compiler.
Simon Marlow's avatar
Simon Marlow committed
412
if test "$target" != "$host" ; then
413 414 415 416 417 418 419 420 421 422
    CrossCompiling=YES
    cross_compiling=yes   # This tells configure that it can accept just 'target',
                          # otherwise you get
                          #   configure: error: cannot run C compiled programs.
                          #   If you meant to cross compile, use `--host'.
fi
if test "$build" != "$host" ; then
   AC_MSG_ERROR([
You've selected:

Simon Marlow's avatar
Simon Marlow committed
423 424 425
  BUILD:  $build   (the architecture we're building on)
  HOST:   $host    (the architecture the compiler we're building will execute on)
  TARGET: $target  (the architecture the compiler we're building will produce code for)
426

Simon Marlow's avatar
Simon Marlow committed
427 428 429 430
BUILD must equal HOST; that is, we do not support building GHC itself
with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
1 will be a cross-compiler, and stage 2 will be the cross-compiled
GHC.
431 432
])
fi
433 434
if test "$CrossCompiling" = "YES"
then
435 436 437 438 439
  CrossCompilePrefix="${target}-"
else
  CrossCompilePrefix=""
fi
TargetPlatformFull="${target}"
Simon Marlow's avatar
Simon Marlow committed
440
AC_SUBST(CrossCompiling)
441 442 443
AC_SUBST(CrossCompilePrefix)
AC_SUBST(TargetPlatformFull)

444 445
dnl ** Which gcc to use?
dnl --------------------------------------------------------------
446 447 448
FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
CC="$WhatGccIsCalled"
export CC
449

450 451 452 453 454
# If --with-gcc was used, and we're not cross-compiling, then it also
# applies to the stage0 compiler.
MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])

455 456 457
dnl make extensions visible to allow feature-tests to detect them lateron
AC_USE_SYSTEM_EXTENSIONS

thomie's avatar
thomie committed
458 459 460
dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
AC_PROG_CPP

461 462
# --with-hs-cpp/--with-hs-cpp-flags
FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
thomie's avatar
thomie committed
463 464
AC_SUBST([HaskellCPPCmd])
AC_SUBST([HaskellCPPArgs])
465

466 467
dnl ** Which ld to use?
dnl --------------------------------------------------------------
468
FIND_LD([LdCmd])
469 470 471 472
AC_SUBST([LdCmd])

dnl ** Which nm to use?
dnl --------------------------------------------------------------
473
FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
474 475 476
NmCmd="$NM"
AC_SUBST([NmCmd])

477 478 479 480 481 482
dnl ** Which objdump to use?
dnl --------------------------------------------------------------
FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
ObjdumpCmd="$OBJDUMP"
AC_SUBST([ObjdumpCmd])

483 484 485 486 487 488 489 490 491 492 493 494 495 496
dnl ** Which ar to use?
dnl --------------------------------------------------------------
FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
ArCmd="$AR"
fp_prog_ar="$AR"
AC_SUBST([ArCmd])

dnl ** Which ranlib to use?
dnl --------------------------------------------------------------
FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
RanlibCmd="$RANLIB"
RANLIB="$RanlibCmd"


497 498 499 500 501 502 503 504 505 506
# Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
case $HostOS_CPP in
cygwin32|mingw32)
    dnl ** Which objdump to use?
    dnl --------------------------------------------------------------
    FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
    ObjdumpCmd="$OBJDUMP"
    AC_SUBST([ObjdumpCmd])
    ;;
esac
507

508 509 510 511
# Here is where we re-target which specific version of the LLVM
# tools we are looking for. In the past, GHC supported a number of
# versions of LLVM simultaneously, but that stopped working around
# 3.5/3.6 release of LLVM.
512
LlvmVersion=3.7
513
AC_SUBST([LlvmVersion])
514 515
sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
516

517 518
dnl ** Which LLVM llc to use?
dnl --------------------------------------------------------------
519
FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
520 521 522 523 524
LlcCmd="$LLC"
AC_SUBST([LlcCmd])

dnl ** Which LLVM opt to use?
dnl --------------------------------------------------------------
525
FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
526 527 528
OptCmd="$OPT"
AC_SUBST([OptCmd])

sof's avatar
sof committed
529 530 531 532 533 534 535 536
dnl --------------------------------------------------------------
dnl End of configure script option section
dnl --------------------------------------------------------------


dnl --------------------------------------------------------------
dnl * General configuration checks
dnl --------------------------------------------------------------
sof's avatar
sof committed
537

538 539 540 541 542 543 544 545 546
dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
dnl Unfortunately we don't know whether the user is going to request a
dnl build with the LLVM backend as this is only given in build.mk.
dnl
dnl Instead, we try to do as much work as possible here, checking
dnl whether -fllvm is the stage 0 compiler's default. If so we
dnl fail. If not, we check whether -fllvm is affected explicitly and
dnl if so set a flag. The build system will later check this flag
dnl after the desired build flags are known.
547 548 549 550 551 552 553 554 555 556 557 558

dnl This problem is further complicated by the fact that the llvm
dnl version used by the bootstrap compiler may be different from the
dnl version we arre trying to compile GHC against. Therefore, we need
dnl to find the boostrap compiler's `settings` file then check to see
dnl if the `opt` and `llc` command strings are non-empty and if these
dnl programs exist. Only if they exist to we test for bug #9439.

FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")

if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
559 560 561 562 563
then
    AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
    echo "main = putStrLn \"%function\"" > conftestghc.hs

    # Check whether LLVM backend is default for this platform
564
    "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
565
    res=`./conftestghc`
tuncer's avatar
tuncer committed
566
    if test "x$res" = "x%object"
567 568 569 570 571 572 573 574 575 576 577 578 579 580
    then
        AC_MSG_RESULT(yes)
        echo "Buggy bootstrap compiler"
        echo ""
        echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
        echo "and therefore will miscompile the LLVM backend if -fllvm is"
        echo "used."
        echo
        echo "Please use another bootstrap compiler"
        exit 1
    fi

    # -fllvm is not the default, but set a flag so the Makefile can check
    # -for it in the build flags later on
581
    "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
tuncer's avatar
tuncer committed
582
    if test $? = 0
583 584
    then
        res=`./conftestghc`
tuncer's avatar
tuncer committed
585
        if test "x$res" = "x%object"
586 587 588
        then
            AC_MSG_RESULT(yes)
            GHC_LLVM_AFFECTED_BY_9439=1
tuncer's avatar
tuncer committed
589
        elif test "x$res" = "x%function"
590 591 592 593 594 595 596 597 598 599 600 601
        then
            AC_MSG_RESULT(no)
            GHC_LLVM_AFFECTED_BY_9439=0
        else
            AC_MSG_WARN(unexpected output $res)
        fi
    else
        AC_MSG_RESULT(failed to compile, assuming no)
    fi
fi
AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])

602 603 604
dnl ** Can the unix package be built?
dnl --------------------------------------------------------------

605 606 607
if test "$TargetOS" = "mingw32"
then
    GhcLibsWithUnix=NO
608
else
609
    GhcLibsWithUnix=YES
610 611 612
fi
AC_SUBST([GhcLibsWithUnix])

613 614
dnl ** does #! work?
AC_SYS_INTERPRETER()
sof's avatar
sof committed
615

Ian Lynagh's avatar
Ian Lynagh committed
616
dnl ** look for `perl'
rrt's avatar
rrt committed
617 618
case $HostOS_CPP in
cygwin32|mingw32)
Ian Lynagh's avatar
Ian Lynagh committed
619 620
    PerlCmd=$hardtop/inplace/perl/perl
    ;;
rrt's avatar
rrt committed
621
*)
Ian Lynagh's avatar
Ian Lynagh committed
622 623 624 625 626 627 628 629 630 631
    AC_PATH_PROG(PerlCmd,perl)
    if test -z "$PerlCmd"
    then
        echo "You must install perl before you can continue"
        echo "Perhaps it is already installed, but not in your PATH?"
        exit 1
    else
        FPTOOLS_CHECK_PERL_VERSION
    fi
    ;;
rrt's avatar
rrt committed
632
esac
sof's avatar
sof committed
633

rrt's avatar
rrt committed
634 635
dnl ** look for GCC and find out which version
dnl     Figure out which C compiler to use.  Gcc is preferred.
Gabor Greif's avatar
Gabor Greif committed
636
dnl     If gcc, make sure it's at least 3.0
rrt's avatar
rrt committed
637
dnl
638
FP_GCC_VERSION
639

640 641 642 643
dnl ** look to see if we have a C compiler using an llvm back end.
dnl
FP_CC_LLVM_BACKEND

644 645 646
FP_PROG_LD_IS_GNU
FP_PROG_LD_BUILD_ID
FP_PROG_LD_NO_COMPACT_UNWIND
647
FP_PROG_LD_FILELIST
648

649

650 651 652 653
FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
654
# Stage 3 won't be supported by cross-compilation
655

656
FP_GCC_EXTRA_FLAGS
rrt's avatar
rrt committed
657

658 659 660
AC_SUBST(CONF_CC_OPTS_STAGE0)
AC_SUBST(CONF_CC_OPTS_STAGE1)
AC_SUBST(CONF_CC_OPTS_STAGE2)
661 662 663 664 665 666
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
667 668 669
AC_SUBST(CONF_CPP_OPTS_STAGE0)
AC_SUBST(CONF_CPP_OPTS_STAGE1)
AC_SUBST(CONF_CPP_OPTS_STAGE2)
rrt's avatar
rrt committed
670

671 672 673 674 675
dnl ** Set up the variables for the platform in the settings file.
dnl May need to use gcc to find platform details.
dnl --------------------------------------------------------------
FPTOOLS_SET_HASKELL_PLATFORM_VARS

676
dnl ** figure out how to do context diffs
677
FP_PROG_CONTEXT_DIFF
sof's avatar
sof committed
678

679 680 681
dnl Let's make sure install-sh is executable here.  If we got it from
dnl a darcs repo, it might not be (see bug #978).
chmod +x install-sh
682 683
dnl ** figure out how to do a BSD-ish install
AC_PROG_INSTALL
sof's avatar
sof committed
684

sof's avatar
sof committed
685
dnl ** how to invoke `ar' and `ranlib'
686
FP_PROG_AR_SUPPORTS_ATFILE
687
FP_PROG_AR_NEEDS_RANLIB
sof's avatar
sof committed
688

689
dnl ** Check to see whether ln -s works
sof's avatar
sof committed
690 691
AC_PROG_LN_S

692
FP_SETTINGS
sof's avatar
sof committed
693 694

dnl ** Find the path to sed
Ian Lynagh's avatar
Ian Lynagh committed
695
AC_PATH_PROGS(SedCmd,gsed sed,sed)
sof's avatar
sof committed
696

sof's avatar
sof committed
697 698

dnl ** check for time command
sof's avatar
sof committed
699 700
AC_PATH_PROG(TimeCmd,time)

sof's avatar
sof committed
701 702
dnl ** check for tar
dnl   if GNU tar is named gtar, look for it first.
703
AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
sof's avatar
sof committed
704

Ian Lynagh's avatar
Ian Lynagh committed
705 706 707 708
dnl ** check for patch
dnl if GNU patch is named gpatch, look for it first
AC_PATH_PROGS(PatchCmd,gpatch patch, patch)

709 710 711 712
dnl ** check for dtrace (currently only implemented for Mac OS X)
HaveDtrace=NO
AC_PATH_PROG(DtraceCmd,dtrace)
if test -n "$DtraceCmd"; then
713
  if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
714 715 716 717 718
    HaveDtrace=YES
  fi
fi
AC_SUBST(HaveDtrace)

719
AC_PATH_PROG(HSCOLOUR,HsColour)
720
# HsColour is passed to Cabal, so we need a native path
721 722 723
if test "$HostOS"      = "mingw32" && \
   test "${OSTYPE}"   != "msys"    && \
   test "${HSCOLOUR}" != ""
724 725 726
then
    # Canonicalise to <drive>:/path/to/gcc
    HSCOLOUR=`cygpath -m ${HSCOLOUR}`
727
fi
728

729
dnl ** check for Sphinx toolchain
730 731
AC_PATH_PROG(SPHINXBUILD,sphinx-build)
AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
732 733
changequote(, )dnl
[if test -n "$SPHINXBUILD"; then
734
  fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
735 736 737
fi;
changequote([, ])dnl
])
738 739
FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
    [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
740 741 742

dnl ** check for xelatex
AC_PATH_PROG(XELATEX,xelatex)
743

reid's avatar
reid committed
744
dnl ** check for ghc-pkg command
745
FP_PROG_GHC_PKG
reid's avatar
reid committed
746

sof's avatar
sof committed
747
dnl ** check for installed happy binary + version
sof's avatar
sof committed
748
FPTOOLS_HAPPY
sof's avatar
sof committed
749

750 751 752
dnl ** check for installed alex binary + version
FPTOOLS_ALEX

sof's avatar
sof committed
753 754 755
dnl --------------------------------------------------
dnl ### program checking section ends here ###
dnl --------------------------------------------------
sof's avatar
sof committed
756

sof's avatar
sof committed
757 758 759
dnl --------------------------------------------------
dnl * Platform header file and syscall feature tests
dnl ### checking the state of the local header files and syscalls ###
sof's avatar
sof committed
760

761 762
dnl ** check for full ANSI header (.h) files
AC_HEADER_STDC
sof's avatar
sof committed
763

764 765 766 767
dnl ** Enable large file support.  NB. do this before testing the type of
dnl    off_t, because it will affect the result of that test.
AC_SYS_LARGEFILE

768
dnl ** check for specific header (.h) files that we are interested in
769
AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
770 771 772 773 774 775 776

dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
AC_CHECK_HEADERS([sys/cpuset.h], [], [],
[[#if HAVE_SYS_PARAM_H
# include <sys/param.h>
#endif
]])
777

778 779
dnl ** check if it is safe to include both <time.h> and <sys/time.h>
AC_HEADER_TIME
sof's avatar
sof committed
780

781
dnl ** do we have long longs?
782
AC_CHECK_TYPES([long long])
783

reid's avatar
reid committed
784
dnl ** what are the sizes of various types
785
AC_CHECK_SIZEOF(char,               1)
786 787
AC_CHECK_SIZEOF(double,             8)
AC_CHECK_SIZEOF(float,              4)
788 789
AC_CHECK_SIZEOF(int,                4)
AC_CHECK_SIZEOF(long,               4)
790
if test "$ac_cv_type_long_long" = yes; then
791
AC_CHECK_SIZEOF(long long,          8)
792 793 794 795 796
fi
AC_CHECK_SIZEOF(short,              2)
AC_CHECK_SIZEOF(unsigned char,      1)
AC_CHECK_SIZEOF(unsigned int,       4)
AC_CHECK_SIZEOF(unsigned long,      4)
797
if test "$ac_cv_type_long_long" = yes; then
798 799
AC_CHECK_SIZEOF(unsigned long long, 8)
fi
800
AC_CHECK_SIZEOF(unsigned short,     2)
801
AC_CHECK_SIZEOF(void *,             4)
reid's avatar
reid committed
802

803 804 805 806
dnl for use in settings.in
WordSize=$ac_cv_sizeof_void_p
AC_SUBST(WordSize)

reid's avatar
reid committed
807
dnl ** what are alignment constraints on various types
808 809 810 811 812 813 814
FP_CHECK_ALIGNMENT(char)
FP_CHECK_ALIGNMENT(double)
FP_CHECK_ALIGNMENT(float)
FP_CHECK_ALIGNMENT(int)
FP_CHECK_ALIGNMENT(long)
if test "$ac_cv_type_long_long" = yes; then
FP_CHECK_ALIGNMENT(long long)
815
fi
816 817 818 819 820 821
FP_CHECK_ALIGNMENT(short)
FP_CHECK_ALIGNMENT(unsigned char)
FP_CHECK_ALIGNMENT(unsigned int)
FP_CHECK_ALIGNMENT(unsigned long)
if test "$ac_cv_type_long_long" = yes; then
FP_CHECK_ALIGNMENT(unsigned long long)
822
fi
823 824
FP_CHECK_ALIGNMENT(unsigned short)
FP_CHECK_ALIGNMENT(void *)
reid's avatar
reid committed
825

826 827
FP_CHECK_FUNC([WinExec],
  [@%:@include <windows.h>], [WinExec("",0)])
reid's avatar
reid committed
828

829 830
FP_CHECK_FUNC([GetModuleFileName],
  [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
reid's avatar
reid committed
831 832

dnl ** check for more functions
833
dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
834
AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
835

rl@cse.unsw.edu.au's avatar
rl@cse.unsw.edu.au committed
836 837 838 839 840 841 842
dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
dnl ** _POSIX_C_SOURCE is defined
AC_CHECK_DECLS([ctime_r], , ,
[#define _POSIX_SOURCE 1
#define _POSIX_C_SOURCE 199506L
#include <time.h>])

843 844 845 846 847
dnl ** check for mingwex library
AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
AC_SUBST(HaveLibMingwEx)

if test $HaveLibMingwEx = YES ; then
848
  AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
849 850
fi

sebc's avatar
sebc committed
851
dnl ** check for math library
852 853 854
dnl    Keep that check as early as possible.
dnl    as we need to know whether we need libm
dnl    for math functions or not
855
dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
856 857 858 859 860
AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
if test $HaveLibM = YES
then
  AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
fi
sebc's avatar
sebc committed
861

862
FP_BFD_SUPPORT
863

reid's avatar
reid committed
864 865 866 867
dnl ################################################################
dnl Check for libraries
dnl ################################################################

868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915
# system libffi

AC_ARG_WITH([system-libffi],
[AC_HELP_STRING([--with-system-libffi],
  [Use system provided libffi for RTS [default=no]])
])

AS_IF([test "x$with_system_libffi" = "xyes"],
  [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
)


AC_SUBST(UseSystemLibFFI)

AC_ARG_WITH([ffi-includes],
[AC_HELP_STRING([--with-ffi-includes=ARG],
  [Find includes for libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
 else
    FFIIncludeDir="$withval"
    LIBFFI_CFLAGS="-I$withval"
 fi
])

AC_SUBST(FFIIncludeDir)

AC_ARG_WITH([ffi-libraries],
[AC_HELP_STRING([--with-ffi-libraries=ARG],
  [Find libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
 else
    FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
 fi
])

AC_SUBST(FFILibDir)

AS_IF([test "$UseSystemLibFFI" = "YES"], [
 CFLAGS2="$CFLAGS"
 CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
 LDFLAGS2="$LDFLAGS"
 LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
916 917 918 919 920 921 922 923 924
 if test "$HostOS" = "openbsd";
 then
   # OpenBSD's libffi is not directly linked to the libpthread but
   # still requires pthread functionality. This means that any client
   # binary which links with libffi also needs to link with
   # libpthread. If it does not, then linking fails with unresolved
   # symbols.
   LDFLAGS="$LDFLAGS -lpthread"
 fi
925 926 927 928 929 930 931 932
 AC_CHECK_LIB(ffi, ffi_call,
  [AC_CHECK_HEADERS([ffi.h], [break], [])
   AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
  [AC_MSG_ERROR([Cannot find system libffi])])
 CFLAGS="$CFLAGS2"
 LDFLAGS="$LDFLAGS2"
])

ross's avatar
ross committed
933
dnl ** check whether we need -ldl to get dlopen()
934
AC_CHECK_LIB(dl, dlopen)
935

936
dnl --------------------------------------------------
sof's avatar
sof committed
937 938 939
dnl * Miscellaneous feature tests
dnl --------------------------------------------------

sof's avatar
sof committed
940
dnl ** can we get alloca?
941
AC_FUNC_ALLOCA
sof's avatar
sof committed
942

943
dnl ** working vfork?
944
AC_FUNC_FORK
945

946 947
dnl ** determine whether or not const works
AC_C_CONST
sof's avatar
sof committed
948

949 950
dnl ** are we big endian?
AC_C_BIGENDIAN
951
FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
sof's avatar
sof committed
952

953
dnl ** check for leading underscores in symbol names
954
FP_LEADING_UNDERSCORE
955

956 957
FP_VISIBILITY_HIDDEN

958 959
dnl ** check for librt
AC_CHECK_LIB(rt, clock_gettime)
960
AC_CHECK_FUNCS(clock_gettime timer_settime)
961
FP_CHECK_TIMER_CREATE
962

963
dnl ** check for Apple's "interesting" long double compatibility scheme
964 965
AC_MSG_CHECKING(for printf\$LDBLStub)
AC_TRY_LINK_FUNC(printf\$LDBLStub,
966 967 968 969 970 971 972 973 974 975 976
    [
        AC_MSG_RESULT(yes)
        AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
            [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
    ],
    [
        AC_MSG_RESULT(no)
        AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
            [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
    ])

977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992
dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
dnl    a different single-argument version.
AC_CHECK_LIB(pthread, pthread_setname_np)
AC_MSG_CHECKING(for pthread_setname_np)
AC_TRY_LINK(
[
#define _GNU_SOURCE
#include <pthread.h>
],
[pthread_setname_np(pthread_self(), "name");],
    AC_MSG_RESULT(yes)
    AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
      [Define to 1 if you have the glibc version of pthread_setname_np]),
    AC_MSG_RESULT(no)
)

993 994 995 996
dnl ** check for eventfd which is needed by the I/O manager
AC_CHECK_HEADERS([sys/eventfd.h])
AC_CHECK_FUNCS([eventfd])

997 998 999 1000 1001 1002
dnl ** Check for __thread support in the compiler
AC_MSG_CHECKING(for __thread support)
AC_COMPILE_IFELSE(
  [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
  [
   AC_MSG_RESULT(yes)
1003
   AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1004 1005 1006
  ],
  [
   AC_MSG_RESULT(no)
1007
   AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1008 1009 1010
  ])


1011 1012
AC_CHECK_FUNCS(__mingw_vfprintf)

1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025
dnl large address space support (see includes/rts/storage/MBlock.h)
dnl
dnl Darwin has vm_allocate/vm_protect
dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
dnl (They also have MADV_DONTNEED, but it means something else!)
dnl
dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
dnl it counts page-table space as committed memory, and so quickly
dnl runs out of paging file when we have multiple processes reserving
dnl 1TB of address space, we get the following error:
dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
dnl
1026 1027 1028 1029 1030 1031 1032 1033

AC_ARG_ENABLE(large-address-space,
    [AC_HELP_STRING([--enable-large-address-space],
        [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
    EnableLargeAddressSpace=$enableval,
    EnableLargeAddressSpace=yes
)

1034 1035
use_large_address_space=no
if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1036 1037 1038
    if test "x$EnableLargeAddressSpace" = "xyes" ; then
        if test "$ghc_host_os" = "darwin" ; then
            use_large_address_space=yes
1039 1040 1041 1042 1043
	elif test "$ghc_host_os" = "openbsd" ; then
	    # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
	    # The flag MAP_NORESERVE is supported for source compatibility reasons,
	    # but is completely ignored by OS mmap
            use_large_address_space=no
1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058
        else
            AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
                [
                #include <unistd.h>
                #include <sys/types.h>
                #include <sys/mman.h>
                #include <fcntl.h>
            ])
            if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
                test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
                test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
                    use_large_address_space=yes
            fi
        fi
    fi
1059 1060 1061 1062 1063
fi
if test "$use_large_address_space" = "yes" ; then
   AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
fi

1064 1065 1066
AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
AC_SUBST(HaveLibdw)

1067 1068 1069 1070 1071 1072 1073 1074
if test -n "$SPHINXBUILD"; then
    BUILD_MAN=YES
    BUILD_SPHINX_HTML=YES
    if test -n "$XELATEX"; then
        BUILD_SPHINX_PDF=YES
    else
        BUILD_SPHINX_PDF=NO
    fi
1075
else
1076 1077 1078
    BUILD_MAN=NO
    BUILD_SPHINX_HTML=NO
    BUILD_SPHINX_PDF=NO
1079
fi
1080 1081 1082
AC_SUBST(BUILD_MAN)
AC_SUBST(BUILD_SPHINX_HTML)
AC_SUBST(BUILD_SPHINX_PDF)
1083

1084
LIBRARY_VERSION(base)
1085
LIBRARY_VERSION(Cabal, Cabal/Cabal)
1086
LIBRARY_VERSION(ghc-prim)
1087 1088
LIBRARY_ghc_VERSION="$ProjectVersion"
AC_SUBST(LIBRARY_ghc_VERSION)
1089