Parser.y.pp 63.8 KB
Newer Older
1 2 3 4 5 6 7 8 9 10
--								-*-haskell-*-
-- ---------------------------------------------------------------------------
-- (c) The University of Glasgow 1997-2003
---
-- The GHC grammar.
--
-- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
-- ---------------------------------------------------------------------------

{
11
module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
12
		parseHeader ) where
13 14 15 16 17 18

#define INCLUDE #include 
INCLUDE "HsVersions.h"

import HsSyn
import RdrHsSyn
19
import HscTypes		( IsBootInterface, DeprecTxt )
20 21 22 23 24
import Lexer
import RdrName
import TysWiredIn	( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
			  listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
import Type		( funTyCon )
25
import ForeignCall	( Safety(..), CExportSpec(..), CLabelString,
26 27
			  CCallConv(..), CCallTarget(..), defaultCCallConv
			)
28
import OccName		( varName, dataName, tcClsName, tvName )
29 30
import DataCon		( DataCon, dataConName )
import SrcLoc		( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
31 32
			  SrcSpan, combineLocs, srcLocFile, 
			  mkSrcLoc, mkSrcSpan )
33
import Module
34
import StaticFlags	( opt_SccProfilingOn )
Simon Marlow's avatar
Simon Marlow committed
35
import Type		( Kind, mkArrowKind, liftedTypeKind, unliftedTypeKind )
36
import BasicTypes	( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
37
			  Activation(..), defaultInlineSpec )
38
import OrdList
39 40 41
import HaddockParse
import {-# SOURCE #-} HaddockLex hiding ( Token )
import HaddockUtils
42 43 44 45

import FastString
import Maybes		( orElse )
import Outputable
46

Simon Marlow's avatar
Simon Marlow committed
47 48
import Control.Monad    ( when )
import GHC.Exts
49 50
import Data.Char
import Control.Monad    ( mplus )
51 52 53
}

{-
54 55 56 57 58 59 60 61 62 63 64
-----------------------------------------------------------------------------
26 July 2006

Conflicts: 37 shift/reduce
           1 reduce/reduce

The reduce/reduce conflict is weird.  It's between tyconsym and consym, and I
would think the two should never occur in the same context.

  -=chak

65
-----------------------------------------------------------------------------
66
Conflicts: 38 shift/reduce (1.25)
67

68
10 for abiguity in 'if x then y else z + 1'		[State 178]
69 70 71
	(shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
	10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM

72
1 for ambiguity in 'if x then y else z :: T'		[State 178]
73 74
	(shift parses as 'if x then y else (z :: T)', as per longest-parse rule)

75
4 for ambiguity in 'if x then y else z -< e'		[State 178]
ross's avatar
ross committed
76
	(shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
77 78 79 80 81 82 83 84 85 86
	There are four such operators: -<, >-, -<<, >>-


2 for ambiguity in 'case v of { x :: T -> T ... } ' 	[States 11, 253]
 	Which of these two is intended?
	  case v of
	    (x::T) -> T		-- Rhs is T
    or
	  case v of
	    (x::T -> T) -> ..	-- Rhs is ...
ross's avatar
ross committed
87

88
10 for ambiguity in 'e :: a `b` c'.  Does this mean 	[States 11, 253]
89 90
	(e::a) `b` c, or 
	(e :: (a `b` c))
91
    As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
92
    Same duplication between states 11 and 253 as the previous case
93

94
1 for ambiguity in 'let ?x ...'				[State 329]
95 96 97 98
	the parser can't tell whether the ?x is the lhs of a normal binding or
	an implicit binding.  Fortunately resolving as shift gives it the only
	sensible meaning, namely the lhs of an implicit binding.

99
1 for ambiguity in '{-# RULES "name" [ ... #-}		[State 382]
100 101 102 103
	we don't know whether the '[' starts the activation or not: it
  	might be the start of the declaration with the activation being
	empty.  --SDM 1/4/2002

104
1 for ambiguity in '{-# RULES "name" forall = ... #-}' 	[State 474]
105 106 107 108 109 110 111
	since 'forall' is a valid variable name, we don't know whether
	to treat a forall on the input as the beginning of a quantifier
	or the beginning of the rule itself.  Resolving to shift means
	it's always treated as a quantifier, hence the above is disallowed.
	This saves explicitly defining a grammar for the rule lhs that
	doesn't include 'forall'.

112 113 114 115
1 for ambiguity when the source file starts with "-- | doc". We need another
  token of lookahead to determine if a top declaration or the 'module' keyword
  follows. Shift parses as if the 'module' keyword follows.   

116 117 118 119 120 121 122 123 124 125 126
-- ---------------------------------------------------------------------------
-- Adding location info

This is done in a stylised way using the three macros below, L0, L1
and LL.  Each of these macros can be thought of as having type

   L0, L1, LL :: a -> Located a

They each add a SrcSpan to their argument.

   L0	adds 'noSrcSpan', used for empty productions
127
     -- This doesn't seem to work anymore -=chak
128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171

   L1   for a production with a single token on the lhs.  Grabs the SrcSpan
	from that token.

   LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
        the first and last tokens.

These suffice for the majority of cases.  However, we must be
especially careful with empty productions: LL won't work if the first
or last token on the lhs can represent an empty span.  In these cases,
we have to calculate the span using more of the tokens from the lhs, eg.

	| 'newtype' tycl_hdr '=' newconstr deriving
		{ L (comb3 $1 $4 $5)
		    (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }

We provide comb3 and comb4 functions which are useful in such cases.

Be careful: there's no checking that you actually got this right, the
only symptom will be that the SrcSpans of your syntax will be
incorrect.

/*
 * We must expand these macros *before* running Happy, which is why this file is
 * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 */
#define L0   L noSrcSpan
#define L1   sL (getLoc $1)
#define LL   sL (comb2 $1 $>)

-- -----------------------------------------------------------------------------

-}

%token
 '_'            { L _ ITunderscore }		-- Haskell keywords
 'as' 		{ L _ ITas }
 'case' 	{ L _ ITcase }  	
 'class' 	{ L _ ITclass } 
 'data' 	{ L _ ITdata } 
 'default' 	{ L _ ITdefault }
 'deriving' 	{ L _ ITderiving }
 'do' 		{ L _ ITdo }
 'else' 	{ L _ ITelse }
172
 'for' 	        { L _ ITfor }
173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190
 'hiding' 	{ L _ IThiding }
 'if' 		{ L _ ITif }
 'import' 	{ L _ ITimport }
 'in' 		{ L _ ITin }
 'infix' 	{ L _ ITinfix }
 'infixl' 	{ L _ ITinfixl }
 'infixr' 	{ L _ ITinfixr }
 'instance' 	{ L _ ITinstance }
 'let' 		{ L _ ITlet }
 'module' 	{ L _ ITmodule }
 'newtype' 	{ L _ ITnewtype }
 'of' 		{ L _ ITof }
 'qualified' 	{ L _ ITqualified }
 'then' 	{ L _ ITthen }
 'type' 	{ L _ ITtype }
 'where' 	{ L _ ITwhere }
 '_scc_'	{ L _ ITscc }	      -- ToDo: remove

191
 'forall'	{ L _ ITforall }		-- GHC extension keywords
192 193 194 195 196 197 198 199
 'foreign'	{ L _ ITforeign }
 'export'	{ L _ ITexport }
 'label'	{ L _ ITlabel } 
 'dynamic'	{ L _ ITdynamic }
 'safe'		{ L _ ITsafe }
 'threadsafe'	{ L _ ITthreadsafe }
 'unsafe'	{ L _ ITunsafe }
 'mdo'		{ L _ ITmdo }
200
 'iso'		{ L _ ITiso }
201
 'family'	{ L _ ITfamily }
202 203 204 205 206 207
 'stdcall'      { L _ ITstdcallconv }
 'ccall'        { L _ ITccallconv }
 'dotnet'       { L _ ITdotnet }
 'proc'		{ L _ ITproc }		-- for arrow notation extension
 'rec'		{ L _ ITrec }		-- for arrow notation extension

208 209 210
 '{-# INLINE'      	  { L _ (ITinline_prag _) }
 '{-# SPECIALISE'  	  { L _ ITspec_prag }
 '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279
 '{-# SOURCE'	   { L _ ITsource_prag }
 '{-# RULES'	   { L _ ITrules_prag }
 '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 '{-# SCC'	   { L _ ITscc_prag }
 '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 '{-# UNPACK'      { L _ ITunpack_prag }
 '#-}'		   { L _ ITclose_prag }

 '..'		{ L _ ITdotdot }  			-- reserved symbols
 ':'		{ L _ ITcolon }
 '::'		{ L _ ITdcolon }
 '='		{ L _ ITequal }
 '\\'		{ L _ ITlam }
 '|'		{ L _ ITvbar }
 '<-'		{ L _ ITlarrow }
 '->'		{ L _ ITrarrow }
 '@'		{ L _ ITat }
 '~'		{ L _ ITtilde }
 '=>'		{ L _ ITdarrow }
 '-'		{ L _ ITminus }
 '!'		{ L _ ITbang }
 '*'		{ L _ ITstar }
 '-<'		{ L _ ITlarrowtail }		-- for arrow notation
 '>-'		{ L _ ITrarrowtail }		-- for arrow notation
 '-<<'		{ L _ ITLarrowtail }		-- for arrow notation
 '>>-'		{ L _ ITRarrowtail }		-- for arrow notation
 '.'		{ L _ ITdot }

 '{'		{ L _ ITocurly } 			-- special symbols
 '}'		{ L _ ITccurly }
 '{|'           { L _ ITocurlybar }
 '|}'           { L _ ITccurlybar }
 vocurly	{ L _ ITvocurly } -- virtual open curly (from layout)
 vccurly	{ L _ ITvccurly } -- virtual close curly (from layout)
 '['		{ L _ ITobrack }
 ']'		{ L _ ITcbrack }
 '[:'		{ L _ ITopabrack }
 ':]'		{ L _ ITcpabrack }
 '('		{ L _ IToparen }
 ')'		{ L _ ITcparen }
 '(#'		{ L _ IToubxparen }
 '#)'		{ L _ ITcubxparen }
 '(|'		{ L _ IToparenbar }
 '|)'		{ L _ ITcparenbar }
 ';'		{ L _ ITsemi }
 ','		{ L _ ITcomma }
 '`'		{ L _ ITbackquote }

 VARID   	{ L _ (ITvarid    _) }		-- identifiers
 CONID   	{ L _ (ITconid    _) }
 VARSYM  	{ L _ (ITvarsym   _) }
 CONSYM  	{ L _ (ITconsym   _) }
 QVARID  	{ L _ (ITqvarid   _) }
 QCONID  	{ L _ (ITqconid   _) }
 QVARSYM 	{ L _ (ITqvarsym  _) }
 QCONSYM 	{ L _ (ITqconsym  _) }

 IPDUPVARID   	{ L _ (ITdupipvarid   _) }		-- GHC extension

 CHAR		{ L _ (ITchar     _) }
 STRING		{ L _ (ITstring   _) }
 INTEGER	{ L _ (ITinteger  _) }
 RATIONAL	{ L _ (ITrational _) }
		    
 PRIMCHAR	{ L _ (ITprimchar   _) }
 PRIMSTRING	{ L _ (ITprimstring _) }
 PRIMINTEGER	{ L _ (ITprimint    _) }
 PRIMFLOAT	{ L _ (ITprimfloat  _) }
 PRIMDOUBLE	{ L _ (ITprimdouble _) }
280 281 282 283 284 285 286

 DOCNEXT	{ L _ (ITdocCommentNext _) }
 DOCPREV	{ L _ (ITdocCommentPrev _) }
 DOCNAMED	{ L _ (ITdocCommentNamed _) }
 DOCSECTION	{ L _ (ITdocSection _ _) }
 DOCOPTIONS	{ L _ (ITdocOptions _) }

287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302
-- Template Haskell 
'[|'            { L _ ITopenExpQuote  }       
'[p|'           { L _ ITopenPatQuote  }      
'[t|'           { L _ ITopenTypQuote  }      
'[d|'           { L _ ITopenDecQuote  }      
'|]'            { L _ ITcloseQuote    }
TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
'$('	        { L _ ITparenEscape   }     -- $( exp )
TH_VAR_QUOTE	{ L _ ITvarQuote      }     -- 'x
TH_TY_QUOTE	{ L _ ITtyQuote       }      -- ''T

%monad { P } { >>= } { return }
%lexer { lexer } { L _ ITeof }
%name parseModule module
%name parseStmt   maybe_stmt
%name parseIdentifier  identifier
303
%name parseType ctype
304
%partial parseHeader header
305
%tokentype { (Located Token) }
306 307
%%

308 309 310 311 312 313 314 315
-----------------------------------------------------------------------------
-- Identifiers; one of the entry points
identifier :: { Located RdrName }
	: qvar				{ $1 }
	| qcon				{ $1 }
	| qvarop			{ $1 }
	| qconop			{ $1 }

316 317 318 319 320 321 322 323 324 325 326
-----------------------------------------------------------------------------
-- Module Header

-- The place for module deprecation is really too restrictive, but if it
-- was allowed at its natural place just before 'module', we get an ugly
-- s/r conflict with the second alternative. Another solution would be the
-- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
-- either, and DEPRECATED is only expected to be used by people who really
-- know what they are doing. :-)

module 	:: { Located (HsModule RdrName) }
327 328 329 330
 	: optdoc 'module' modid maybemoddeprec maybeexports 'where' body 
		{% fileSrcSpan >>= \ loc -> case $1 of { (opt, info, doc) -> 
		   return (L loc (HsModule (Just $3) $5 (fst $7) (snd $7) $4 
                          opt info doc) )}}
331 332 333
	| missing_module_keyword top close
		{% fileSrcSpan >>= \ loc ->
		   return (L loc (HsModule Nothing Nothing 
334 335 336 337 338 339 340 341 342
                          (fst $2) (snd $2) Nothing Nothing emptyHaddockModInfo 
                          Nothing)) }

optdoc :: { (Maybe String, HaddockModInfo RdrName, Maybe (HsDoc RdrName)) }                             
        : moduleheader            { (Nothing, fst $1, snd $1) }
        | docoptions              { (Just $1, emptyHaddockModInfo, Nothing)} 
        | docoptions moduleheader { (Just $1, fst $2, snd $2) } 
        | moduleheader docoptions { (Just $2, fst $1, snd $1) } 
        | {- empty -}             { (Nothing, emptyHaddockModInfo, Nothing) }  
343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362

missing_module_keyword :: { () }
	: {- empty -}				{% pushCurrentContext }

maybemoddeprec :: { Maybe DeprecTxt }
	: '{-# DEPRECATED' STRING '#-}' 	{ Just (getSTRING $2) }
	|  {- empty -}				{ Nothing }

body 	:: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
	:  '{'            top '}'		{ $2 }
 	|      vocurly    top close		{ $2 }

top 	:: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
	: importdecls				{ (reverse $1,[]) }
	| importdecls ';' cvtopdecls		{ (reverse $1,$3) }
	| cvtopdecls				{ ([],$1) }

cvtopdecls :: { [LHsDecl RdrName] }
	: topdecls				{ cvTopDecls $1 }

363 364 365 366
-----------------------------------------------------------------------------
-- Module declaration & imports only

header 	:: { Located (HsModule RdrName) }
367 368 369 370
 	: optdoc 'module' modid maybemoddeprec maybeexports 'where' header_body
		{% fileSrcSpan >>= \ loc -> case $1 of { (opt, info, doc) -> 
		   return (L loc (HsModule (Just $3) $5 $7 [] $4 
                   opt info doc))}}
371 372
	| missing_module_keyword importdecls
		{% fileSrcSpan >>= \ loc ->
373 374
		   return (L loc (HsModule Nothing Nothing $2 [] Nothing 
                   Nothing emptyHaddockModInfo Nothing)) }
375 376 377 378 379

header_body :: { [LImportDecl RdrName] }
	:  '{'            importdecls		{ $2 }
 	|      vocurly    importdecls		{ $2 }

380 381 382 383 384 385 386
-----------------------------------------------------------------------------
-- The Export List

maybeexports :: { Maybe [LIE RdrName] }
	:  '(' exportlist ')'			{ Just $2 }
	|  {- empty -}				{ Nothing }

387 388
exportlist :: { [LIE RdrName] }
	: expdoclist ',' expdoclist		{ $1 ++ $3 }
389 390 391
	| exportlist1				{ $1 }

exportlist1 :: { [LIE RdrName] }
392 393 394 395 396 397 398 399 400 401 402 403 404
        : expdoclist export expdoclist ',' exportlist  { $1 ++ ($2 : $3) ++ $5 }
 	| expdoclist export expdoclist	               { $1 ++ ($2 : $3) }
	| expdoclist				       { $1 }

expdoclist :: { [LIE RdrName] }
        : exp_doc expdoclist                           { $1 : $2 }
        | {- empty -}                                  { [] }

exp_doc :: { LIE RdrName }                                                   
        : docsection    { L1 (case (unLoc $1) of (n, doc) -> IEGroup n doc) }
        | docnamed      { L1 (IEDocNamed ((fst . unLoc) $1)) } 
        | docnext       { L1 (IEDoc (unLoc $1)) }       
                       
405 406 407 408 409 410 411 412 413 414 415
   -- No longer allow things like [] and (,,,) to be exported
   -- They are built in syntax, always available
export 	:: { LIE RdrName }
	:  qvar				{ L1 (IEVar (unLoc $1)) }
	|  oqtycon			{ L1 (IEThingAbs (unLoc $1)) }
	|  oqtycon '(' '..' ')'		{ LL (IEThingAll (unLoc $1)) }
	|  oqtycon '(' ')'		{ LL (IEThingWith (unLoc $1) []) }
	|  oqtycon '(' qcnames ')'	{ LL (IEThingWith (unLoc $1) (reverse $3)) }
	|  'module' modid		{ LL (IEModuleContents (unLoc $2)) }

qcnames :: { [RdrName] }
416 417
	:  qcnames ',' qcname_ext	{ unLoc $3 : $1 }
	|  qcname_ext			{ [unLoc $1]  }
418

419 420 421 422 423 424 425 426
qcname_ext :: { Located RdrName }	-- Variable or data constructor
					-- or tagged type constructor
	:  qcname			{ $1 }
	|  'type' qcon			{ sL (comb2 $1 $2) 
					     (setRdrNameSpace (unLoc $2) 
							      tcClsName)  }

-- Cannot pull into qcname_ext, as qcname is also used in expression.
427
qcname 	:: { Located RdrName }	-- Variable or data constructor
428 429
	:  qvar				{ $1 }
	|  qcon				{ $1 }
430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454

-----------------------------------------------------------------------------
-- Import Declarations

-- import decls can be *empty*, or even just a string of semicolons
-- whereas topdecls must contain at least one topdecl.

importdecls :: { [LImportDecl RdrName] }
	: importdecls ';' importdecl		{ $3 : $1 }
	| importdecls ';'			{ $1 }
	| importdecl				{ [ $1 ] }
	| {- empty -}				{ [] }

importdecl :: { LImportDecl RdrName }
	: 'import' maybe_src optqualified modid maybeas maybeimpspec 
		{ L (comb4 $1 $4 $5 $6) (ImportDecl $4 $2 $3 (unLoc $5) (unLoc $6)) }

maybe_src :: { IsBootInterface }
	: '{-# SOURCE' '#-}'			{ True }
	| {- empty -}				{ False }

optqualified :: { Bool }
      	: 'qualified'                           { True  }
      	| {- empty -}				{ False }

Simon Marlow's avatar
Simon Marlow committed
455
maybeas :: { Located (Maybe ModuleName) }
456 457 458 459 460 461 462 463
      	: 'as' modid                            { LL (Just (unLoc $2)) }
      	| {- empty -}				{ noLoc Nothing }

maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
	: impspec				{ L1 (Just (unLoc $1)) }
	| {- empty -}				{ noLoc Nothing }

impspec :: { Located (Bool, [LIE RdrName]) }
464 465
	:  '(' exportlist ')'  			{ LL (False, $2) }
	|  'hiding' '(' exportlist ')' 		{ LL (True,  $3) }
466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485

-----------------------------------------------------------------------------
-- Fixity Declarations

prec 	:: { Int }
	: {- empty -}		{ 9 }
	| INTEGER		{% checkPrecP (L1 (fromInteger (getINTEGER $1))) }

infix 	:: { Located FixityDirection }
	: 'infix'				{ L1 InfixN  }
	| 'infixl'				{ L1 InfixL  }
	| 'infixr'				{ L1 InfixR }

ops   	:: { Located [Located RdrName] }
	: ops ',' op				{ LL ($3 : unLoc $1) }
	| op					{ L1 [$1] }

-----------------------------------------------------------------------------
-- Top-Level Declarations

486
topdecls :: { OrdList (LHsDecl RdrName) }
487 488 489
        : topdecls ';' topdecl		        { $1 `appOL` $3 }
        | topdecls ';'			        { $1 }
	| topdecl			        { $1 }
490

491
topdecl :: { OrdList (LHsDecl RdrName) }
492
  	: cl_decl			{ unitOL (L1 (TyClD (unLoc $1))) }
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
493
  	| ty_decl			{ unitOL (L1 (TyClD (unLoc $1))) }
494 495 496
	  | 'instance' inst_type where
		{ let (binds, sigs, ats, _) = cvBindsAndSigs (unLoc $3)
		  in unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs ats))) }
497
        | stand_alone_deriving                  { unitOL (LL (DerivD (unLoc $1))) }
498 499 500 501
	| 'default' '(' comma_types0 ')'	{ unitOL (LL $ DefD (DefaultDecl $3)) }
	| 'foreign' fdecl			{ unitOL (LL (unLoc $2)) }
	| '{-# DEPRECATED' deprecations '#-}'	{ $2 }
	| '{-# RULES' rules '#-}'		{ $2 }
502 503
      	| decl					{ unLoc $1 }

504 505 506 507 508 509
	-- Template Haskell Extension
	| '$(' exp ')'				{ unitOL (LL $ SpliceD (SpliceDecl $2)) }
	| TH_ID_SPLICE				{ unitOL (LL $ SpliceD (SpliceDecl $
							L1 $ HsVar (mkUnqual varName (getTH_ID_SPLICE $1))
						  )) }

510 511 512 513
-- Type classes
--
cl_decl :: { LTyClDecl RdrName }
	: 'class' tycl_hdr fds where
514
		{% do { let { (binds, sigs, ats, docs)           = 
515
			        cvBindsAndSigs (unLoc $4)
516
		            ; (ctxt, tc, tvs, tparms) = unLoc $2}
517
                      ; checkTyVars tparms      -- only type vars allowed
518
		      ; checkKindSigs ats
519 520
		      ; return $ L (comb4 $1 $2 $3 $4) 
				   (mkClassDecl (ctxt, tc, tvs) 
521
					        (unLoc $3) sigs binds ats docs) } }
522

523
-- Type declarations (toplevel)
524 525
--
ty_decl :: { LTyClDecl RdrName }
526 527 528 529 530 531
           -- ordinary type synonyms
        : 'type' type '=' ctype
		-- Note ctype, not sigtype, on the right of '='
		-- We allow an explicit for-all but we don't insert one
		-- in 	type Foo a = (b,b)
		-- Instead we just say b is out of scope
532 533
	        --
		-- Note the use of type for the head; this allows
534 535 536 537 538 539 540
		-- infix type constructors to be declared 
 		{% do { (tc, tvs, _) <- checkSynHdr $2 False
		      ; return (L (comb2 $1 $4) 
				  (TySynonym tc tvs Nothing $4)) 
                      } }

           -- type family declarations
541
        | 'type' 'family' type opt_kind_sig 
542 543
		-- Note the use of type for the head; this allows
		-- infix type constructors to be declared
544
		--
545 546 547 548 549 550
 		{% do { (tc, tvs, _) <- checkSynHdr $3 False
		      ; let kind = case unLoc $4 of
				     Nothing -> liftedTypeKind
				     Just ki -> ki
		      ; return (L (comb3 $1 $3 $4) 
				  (TyFunction tc tvs False kind))
551 552 553 554 555 556 557 558 559 560 561
		      } }

           -- type instance declarations
        | 'type' 'instance' type '=' ctype
		-- Note the use of type for the head; this allows
		-- infix type constructors and type patterns
		--
 		{% do { (tc, tvs, typats) <- checkSynHdr $3 True
		      ; return (L (comb2 $1 $5) 
				  (TySynonym tc tvs (Just typats) $5)) 
                      } }
562

563
          -- ordinary data type or newtype declaration
564
	| data_or_newtype tycl_hdr constrs deriving
565
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
566
                      ; checkTyVars tparms    -- no type pattern
567 568 569 570
		      ; return $
			  L (comb4 $1 $2 $3 $4)
			           -- We need the location on tycl_hdr in case 
				   -- constrs and deriving are both empty
571 572
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing) 
			       Nothing (reverse (unLoc $3)) (unLoc $4)) } }
573

574
          -- ordinary GADT declaration
575
        | data_or_newtype tycl_hdr opt_kind_sig 
576
		 'where' gadt_constrlist
577
		 deriving
578
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
579
                      ; checkTyVars tparms    -- can have type pats
580 581
		      ; return $
			  L (comb4 $1 $2 $4 $5)
582 583
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing) 
			      (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
584

585
          -- data/newtype family
586
        | data_or_newtype 'family' tycl_hdr opt_kind_sig
587 588
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
                      ; checkTyVars tparms    -- no type pattern
589 590 591
		      ; let kind = case unLoc $4 of
				     Nothing -> liftedTypeKind
				     Just ki -> ki
592
		      ; return $
593
			  L (comb3 $1 $2 $4)
594
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing) 
595
			      (Just kind) [] Nothing) } }
596

597
          -- data/newtype instance declaration
598 599 600 601 602 603 604 605 606 607
	| data_or_newtype 'instance' tycl_hdr constrs deriving
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
                                             -- can have type pats
		      ; return $
			  L (comb4 $1 $3 $4 $5)
			           -- We need the location on tycl_hdr in case 
				   -- constrs and deriving are both empty
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms) 
			      Nothing (reverse (unLoc $4)) (unLoc $5)) } }

608
          -- GADT instance declaration
609 610 611 612 613 614 615 616
        | data_or_newtype 'instance' tycl_hdr opt_kind_sig 
		 'where' gadt_constrlist
		 deriving
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $3}
                                             -- can have type pats
		      ; return $
			  L (comb4 $1 $3 $6 $7)
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms) 
617
			       (unLoc $4) (reverse (unLoc $6)) (unLoc $7)) } }
618

619 620 621 622
-- Associate type declarations
--
at_decl :: { LTyClDecl RdrName }
           -- type family declarations
623
        : 'type' type opt_kind_sig
624 625 626
		-- Note the use of type for the head; this allows
		-- infix type constructors to be declared
		--
627 628 629 630 631 632
 		{% do { (tc, tvs, _) <- checkSynHdr $2 False
		      ; let kind = case unLoc $3 of
				     Nothing -> liftedTypeKind
				     Just ki -> ki
		      ; return (L (comb3 $1 $2 $3) 
				  (TyFunction tc tvs False kind))
633 634 635
		      } }

           -- type instance declarations
636
        | 'type' type '=' ctype
637 638 639
		-- Note the use of type for the head; this allows
		-- infix type constructors and type patterns
		--
640 641 642
 		{% do { (tc, tvs, typats) <- checkSynHdr $2 True
		      ; return (L (comb2 $1 $4) 
				  (TySynonym tc tvs (Just typats) $4)) 
643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673
                      } }

          -- data/newtype family
        | data_or_newtype tycl_hdr '::' kind
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
                      ; checkTyVars tparms    -- no type pattern
		      ; return $
			  L (comb3 $1 $2 $4)
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Nothing) 
			      (Just (unLoc $4)) [] Nothing) } }

        -- data/newtype instance declaration
	| data_or_newtype tycl_hdr constrs deriving
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
                                             -- can have type pats
		      ; return $
			  L (comb4 $1 $2 $3 $4)
			           -- We need the location on tycl_hdr in case 
				   -- constrs and deriving are both empty
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms) 
			      Nothing (reverse (unLoc $3)) (unLoc $4)) } }

        -- GADT instance declaration
        | data_or_newtype tycl_hdr opt_kind_sig 
		 'where' gadt_constrlist
		 deriving
		{% do { let {(ctxt, tc, tvs, tparms) = unLoc $2}
                                             -- can have type pats
		      ; return $
			  L (comb4 $1 $2 $5 $6)
			    (mkTyData (unLoc $1) (ctxt, tc, tvs, Just tparms) 
674
			     (unLoc $3) (reverse (unLoc $5)) (unLoc $6)) } }
675

676 677 678 679
opt_iso :: { Bool }
	:       { False }
	| 'iso'	{ True  }

680 681 682 683
data_or_newtype :: { Located NewOrData }
	: 'data'	{ L1 DataType }
	| 'newtype'	{ L1 NewType }

684 685 686
opt_kind_sig :: { Located (Maybe Kind) }
	: 				{ noLoc Nothing }
	| '::' kind			{ LL (Just (unLoc $2)) }
687

688
-- tycl_hdr parses the header of a class or data type decl,
689 690 691 692
-- which takes the form
--	T a b
-- 	Eq a => T a
--	(Eq a, Ord b) => T a b
693
--      T Int [a]			-- for associated types
694
-- Rather a lot of inlining here, else we get reduce/reduce errors
695 696 697
tycl_hdr :: { Located (LHsContext RdrName, 
		       Located RdrName, 
		       [LHsTyVarBndr RdrName],
698
		       [LHsType RdrName]) }
699
	: context '=>' type		{% checkTyClHdr $1         $3 >>= return.LL }
700 701
	| type				{% checkTyClHdr (noLoc []) $1 >>= return.L1 }

702 703 704 705 706 707 708 709 710 711
-----------------------------------------------------------------------------
-- Stand-alone deriving

-- Glasgow extension: stand-alone deriving declarations
stand_alone_deriving :: { LDerivDecl RdrName }
  	: 'deriving' qtycon            'for' qtycon  {% do { p <- checkInstType (fmap HsTyVar $2)
				                           ; checkDerivDecl (LL (DerivDecl p $4)) } }

        | 'deriving' '(' inst_type ')' 'for' qtycon  {% checkDerivDecl (LL (DerivDecl $3 $6)) }

712 713 714
-----------------------------------------------------------------------------
-- Nested declarations

715 716 717
-- Type declaration or value declaration
--
tydecl  :: { Located (OrdList (LHsDecl RdrName)) }
718
tydecl  : at_decl		        { LL (unitOL (L1 (TyClD (unLoc $1)))) }
719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740
	| decl                          { $1 }

tydecls	:: { Located (OrdList (LHsDecl RdrName)) }	-- Reversed
	: tydecls ';' tydecl		{ LL (unLoc $1 `appOL` unLoc $3) }
	| tydecls ';'			{ LL (unLoc $1) }
	| tydecl			{ $1 }
	| {- empty -}			{ noLoc nilOL }


tydecllist 
        :: { Located (OrdList (LHsDecl RdrName)) }	-- Reversed
	: '{'            tydecls '}'	{ LL (unLoc $2) }
	|     vocurly    tydecls close	{ $2 }

-- Form of the body of class and instance declarations
--
where 	:: { Located (OrdList (LHsDecl RdrName)) }	-- Reversed
				-- No implicit parameters
				-- May have type declarations
	: 'where' tydecllist		{ LL (unLoc $2) }
	| {- empty -}			{ noLoc nilOL }

741
decls 	:: { Located (OrdList (LHsDecl RdrName)) }	
742
	: decls ';' decl		{ LL (unLoc $1 `appOL` unLoc $3) }
743
	| decls ';'			{ LL (unLoc $1) }
744
	| decl				{ $1 }
745
	| {- empty -}			{ noLoc nilOL }
746

747
decllist :: { Located (OrdList (LHsDecl RdrName)) }
748 749 750
	: '{'            decls '}'	{ LL (unLoc $2) }
	|     vocurly    decls close	{ $2 }

751 752
-- Binding groups other than those of class and instance declarations
--
753
binds 	::  { Located (HsLocalBinds RdrName) } 		-- May have implicit parameters
754
						-- No type declarations
755 756 757
	: decllist			{ L1 (HsValBinds (cvBindGroup (unLoc $1))) }
	| '{'            dbinds '}'	{ LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
	|     vocurly    dbinds close	{ L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
758

759
wherebinds :: { Located (HsLocalBinds RdrName) }	-- May have implicit parameters
760
						-- No type declarations
761
	: 'where' binds			{ LL (unLoc $2) }
762
	| {- empty -}			{ noLoc emptyLocalBinds }
763 764 765 766 767


-----------------------------------------------------------------------------
-- Transformation Rules

768
rules	:: { OrdList (LHsDecl RdrName) }
769
	:  rules ';' rule			{ $1 `snocOL` $3 }
770
        |  rules ';'				{ $1 }
771 772
        |  rule					{ unitOL $1 }
	|  {- empty -}				{ nilOL }
773

774
rule  	:: { LHsDecl RdrName }
775
	: STRING activation rule_forall infixexp '=' exp
776 777
	     { LL $ RuleD (HsRule (getSTRING $1) 
				  ($2 `orElse` AlwaysActive) 
778
				  $3 $4 placeHolderNames $6 placeHolderNames) }
779

780 781 782
activation :: { Maybe Activation } 
        : {- empty -}                           { Nothing }
        | explicit_activation                   { Just $1 }
783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802

explicit_activation :: { Activation }  -- In brackets
        : '[' INTEGER ']'		{ ActiveAfter  (fromInteger (getINTEGER $2)) }
        | '[' '~' INTEGER ']'		{ ActiveBefore (fromInteger (getINTEGER $3)) }

rule_forall :: { [RuleBndr RdrName] }
	: 'forall' rule_var_list '.'            { $2 }
        | {- empty -}				{ [] }

rule_var_list :: { [RuleBndr RdrName] }
        : rule_var				{ [$1] }
        | rule_var rule_var_list		{ $1 : $2 }

rule_var :: { RuleBndr RdrName }
	: varid                              	{ RuleBndr $1 }
       	| '(' varid '::' ctype ')'             	{ RuleBndrSig $2 $4 }

-----------------------------------------------------------------------------
-- Deprecations (c.f. rules)

803
deprecations :: { OrdList (LHsDecl RdrName) }
804
	: deprecations ';' deprecation		{ $1 `appOL` $3 }
805
	| deprecations ';' 			{ $1 }
806 807
	| deprecation				{ $1 }
	| {- empty -}				{ nilOL }
808 809

-- SUP: TEMPORARY HACK, not checking for `module Foo'
810
deprecation :: { OrdList (LHsDecl RdrName) }
811
	: depreclist STRING
812 813
		{ toOL [ LL $ DeprecD (Deprecation n (getSTRING $2)) 
		       | n <- unLoc $1 ] }
814 815 816 817 818 819


-----------------------------------------------------------------------------
-- Foreign import and export declarations

fdecl :: { LHsDecl RdrName }
Simon Marlow's avatar
Simon Marlow committed
820
fdecl : 'import' callconv safety fspec
821
		{% mkImport $2 $3 (unLoc $4) >>= return.LL }
Simon Marlow's avatar
Simon Marlow committed
822
      | 'import' callconv        fspec		
823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838
		{% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
			return (LL d) } }
      | 'export' callconv fspec
		{% mkExport $2 (unLoc $3) >>= return.LL }

callconv :: { CallConv }
	  : 'stdcall'			{ CCall  StdCallConv }
	  | 'ccall'			{ CCall  CCallConv   }
	  | 'dotnet'			{ DNCall	     }

safety :: { Safety }
	: 'unsafe'			{ PlayRisky }
	| 'safe'			{ PlaySafe  False }
	| 'threadsafe'			{ PlaySafe  True }

fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
839 840
       : STRING var '::' sigtypedoc     { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
       |        var '::' sigtypedoc     { LL (noLoc nilFS, $1, $3) }
841 842 843 844 845 846 847 848 849 850 851 852 853 854 855
         -- if the entity string is missing, it defaults to the empty string;
         -- the meaning of an empty entity string depends on the calling
         -- convention

-----------------------------------------------------------------------------
-- Type signatures

opt_sig :: { Maybe (LHsType RdrName) }
	: {- empty -}			{ Nothing }
	| '::' sigtype			{ Just $2 }

opt_asig :: { Maybe (LHsType RdrName) }
	: {- empty -}			{ Nothing }
	| '::' atype			{ Just $2 }

856
sigtypes1 :: { [LHsType RdrName] }
857
	: sigtype			{ [ $1 ] }
858
	| sigtype ',' sigtypes1		{ $1 : $3 }
859 860 861 862 863

sigtype :: { LHsType RdrName }
	: ctype				{ L1 (mkImplicitHsForAllTy (noLoc []) $1) }
	-- Wrap an Implicit forall if there isn't one there already

864 865 866 867
sigtypedoc :: { LHsType RdrName }
	: ctypedoc			{ L1 (mkImplicitHsForAllTy (noLoc []) $1) }
	-- Wrap an Implicit forall if there isn't one there already

868 869 870 871 872 873 874
sig_vars :: { Located [Located RdrName] }
	 : sig_vars ',' var		{ LL ($3 : unLoc $1) }
	 | var				{ L1 [$1] }

-----------------------------------------------------------------------------
-- Types

875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895
infixtype :: { LHsType RdrName }
	: btype qtyconop gentype         { LL $ HsOpTy $1 $2 $3 }
        | btype tyvarop  gentype  	 { LL $ HsOpTy $1 $2 $3 }

infixtypedoc :: { LHsType RdrName }
        : infixtype                      { $1 }
	| infixtype docprev              { LL $ HsDocTy $1 $2 }

gentypedoc :: { LHsType RdrName }
        : btype                          { $1 }
        | btypedoc                       { $1 }
        | infixtypedoc                   { $1 }
        | btype '->' ctypedoc            { LL $ HsFunTy $1 $3 }
        | btypedoc '->' ctypedoc         { LL $ HsFunTy $1 $3 }

ctypedoc  :: { LHsType RdrName }
        : 'forall' tv_bndrs '.' ctypedoc { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
        | context '=>' gentypedoc        { LL $ mkImplicitHsForAllTy   $1 $3 }
	-- A type of form (context => type) is an *implicit* HsForAllTy
	| gentypedoc			 { $1 }
	
896 897 898 899
strict_mark :: { Located HsBang }
	: '!'				{ L1 HsStrict }
	| '{-# UNPACK' '#-}' '!'	{ LL HsUnbox }

900 901 902 903 904 905 906 907 908 909 910 911 912 913 914
-- A ctype is a for-all type
ctype	:: { LHsType RdrName }
	: 'forall' tv_bndrs '.' ctype	{ LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
	| context '=>' type		{ LL $ mkImplicitHsForAllTy   $1 $3 }
	-- A type of form (context => type) is an *implicit* HsForAllTy
	| type				{ $1 }

-- We parse a context as a btype so that we don't get reduce/reduce
-- errors in ctype.  The basic problem is that
--	(Eq a, Ord a)
-- looks so much like a tuple type.  We can't tell until we find the =>
context :: { LHsContext RdrName }
	: btype 			{% checkContext $1 }

type :: { LHsType RdrName }
915
	: ipvar '::' gentype		{ LL (HsPredTy (HsIParam (unLoc $1) $3)) }
916 917 918 919 920
	| gentype			{ $1 }

gentype :: { LHsType RdrName }
        : btype                         { $1 }
        | btype qtyconop gentype        { LL $ HsOpTy $1 $2 $3 }
921
        | btype tyvarop  gentype  	{ LL $ HsOpTy $1 $2 $3 }
922
 	| btype '->' ctype		{ LL $ HsFunTy $1 $3 }
923 924 925 926 927

btype :: { LHsType RdrName }
	: btype atype			{ LL $ HsAppTy $1 $2 }
	| atype				{ $1 }

928 929 930 931
btypedoc :: { LHsType RdrName }
	: btype atype docprev		{ LL $ HsDocTy (L (comb2 $1 $2) (HsAppTy $1 $2)) $3 }
        | atype docprev                 { LL $ HsDocTy $1 $2 }

932 933
atype :: { LHsType RdrName }
	: gtycon			{ L1 (HsTyVar (unLoc $1)) }
934
	| tyvar				{ L1 (HsTyVar (unLoc $1)) }
935
	| strict_mark atype		{ LL (HsBangTy (unLoc $1) $2) }
936
	| '(' ctype ',' comma_types1 ')'  { LL $ HsTupleTy Boxed  ($2:$4) }
937
	| '(#' comma_types1 '#)'	{ LL $ HsTupleTy Unboxed $2     }
938 939
	| '[' ctype ']'			{ LL $ HsListTy  $2 }
	| '[:' ctype ':]'		{ LL $ HsPArrTy  $2 }
940
	| '(' ctype ')'		        { LL $ HsParTy   $2 }
941
	| '(' ctype '::' kind ')'	{ LL $ HsKindSig $2 (unLoc $4) }
942 943 944 945 946 947 948 949
-- Generics
        | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }

-- An inst_type is what occurs in the head of an instance decl
--	e.g.  (Foo a, Gaz b) => Wibble a b
-- It's kept as a single type, with a MonoDictTy at the right
-- hand corner, for convenience.
inst_type :: { LHsType RdrName }
950
	: sigtype			{% checkInstType $1 }
951

952 953 954 955
inst_types1 :: { [LHsType RdrName] }
	: inst_type			{ [$1] }
	| inst_type ',' inst_types1	{ $1 : $3 }

956 957 958 959 960
comma_types0  :: { [LHsType RdrName] }
	: comma_types1			{ $1 }
	| {- empty -}			{ [] }

comma_types1	:: { [LHsType RdrName] }
961 962
	: ctype				{ [$1] }
	| ctype  ',' comma_types1	{ $1 : $3 }
963 964 965 966 967 968 969

tv_bndrs :: { [LHsTyVarBndr RdrName] }
	 : tv_bndr tv_bndrs		{ $1 : $2 }
	 | {- empty -}			{ [] }

tv_bndr :: { LHsTyVarBndr RdrName }
	: tyvar				{ L1 (UserTyVar (unLoc $1)) }
970 971
	| '(' tyvar '::' kind ')'	{ LL (KindedTyVar (unLoc $2) 
							  (unLoc $4)) }
972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991

fds :: { Located [Located ([RdrName], [RdrName])] }
	: {- empty -}			{ noLoc [] }
	| '|' fds1			{ LL (reverse (unLoc $2)) }

fds1 :: { Located [Located ([RdrName], [RdrName])] }
	: fds1 ',' fd			{ LL ($3 : unLoc $1) }
	| fd				{ L1 [$1] }

fd :: { Located ([RdrName], [RdrName]) }
	: varids0 '->' varids0		{ L (comb3 $1 $2 $3)
					   (reverse (unLoc $1), reverse (unLoc $3)) }

varids0	:: { Located [RdrName] }
	: {- empty -}			{ noLoc [] }
	| varids0 tyvar			{ LL (unLoc $2 : unLoc $1) }

-----------------------------------------------------------------------------
-- Kinds

992
kind	:: { Located Kind }
993
	: akind			{ $1 }
994
	| akind '->' kind	{ LL (mkArrowKind (unLoc $1) (unLoc $3)) }
995

996 997 998 999
akind	:: { Located Kind }
	: '*'			{ L1 liftedTypeKind }
	| '!'			{ L1 unliftedTypeKind }
	| '(' kind ')'		{ LL (unLoc $2) }
1000 1001 1002 1003 1004


-----------------------------------------------------------------------------
-- Datatype declarations

1005 1006 1007 1008 1009 1010
gadt_constrlist :: { Located [LConDecl RdrName] }
	: '{'            gadt_constrs '}'	{ LL (unLoc $2) }
	|     vocurly    gadt_constrs close	{ $2 }

gadt_constrs :: { Located [LConDecl RdrName] }
        : gadt_constrs ';' gadt_constr  { LL ($3 : unLoc $1) }
1011
        | gadt_constrs ';' 		{ $1 }
1012 1013
        | gadt_constr                   { L1 [$1] } 

1014 1015 1016 1017 1018 1019
-- We allow the following forms:
--	C :: Eq a => a -> T a
--	C :: forall a. Eq a => !a -> T a
--	D { x,y :: a } :: T a
--	forall a. Eq a => D { x,y :: a } :: T a

1020
gadt_constr :: { LConDecl RdrName }
1021
        : con '::' sigtype
1022 1023 1024
              { LL (mkGadtDecl $1 $3) } 
        -- Syntax: Maybe merge the record stuff with the single-case above?
        --         (to kill the mostly harmless reduce/reduce error)
1025
        -- XXX revisit audreyt
1026 1027
	| constr_stuff_record '::' sigtype
		{ let (con,details) = unLoc $1 in 
1028
		  LL (ConDecl con Implicit [] (noLoc []) details (ResTyGADT $3) Nothing) }
1029 1030 1031
{-
	| forall context '=>' constr_stuff_record '::' sigtype
		{ let (con,details) = unLoc $4 in 
1032
		  LL (ConDecl con Implicit (unLoc $1) $2 details (ResTyGADT $6) Nothing ) }
1033 1034
	| forall constr_stuff_record '::' sigtype
		{ let (con,details) = unLoc $2 in 
1035
		  LL (ConDecl con Implicit (unLoc $1) (noLoc []) details (ResTyGADT $4) Nothing) }
1036 1037
-}

1038 1039 1040

constrs :: { Located [LConDecl RdrName] }
        : {- empty; a GHC extension -}  { noLoc [] }
1041
        | maybe_docnext '=' constrs1    { L (comb2 $2 $3) (addConDocs (unLoc $3) $1) }
1042 1043

constrs1 :: { Located [LConDecl RdrName] }
1044 1045
	: constrs1 maybe_docnext '|' maybe_docprev constr { LL (addConDoc $5 $2 : addConDocFirst (unLoc $1) $4) }
	| constr			                  { L1 [$1] }
1046 1047

constr :: { LConDecl RdrName }
1048 1049 1050 1051 1052 1053
	: maybe_docnext forall context '=>' constr_stuff maybe_docprev	
		{ let (con,details) = unLoc $5 in 
		  L (comb4 $2 $3 $4 $5) (ConDecl con Explicit (unLoc $2) $3 details ResTyH98 ($1 `mplus` $6)) }
	| maybe_docnext forall constr_stuff maybe_docprev
		{ let (con,details) = unLoc $3 in 
		  L (comb2 $2 $3) (ConDecl con Explicit (unLoc $2) (noLoc []) details ResTyH98 ($1 `mplus` $4)) }
1054 1055 1056 1057 1058 1059

forall :: { Located [LHsTyVarBndr RdrName] }
	: 'forall' tv_bndrs '.'		{ LL $2 }
	| {- empty -}			{ noLoc [] }

constr_stuff :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
1060 1061 1062 1063 1064 1065 1066
-- We parse the constructor declaration 
--	C t1 t2
-- as a btype (treating C as a type constructor) and then convert C to be
-- a data constructor.  Reason: it might continue like this:
--	C t1 t2 %: D Int
-- in which case C really would be a type constructor.  We can't resolve this
-- ambiguity till we come across the constructor oprerator :% (or not, more usually)
1067 1068 1069
	: btype				{% mkPrefixCon $1 [] >>= return.LL }
	| oqtycon '{' '}' 		{% mkRecCon $1 [] >>= return.LL }
	| oqtycon '{' fielddecls '}' 	{% mkRecCon $1 $3 >>= return.LL }
1070
	| btype conop btype		{ LL ($2, InfixCon $1 $3) }
1071

1072 1073 1074 1075
constr_stuff_record :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
	: oqtycon '{' '}' 		{% mkRecCon $1 [] >>= return.sL (comb2 $1 $>) }
	| oqtycon '{' fielddecls '}' 	{% mkRecCon $1 $3 >>= return.sL (comb2 $1 $>) }

1076 1077 1078
fielddecls :: { [([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName))] }
	: fielddecl maybe_docnext ',' maybe_docprev fielddecls { addFieldDoc (unLoc $1) $4 : addFieldDocs $5 $2 }
	| fielddecl			                       { [unLoc $1] }
1079

1080 1081
fielddecl :: { Located ([Located RdrName], LBangType RdrName, Maybe (LHsDoc RdrName)) }
	: maybe_docnext sig_vars '::' ctype maybe_docprev      { L (comb3 $2 $3 $4) (reverse (unLoc $2), $4, $1 `mplus` $5) }
1082

1083 1084 1085 1086
-- We allow the odd-looking 'inst_type' in a deriving clause, so that
-- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
-- The 'C [a]' part is converted to an HsPredTy by checkInstType
-- We don't allow a context, but that's sorted out by the type checker.
1087 1088
deriving :: { Located (Maybe [LHsType RdrName]) }
	: {- empty -}				{ noLoc Nothing }
1089 1090 1091
	| 'deriving' qtycon	{% do { let { L loc tv = $2 }
				      ; p <- checkInstType (L loc (HsTyVar tv))
				      ; return (LL (Just [p])) } }
1092 1093
	| 'deriving' '(' ')'	 		{ LL (Just []) }
	| 'deriving' '(' inst_types1 ')' 	{ LL (Just $3) }
1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119
             -- Glasgow extension: allow partial 
             -- applications in derivings

-----------------------------------------------------------------------------
-- Value definitions

{- There's an awkward overlap with a type signature.  Consider
	f :: Int -> Int = ...rhs...
   Then we can't tell whether it's a type signature or a value
   definition with a result signature until we see the '='.
   So we have to inline enough to postpone reductions until we know.
-}

{-
  ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
  instead of qvar, we get another shift/reduce-conflict. Consider the
  following programs:
  
     { (^^) :: Int->Int ; }          Type signature; only var allowed

     { (^^) :: Int->Int = ... ; }    Value defn with result signature;
				     qvar allowed (because of instance decls)
  
  We can't tell whether to reduce var to qvar until after we've read the signatures.
-}

1120 1121 1122 1123 1124 1125 1126 1127 1128
docdecl :: { LHsDecl RdrName }
        : docdecld { L1 (DocD (unLoc $1)) }

docdecld :: { LDocDecl RdrName }
        : docnext                               { L1 (DocCommentNext (unLoc $1)) }
        | docprev                               { L1 (DocCommentPrev (unLoc $1)) }
        | docnamed                              { L1 (case (unLoc $1) of (n, doc) -> DocCommentNamed n doc) }
        | docsection                            { L1 (case (unLoc $1) of (n, doc) -> DocGroup n doc) }

1129
decl 	:: { Located (OrdList (LHsDecl RdrName)) }
1130
	: sigdecl			{ $1 }
simonpj@microsoft.com's avatar
simonpj@microsoft.com committed
1131
	| '!' infixexp rhs		{% do { pat <- checkPattern $2;
1132
					        return (LL $ unitOL $ LL $ ValD ( 
simonpj@microsoft.com's avatar
simonpj@microsoft.com committed
1133
							PatBind (LL $ BangPat pat) (unLoc $3)
1134
								placeHolderType placeHolderNames)) } }
1135
	| infixexp opt_sig rhs		{% do { r <- checkValDef $1 $2 $3;
1136
						return (LL $ unitOL (LL $ ValD r)) } }
1137
        | docdecl                       { LL $ unitOL $1 }
1138 1139

rhs	:: { Located (GRHSs RdrName) }
1140 1141
	: '=' exp wherebinds	{ L (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
	| gdrhs	wherebinds	{ LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
1142 1143 1144 1145 1146 1147

gdrhs :: { Located [LGRHS RdrName] }
	: gdrhs gdrh		{ LL ($2 : unLoc $1) }
	| gdrh			{ L1 [$1] }

gdrh :: { LGRHS RdrName }
1148
	: '|' quals '=' exp  	{ sL (comb2 $1 $>) $ GRHS (reverse (unLoc $2)) $4 }
1149

1150
sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
1151
	: infixexp '::' sigtypedoc
1152
				{% do s <- checkValSig $1 $3; 
1153
				      return (LL $ unitOL (LL $ SigD s)) }
1154
		-- See the above notes for why we need infixexp here
1155
	| var ',' sig_vars '::' sigtypedoc
1156
				{ LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
1157
	| infix prec ops	{ LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
1158 1159
					     | n <- unLoc $3 ] }
	| '{-# INLINE'   activation qvar '#-}'	      
1160
				{ LL $ unitOL (LL $ SigD (InlineSig $3 (mkInlineSpec $2 (getINLINE $1)))) }
1161
	| '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1162
			 	{ LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlineSpec) 
1163
					    | t <- $4] }
1164
	| '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1165
			 	{ LL $ toOL [ LL $ SigD (SpecSig $3 t (mkInlineSpec $2 (getSPEC_INLINE $1)))
1166
					    | t <- $5] }
1167
	| '{-# SPECIALISE' 'instance' inst_type '#-}'
1168
				{ LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1169 1170 1171 1172 1173 1174

-----------------------------------------------------------------------------
-- Expressions

exp   :: { LHsExpr RdrName }
	: infixexp '::' sigtype		{ LL $ ExprWithTySig $1 $3 }
ross's avatar
ross committed
1175 1176 1177 1178
	| infixexp '-<' exp		{ LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
	| infixexp '>-' exp		{ LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
	| infixexp '-<<' exp		{ LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
	| infixexp '>>-' exp		{ LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1179 1180 1181 1182 1183 1184 1185 1186 1187
	| infixexp			{ $1 }

infixexp :: { LHsExpr RdrName }
	: exp10				{ $1 }
	| infixexp qop exp10		{ LL (OpApp $1 $2 (panic "fixity") $3) }

exp10 :: { LHsExpr RdrName }
	: '\\' aexp aexps opt_asig '->' exp	
			{% checkPatterns ($2 : reverse $3) >>= \ ps -> 
1188
			   return (LL $ HsLam (mkMatchGroup [LL $ Match ps $4
1189
					    (GRHSs (unguardedRHS $6) emptyLocalBinds
1190
							)])) }
1191 1192
  	| 'let' binds 'in' exp			{ LL $ HsLet (unLoc $2) $4 }
	| 'if' exp 'then' exp 'else' exp	{ LL $ HsIf $2 $4 $6 }
1193
   	| 'case' exp 'of' altslist		{ LL $ HsCase $2 (mkMatchGroup (un