TcBinds.hs 79.9 KB
Newer Older
Austin Seipp's avatar
Austin Seipp committed
1 2 3 4
{-
(c) The University of Glasgow 2006
(c) The GRASP/AQUA Project, Glasgow University, 1992-1998

5
\section[TcBinds]{TcBinds}
Austin Seipp's avatar
Austin Seipp committed
6
-}
7

8 9
{-# LANGUAGE CPP, RankNTypes, ScopedTypeVariables #-}

10
module TcBinds ( tcLocalBinds, tcTopBinds, tcRecSelBinds,
11
                 tcValBinds, tcHsBootSigs, tcPolyCheck,
12
                 tcSpecPrags, tcSpecWrapper,
13
                 tcVectDecls, addTypecheckedBinds,
14 15
                 TcSigInfo(..), TcSigFun,
                 TcPragEnv, mkPragEnv,
16
                 instTcTySig, instTcTySigFromId, findScopedTyVars,
Facundo Domínguez's avatar
Facundo Domínguez committed
17
                 badBootDeclErr, mkExport ) where
18

ross's avatar
ross committed
19
import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
20
import {-# SOURCE #-} TcExpr  ( tcMonoExpr )
21
import {-# SOURCE #-} TcPatSyn ( tcInferPatSynDecl, tcCheckPatSynDecl, tcPatSynBuilderBind )
Simon Marlow's avatar
Simon Marlow committed
22 23
import DynFlags
import HsSyn
24
import HscTypes( isHsBoot )
25
import TcRnMonad
Simon Marlow's avatar
Simon Marlow committed
26 27 28
import TcEnv
import TcUnify
import TcSimplify
29
import TcEvidence
Simon Marlow's avatar
Simon Marlow committed
30 31 32
import TcHsType
import TcPat
import TcMType
cactus's avatar
cactus committed
33
import ConLike
34
import Inst( deeplyInstantiate )
35 36
import FamInstEnv( normaliseType )
import FamInst( tcGetFamInstEnvs )
37
import TyCon
Simon Marlow's avatar
Simon Marlow committed
38 39
import TcType
import TysPrim
40
import TysWiredIn
Simon Marlow's avatar
Simon Marlow committed
41
import Id
42
import Var
43
import VarSet
44
import VarEnv( TidyEnv )
45
import Module
Simon Marlow's avatar
Simon Marlow committed
46
import Name
47
import NameSet
48
import NameEnv
Simon Marlow's avatar
Simon Marlow committed
49
import SrcLoc
50
import Bag
Matthew Pickering's avatar
Matthew Pickering committed
51
import PatSyn
52
import ListSetOps
Simon Marlow's avatar
Simon Marlow committed
53 54 55 56 57
import ErrUtils
import Digraph
import Maybes
import Util
import BasicTypes
58
import Outputable
59
import FastString
60
import Type(mkStrLitTy)
61
import PrelNames( gHC_PRIM )
62
import TcValidity (checkValidType)
63 64

import Control.Monad
65
import Data.List (partition)
66 67

#include "HsVersions.h"
68

69 70 71 72 73 74 75 76 77 78 79 80 81 82 83
{- *********************************************************************
*                                                                      *
               A useful helper function
*                                                                      *
********************************************************************* -}

addTypecheckedBinds :: TcGblEnv -> [LHsBinds Id] -> TcGblEnv
addTypecheckedBinds tcg_env binds
  | isHsBoot (tcg_src tcg_env) = tcg_env
    -- Do not add the code for record-selector bindings
    -- when compiling hs-boot files
  | otherwise = tcg_env { tcg_binds = foldr unionBags
                                            (tcg_binds tcg_env)
                                            binds }

Austin Seipp's avatar
Austin Seipp committed
84 85 86
{-
************************************************************************
*                                                                      *
87
\subsection{Type-checking bindings}
Austin Seipp's avatar
Austin Seipp committed
88 89
*                                                                      *
************************************************************************
90

91
@tcBindsAndThen@ typechecks a @HsBinds@.  The "and then" part is because
92 93 94 95 96 97 98 99 100 101
it needs to know something about the {\em usage} of the things bound,
so that it can create specialisations of them.  So @tcBindsAndThen@
takes a function which, given an extended environment, E, typechecks
the scope of the bindings returning a typechecked thing and (most
important) an LIE.  It is this LIE which is then used as the basis for
specialising the things bound.

@tcBindsAndThen@ also takes a "combiner" which glues together the
bindings and the "thing" to make a new "thing".

102
The real work is done by @tcBindWithSigsAndThen@.
103 104 105 106 107 108 109 110 111 112

Recursive and non-recursive binds are handled in essentially the same
way: because of uniques there are no scoping issues left.  The only
difference is that non-recursive bindings can bind primitive values.

Even for non-recursive binding groups we add typings for each binder
to the LVE for the following reason.  When each individual binding is
checked the type of its LHS is unified with that of its RHS; and
type-checking the LHS of course requires that the binder is in scope.

113 114 115
At the top-level the LIE is sure to contain nothing but constant
dictionaries, which we resolve at the module level.

116 117
Note [Polymorphic recursion]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~
118
The game plan for polymorphic recursion in the code above is
119 120

        * Bind any variable for which we have a type signature
121
          to an Id with a polymorphic type.  Then when type-checking
122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173
          the RHSs we'll make a full polymorphic call.

This fine, but if you aren't a bit careful you end up with a horrendous
amount of partial application and (worse) a huge space leak. For example:

        f :: Eq a => [a] -> [a]
        f xs = ...f...

If we don't take care, after typechecking we get

        f = /\a -> \d::Eq a -> let f' = f a d
                               in
                               \ys:[a] -> ...f'...

Notice the the stupid construction of (f a d), which is of course
identical to the function we're executing.  In this case, the
polymorphic recursion isn't being used (but that's a very common case).
This can lead to a massive space leak, from the following top-level defn
(post-typechecking)

        ff :: [Int] -> [Int]
        ff = f Int dEqInt

Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
f' is another thunk which evaluates to the same thing... and you end
up with a chain of identical values all hung onto by the CAF ff.

        ff = f Int dEqInt

           = let f' = f Int dEqInt in \ys. ...f'...

           = let f' = let f' = f Int dEqInt in \ys. ...f'...
                      in \ys. ...f'...

Etc.

NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
which would make the space leak go away in this case

Solution: when typechecking the RHSs we always have in hand the
*monomorphic* Ids for each binding.  So we just need to make sure that
if (Method f a d) shows up in the constraints emerging from (...f...)
we just use the monomorphic Id.  We achieve this by adding monomorphic Ids
to the "givens" when simplifying constraints.  That's what the "lies_avail"
is doing.

Then we get

        f = /\a -> \d::Eq a -> letrec
                                 fm = \ys:[a] -> ...fm...
                               in
                               fm
Austin Seipp's avatar
Austin Seipp committed
174
-}
175

176 177 178 179
tcTopBinds :: HsValBinds Name -> TcM (TcGblEnv, TcLclEnv)
-- The TcGblEnv contains the new tcg_binds and tcg_spects
-- The TcLclEnv has an extended type envt for the new bindings
tcTopBinds (ValBindsOut binds sigs)
cactus's avatar
cactus committed
180 181 182 183 184
  = do  { -- Pattern synonym bindings populate the global environment
          (binds', (tcg_env, tcl_env)) <- tcValBinds TopLevel binds sigs $
            do { gbl <- getGblEnv
               ; lcl <- getLclEnv
               ; return (gbl, lcl) }
185 186
        ; specs <- tcImpPrags sigs   -- SPECIALISE prags for imported Ids

187 188
        ; let { tcg_env' = tcg_env { tcg_imp_specs = specs ++ tcg_imp_specs tcg_env }
                           `addTypecheckedBinds` map snd binds' }
189 190

        ; return (tcg_env', tcl_env) }
191
        -- The top level bindings are flattened into a giant
Ian Lynagh's avatar
Ian Lynagh committed
192
        -- implicitly-mutually-recursive LHsBinds
cactus's avatar
cactus committed
193

194 195 196 197
tcTopBinds (ValBindsIn {}) = panic "tcTopBinds"

tcRecSelBinds :: HsValBinds Name -> TcM TcGblEnv
tcRecSelBinds (ValBindsOut binds sigs)
198 199 200 201
  = -- tcExtendGlobalValEnv [sel_id | L _ (IdSig sel_id) <- sigs] $
    -- this envt extension happens in tcValBinds
    do { (rec_sel_binds, tcg_env) <- discardWarnings $
                                     tcValBinds TopLevel binds sigs getGblEnv
202
       ; let tcg_env'
203
              | isHsBoot (tcg_src tcg_env) = tcg_env
204 205 206
              | otherwise = tcg_env { tcg_binds = foldr (unionBags . snd)
                                                        (tcg_binds tcg_env)
                                                        rec_sel_binds }
207 208
              -- Do not add the code for record-selector bindings
              -- when compiling hs-boot files
209 210
       ; return tcg_env' }
tcRecSelBinds (ValBindsIn {}) = panic "tcRecSelBinds"
211

212
tcHsBootSigs :: HsValBinds Name -> TcM [Id]
213 214
-- A hs-boot file has only one BindGroup, and it only has type
-- signatures in it.  The renamer checked all this
215
tcHsBootSigs (ValBindsOut binds sigs)
Ian Lynagh's avatar
Ian Lynagh committed
216
  = do  { checkTc (null binds) badBootDeclErr
217
        ; concat <$> mapM (addLocM tc_boot_sig) (filter isTypeLSig sigs) }
218
  where
219
    tc_boot_sig (TypeSig lnames hs_ty _) = mapM f lnames
220
      where
221 222 223
        f (L _ name)
          = do { sigma_ty <- tcHsSigType (FunSigCtxt name False) hs_ty
               ; return (mkVanillaGlobal name sigma_ty) }
Ian Lynagh's avatar
Ian Lynagh committed
224
        -- Notice that we make GlobalIds, not LocalIds
Ian Lynagh's avatar
Ian Lynagh committed
225
    tc_boot_sig s = pprPanic "tcHsBootSigs/tc_boot_sig" (ppr s)
226
tcHsBootSigs groups = pprPanic "tcHsBootSigs" (ppr groups)
227

228
badBootDeclErr :: MsgDoc
Ian Lynagh's avatar
Ian Lynagh committed
229
badBootDeclErr = ptext (sLit "Illegal declarations in an hs-boot file")
230

231 232
------------------------
tcLocalBinds :: HsLocalBinds Name -> TcM thing
Ian Lynagh's avatar
Ian Lynagh committed
233
             -> TcM (HsLocalBinds TcId, thing)
sof's avatar
sof committed
234

235
tcLocalBinds EmptyLocalBinds thing_inside
Ian Lynagh's avatar
Ian Lynagh committed
236 237
  = do  { thing <- thing_inside
        ; return (EmptyLocalBinds, thing) }
sof's avatar
sof committed
238

239 240 241 242
tcLocalBinds (HsValBinds (ValBindsOut binds sigs)) thing_inside
  = do  { (binds', thing) <- tcValBinds NotTopLevel binds sigs thing_inside
        ; return (HsValBinds (ValBindsOut binds' sigs), thing) }
tcLocalBinds (HsValBinds (ValBindsIn {})) _ = panic "tcLocalBinds"
243

244
tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
245
  = do  { (given_ips, ip_binds') <-
246
            mapAndUnzipM (wrapLocSndM (tc_ip_bind ipClass)) ip_binds
247

248
        -- If the binding binds ?x = E, we  must now
Ian Lynagh's avatar
Ian Lynagh committed
249
        -- discharge any ?x constraints in expr_lie
250
        -- See Note [Implicit parameter untouchables]
251
        ; (ev_binds, result) <- checkConstraints (IPSkol ips)
252
                                  [] given_ips thing_inside
253 254

        ; return (HsIPBinds (IPBinds ip_binds' ev_binds), result) }
255
  where
Alan Zimmerman's avatar
Alan Zimmerman committed
256
    ips = [ip | L _ (IPBind (Left (L _ ip)) _) <- ip_binds]
257

Ian Lynagh's avatar
Ian Lynagh committed
258 259 260
        -- I wonder if we should do these one at at time
        -- Consider     ?x = 4
        --              ?y = ?x + 1
Alan Zimmerman's avatar
Alan Zimmerman committed
261
    tc_ip_bind ipClass (IPBind (Left (L _ ip)) expr)
262
       = do { ty <- newFlexiTyVarTy openTypeKind
263 264
            ; let p = mkStrLitTy $ hsIPNameFS ip
            ; ip_id <- newDict ipClass [ p, ty ]
265
            ; expr' <- tcMonoExpr expr ty
266 267 268 269 270 271
            ; let d = toDict ipClass p ty `fmap` expr'
            ; return (ip_id, (IPBind (Right ip_id) d)) }
    tc_ip_bind _ (IPBind (Right {}) _) = panic "tc_ip_bind"

    -- Coerces a `t` into a dictionry for `IP "x" t`.
    -- co : t -> IP "x" t
272 273
    toDict ipClass x ty = HsWrap $ mkWpCast $ TcCoercion $
                          wrapIP $ mkClassPred ipClass [x,ty]
274

Austin Seipp's avatar
Austin Seipp committed
275
{-
276 277 278 279 280 281 282
Note [Implicit parameter untouchables]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
We add the type variables in the types of the implicit parameters
as untouchables, not so much because we really must not unify them,
but rather because we otherwise end up with constraints like this
    Num alpha, Implic { wanted = alpha ~ Int }
The constraint solver solves alpha~Int by unification, but then
283
doesn't float that solved constraint out (it's not an unsolved
284
wanted).  Result disaster: the (Num alpha) is again solved, this
285 286
time by defaulting.  No no no.

287
However [Oct 10] this is all handled automatically by the
288 289
untouchable-range idea.

290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311
Note [Placeholder PatSyn kinds]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Consider this (Trac #9161)

  {-# LANGUAGE PatternSynonyms, DataKinds #-}
  pattern A = ()
  b :: A
  b = undefined

Here, the type signature for b mentions A.  But A is a pattern
synonym, which is typechecked (for very good reasons; a view pattern
in the RHS may mention a value binding) as part of a group of
bindings.  It is entirely resonable to reject this, but to do so
we need A to be in the kind environment when kind-checking the signature for B.

Hence the tcExtendKindEnv2 patsyn_placeholder_kinds, which adds a binding
    A -> AGlobal (AConLike (PatSynCon _|_))
to the environment. Then TcHsType.tcTyVar will find A in the kind environment,
and will give a 'wrongThingErr' as a result.  But the lookup of A won't fail.

The _|_ (= panic "fakePatSynCon") works because the wrongThingErr call, in
tcTyVar, doesn't look inside the TcTyThing.
312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358

Note [Inlining and hs-boot files]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Consider this example (Trac #10083):

    ---------- RSR.hs-boot ------------
    module RSR where
      data RSR
      eqRSR :: RSR -> RSR -> Bool

    ---------- SR.hs ------------
    module SR where
      import {-# SOURCE #-} RSR
      data SR = MkSR RSR
      eqSR (MkSR r1) (MkSR r2) = eqRSR r1 r2

    ---------- RSR.hs ------------
    module RSR where
      import SR
      data RSR = MkRSR SR -- deriving( Eq )
      eqRSR (MkRSR s1) (MkRSR s2) = (eqSR s1 s2)
      foo x y = not (eqRSR x y)

When compiling RSR we get this code

    RSR.eqRSR :: RSR -> RSR -> Bool
    RSR.eqRSR = \ (ds1 :: RSR.RSR) (ds2 :: RSR.RSR) ->
                case ds1 of _ { RSR.MkRSR s1 ->
                case ds2 of _ { RSR.MkRSR s2 ->
                SR.eqSR s1 s2 }}

    RSR.foo :: RSR -> RSR -> Bool
    RSR.foo = \ (x :: RSR) (y :: RSR) -> not (RSR.eqRSR x y)

Now, when optimising foo:
    Inline eqRSR (small, non-rec)
    Inline eqSR  (small, non-rec)
but the result of inlining eqSR from SR is another call to eqRSR, so
everything repeats.  Neither eqSR nor eqRSR are (apparently) loop
breakers.

Solution: when compiling RSR, add a NOINLINE pragma to every function
exported by the boot-file for RSR (if it exists).

ALAS: doing so makes the boostrappted GHC itself slower by 8% overall
      (on Trac #9872a-d, and T1969.  So I un-did this change, and
      parked it for now.  Sigh.
Austin Seipp's avatar
Austin Seipp committed
359
-}
360

361
tcValBinds :: TopLevelFlag
362 363
           -> [(RecFlag, LHsBinds Name)] -> [LSig Name]
           -> TcM thing
364
           -> TcM ([(RecFlag, LHsBinds TcId)], thing)
365

366
tcValBinds top_lvl binds sigs thing_inside
367
  = do  {  -- Typecheck the signature
368
        ; (poly_ids, sig_fn) <- tcExtendKindEnv2 patsyn_placeholder_kinds $
thomasw's avatar
thomasw committed
369
                                         -- See Note [Placeholder PatSyn kinds]
370
                                tcTySigs sigs
Ian Lynagh's avatar
Ian Lynagh committed
371

372 373 374 375 376 377 378 379 380 381 382 383 384
        ; _self_boot <- tcSelfBootInfo
        ; let prag_fn = mkPragEnv sigs (foldr (unionBags . snd) emptyBag binds)

-- -------  See Note [Inlining and hs-boot files] (change parked) --------
--              prag_fn | isTopLevel top_lvl   -- See Note [Inlining and hs-boot files]
--                      , SelfBoot { sb_ids = boot_id_names } <- self_boot
--                      = foldNameSet add_no_inl prag_fn1 boot_id_names
--                      | otherwise
--                      = prag_fn1
--              add_no_inl boot_id_name prag_fn
--                = extendPragEnv prag_fn (boot_id_name, no_inl_sig boot_id_name)
--              no_inl_sig name = L boot_loc (InlineSig (L boot_loc name) neverInlinePragma)
--              boot_loc = mkGeneralSrcSpan (fsLit "The hs-boot file for this module")
Ian Lynagh's avatar
Ian Lynagh committed
385

386 387 388 389 390
                -- Extend the envt right away with all the Ids
                -- declared with complete type signatures
                -- Do not extend the TcIdBinderStack; instead
                -- we extend it on a per-rhs basis in tcExtendForRhs
        ; tcExtendLetEnvIds top_lvl [(idName id, id) | id <- poly_ids] $ do
391 392
            { (binds', (extra_binds', thing)) <- tcBindGroups top_lvl sig_fn prag_fn binds $ do
                   { thing <- thing_inside
393 394 395
                     -- See Note [Pattern synonym builders don't yield dependencies]
                   ; patsyn_builders <- mapM tcPatSynBuilderBind patsyns
                   ; let extra_binds = [ (NonRecursive, builder) | builder <- patsyn_builders ]
396 397
                   ; return (extra_binds, thing) }
             ; return (binds' ++ extra_binds', thing) }}
398
  where
399
    patsyns = [psb | (_, lbinds) <- binds, L _ (PatSynBind psb) <- bagToList lbinds]
400
    patsyn_placeholder_kinds -- See Note [Placeholder PatSyn kinds]
401
      = [(name, placeholder_patsyn_tything)| PSB{ psb_id = L _ name } <- patsyns ]
402
    placeholder_patsyn_tything
403
      = AGlobal $ AConLike $ PatSynCon $ panic "fakePatSynCon"
404

405
------------------------
406
tcBindGroups :: TopLevelFlag -> TcSigFun -> TcPragEnv
Ian Lynagh's avatar
Ian Lynagh committed
407 408
             -> [(RecFlag, LHsBinds Name)] -> TcM thing
             -> TcM ([(RecFlag, LHsBinds TcId)], thing)
409 410
-- Typecheck a whole lot of value bindings,
-- one strongly-connected component at a time
411
-- Here a "strongly connected component" has the strightforward
412
-- meaning of a group of bindings that mention each other,
413
-- ignoring type signatures (that part comes later)
414

415
tcBindGroups _ _ _ [] thing_inside
Ian Lynagh's avatar
Ian Lynagh committed
416 417
  = do  { thing <- thing_inside
        ; return ([], thing) }
418

419
tcBindGroups top_lvl sig_fn prag_fn (group : groups) thing_inside
Ian Lynagh's avatar
Ian Lynagh committed
420
  = do  { (group', (groups', thing))
421
                <- tc_group top_lvl sig_fn prag_fn group $
422
                   tcBindGroups top_lvl sig_fn prag_fn groups thing_inside
Ian Lynagh's avatar
Ian Lynagh committed
423
        ; return (group' ++ groups', thing) }
sof's avatar
sof committed
424

425
------------------------
426
tc_group :: forall thing.
427
            TopLevelFlag -> TcSigFun -> TcPragEnv
Ian Lynagh's avatar
Ian Lynagh committed
428 429
         -> (RecFlag, LHsBinds Name) -> TcM thing
         -> TcM ([(RecFlag, LHsBinds TcId)], thing)
430 431

-- Typecheck one strongly-connected component of the original program.
432
-- We get a list of groups back, because there may
433 434
-- be specialisations etc as well

435
tc_group top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
Ian Lynagh's avatar
Ian Lynagh committed
436 437
        -- A single non-recursive binding
        -- We want to keep non-recursive things non-recursive
438
        -- so that we desugar unlifted bindings correctly
cactus's avatar
cactus committed
439 440
  = do { let bind = case bagToList binds of
                 [bind] -> bind
441 442
                 []     -> panic "tc_group: empty list of binds"
                 _      -> panic "tc_group: NonRecursive binds is not a singleton bag"
cactus's avatar
cactus committed
443 444
       ; (bind', thing) <- tc_single top_lvl sig_fn prag_fn bind thing_inside
       ; return ( [(NonRecursive, bind')], thing) }
445 446

tc_group top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
447 448
  =     -- To maximise polymorphism, we do a new
        -- strongly-connected-component analysis, this time omitting
Ian Lynagh's avatar
Ian Lynagh committed
449
        -- any references to variables with type signatures.
450
        -- (This used to be optional, but isn't now.)
451
    do  { traceTc "tc_group rec" (pprLHsBinds binds)
cactus's avatar
cactus committed
452
        ; when hasPatSyn $ recursivePatSynErr binds
453
        ; (binds1, thing) <- go sccs
454
        ; return ([(Recursive, binds1)], thing) }
Ian Lynagh's avatar
Ian Lynagh committed
455
                -- Rec them all together
456
  where
457
    hasPatSyn = anyBag (isPatSyn . unLoc) binds
cactus's avatar
cactus committed
458 459 460
    isPatSyn PatSynBind{} = True
    isPatSyn _ = False

461
    sccs :: [SCC (LHsBind Name)]
462 463
    sccs = stronglyConnCompFromEdgedVertices (mkEdges sig_fn binds)

464
    go :: [SCC (LHsBind Name)] -> TcM (LHsBinds TcId, thing)
465 466
    go (scc:sccs) = do  { (binds1, ids1) <- tc_scc scc
                        ; (binds2, thing) <- tcExtendLetEnv top_lvl ids1 $
467 468 469
                                             go sccs
                        ; return (binds1 `unionBags` binds2, thing) }
    go []         = do  { thing <- thing_inside; return (emptyBag, thing) }
470

471 472
    tc_scc (AcyclicSCC bind) = tc_sub_group NonRecursive [bind]
    tc_scc (CyclicSCC binds) = tc_sub_group Recursive    binds
sof's avatar
sof committed
473

474
    tc_sub_group = tcPolyBinds top_lvl sig_fn prag_fn Recursive
sof's avatar
sof committed
475

cactus's avatar
cactus committed
476 477 478 479
recursivePatSynErr :: OutputableBndr name => LHsBinds name -> TcM a
recursivePatSynErr binds
  = failWithTc $
    hang (ptext (sLit "Recursive pattern synonym definition with following bindings:"))
480
       2 (vcat $ map pprLBind . bagToList $ binds)
cactus's avatar
cactus committed
481 482 483 484 485 486
  where
    pprLoc loc  = parens (ptext (sLit "defined at") <+> ppr loc)
    pprLBind (L loc bind) = pprWithCommas ppr (collectHsBindBinders bind) <+>
                            pprLoc loc

tc_single :: forall thing.
487
            TopLevelFlag -> TcSigFun -> TcPragEnv
488
          -> LHsBind Name -> TcM thing
cactus's avatar
cactus committed
489
          -> TcM (LHsBinds TcId, thing)
490
tc_single _top_lvl sig_fn _prag_fn (L _ (PatSynBind psb@PSB{ psb_id = L _ name })) thing_inside
Matthew Pickering's avatar
Matthew Pickering committed
491
  = do { (pat_syn, aux_binds, tcg_env) <- tc_pat_syn_decl
cactus's avatar
cactus committed
492
       ; let tything = AConLike (PatSynCon pat_syn)
Matthew Pickering's avatar
Matthew Pickering committed
493
       ; thing <- setGblEnv tcg_env  $ tcExtendGlobalEnv [tything] thing_inside
cactus's avatar
cactus committed
494 495
       ; return (aux_binds, thing)
       }
496
  where
Matthew Pickering's avatar
Matthew Pickering committed
497
    tc_pat_syn_decl :: TcM (PatSyn, LHsBinds TcId, TcGblEnv)
498
    tc_pat_syn_decl = case sig_fn name of
499 500 501
        Nothing                 -> tcInferPatSynDecl psb
        Just (TcPatSynSig tpsi) -> tcCheckPatSynDecl psb tpsi
        Just                 _  -> panic "tc_single"
502

cactus's avatar
cactus committed
503
tc_single top_lvl sig_fn prag_fn lbind thing_inside
504 505 506 507
  = do { (binds1, ids) <- tcPolyBinds top_lvl sig_fn prag_fn
                                      NonRecursive NonRecursive
                                      [lbind]
       ; thing <- tcExtendLetEnv top_lvl ids thing_inside
cactus's avatar
cactus committed
508
       ; return (binds1, thing) }
509

510
------------------------
511
mkEdges :: TcSigFun -> LHsBinds Name -> [Node BKey (LHsBind Name)]
512

513
type BKey = Int -- Just number off the bindings
514 515

mkEdges sig_fn binds
516
  = [ (bind, key, [key | n <- nameSetElems (bind_fvs (unLoc bind)),
Ian Lynagh's avatar
Ian Lynagh committed
517
                         Just key <- [lookupNameEnv key_map n], no_sig n ])
518 519 520 521
    | (bind, key) <- keyd_binds
    ]
  where
    no_sig :: Name -> Bool
thomasw's avatar
thomasw committed
522
    no_sig n = noCompleteSig (sig_fn n)
523 524 525

    keyd_binds = bagToList binds `zip` [0::BKey ..]

Ian Lynagh's avatar
Ian Lynagh committed
526
    key_map :: NameEnv BKey     -- Which binding it comes from
527
    key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
528
                                     , bndr <- collectHsBindBinders bind ]
529

530
------------------------
531
tcPolyBinds :: TopLevelFlag -> TcSigFun -> TcPragEnv
532 533 534 535
            -> RecFlag         -- Whether the group is really recursive
            -> RecFlag         -- Whether it's recursive after breaking
                               -- dependencies based on type signatures
            -> [LHsBind Name]  -- None are PatSynBind
536
            -> TcM (LHsBinds TcId, [TcId])
537

538
-- Typechecks a single bunch of values bindings all together,
539 540 541
-- and generalises them.  The bunch may be only part of a recursive
-- group, because we use type signatures to maximise polymorphism
--
542 543
-- Returns a list because the input may be a single non-recursive binding,
-- in which case the dependency order of the resulting bindings is
544 545
-- important.
--
546
-- Knows nothing about the scope of the bindings
547
-- None of the bindings are pattern synonyms
548

549 550
tcPolyBinds top_lvl sig_fn prag_fn rec_group rec_tc bind_list
  = setSrcSpan loc                              $
551
    recoverM (recoveryCode binder_names sig_fn) $ do
552
        -- Set up main recover; take advantage of any type sigs
553

554
    { traceTc "------------------------------------------------" Outputable.empty
555
    ; traceTc "Bindings for {" (ppr binder_names)
556
    ; dflags   <- getDynFlags
557
    ; type_env <- getLclTypeEnv
558
    ; let plan = decideGeneralisationPlan dflags type_env
559
                         binder_names bind_list sig_fn
560
    ; traceTc "Generalisation plan" (ppr plan)
561 562 563 564
    ; result@(tc_binds, poly_ids) <- case plan of
         NoGen              -> tcPolyNoGen rec_tc prag_fn sig_fn bind_list
         InferGen mn        -> tcPolyInfer rec_tc prag_fn sig_fn mn bind_list
         CheckGen lbind sig -> tcPolyCheck rec_tc prag_fn sig lbind
565

chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
566
        -- Check whether strict bindings are ok
Ian Lynagh's avatar
Ian Lynagh committed
567 568
        -- These must be non-recursive etc, and are not generalised
        -- They desugar to a case expression in the end
569 570 571 572
    ; checkStrictBinds top_lvl rec_group bind_list tc_binds poly_ids
    ; traceTc "} End of bindings for" (vcat [ ppr binder_names, ppr rec_group
                                            , vcat [ppr id <+> ppr (idType id) | id <- poly_ids]
                                          ])
573

574
    ; return result }
575
  where
576 577
    binder_names = collectHsBindListBinders bind_list
    loc = foldr1 combineSrcSpans (map getLoc bind_list)
578
         -- The mbinds have been dependency analysed and
579
         -- may no longer be adjacent; so find the narrowest
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
580
         -- span that includes them all
581

582
------------------
583
tcPolyNoGen     -- No generalisation whatsoever
584
  :: RecFlag       -- Whether it's recursive after breaking
585
                   -- dependencies based on type signatures
586
  -> TcPragEnv -> TcSigFun
587
  -> [LHsBind Name]
588
  -> TcM (LHsBinds TcId, [TcId])
589

590 591
tcPolyNoGen rec_tc prag_fn tc_sig_fn bind_list
  = do { (binds', mono_infos) <- tcMonoBinds rec_tc tc_sig_fn
592
                                             (LetGblBndr prag_fn)
593
                                             bind_list
594
       ; mono_ids' <- mapM tc_mono_info mono_infos
595
       ; return (binds', mono_ids') }
596 597
  where
    tc_mono_info (name, _, mono_id)
598
      = do { mono_ty' <- zonkTcType (idType mono_id)
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
599
             -- Zonk, mainly to expose unboxed types to checkStrictBinds
600
           ; let mono_id' = setIdType mono_id mono_ty'
601
           ; _specs <- tcSpecPrags mono_id' (lookupPragEnv prag_fn name)
602
           ; return mono_id' }
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
603 604 605 606
           -- NB: tcPrags generates error messages for
           --     specialisation pragmas for non-overloaded sigs
           -- Indeed that is why we call it here!
           -- So we can safely ignore _specs
607 608

------------------
609
tcPolyCheck :: RecFlag       -- Whether it's recursive after breaking
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
610
                             -- dependencies based on type signatures
611
            -> TcPragEnv
612
            -> TcIdSigInfo
613
            -> LHsBind Name
614
            -> TcM (LHsBinds TcId, [TcId])
615
-- There is just one binding,
616
--   it binds a single variable,
Simon Peyton Jones's avatar
Simon Peyton Jones committed
617
--   it has a complete type signature,
618
tcPolyCheck rec_tc prag_fn
619 620 621 622 623 624
            sig@(TISI { sig_bndr  = CompleteSig poly_id
                      , sig_tvs   = tvs_w_scoped
                      , sig_theta = theta
                      , sig_tau   = tau
                      , sig_ctxt  = ctxt
                      , sig_loc   = loc })
625
            bind
626 627
  = do { ev_vars <- newEvVars theta
       ; let skol_info = SigSkol ctxt (mkPhiTy theta tau)
628
             prag_sigs = lookupPragEnv prag_fn name
629
             tvs = map snd tvs_w_scoped
630 631 632 633
                 -- Find the location of the original source type sig, if
                 -- there is was one.  This will appear in messages like
                 -- "type variable x is bound by .. at <loc>"
             name = idName poly_id
634 635
       ; (ev_binds, (binds', [mono_info]))
            <- setSrcSpan loc $
636
               checkConstraints skol_info tvs ev_vars $
637
               tcMonoBinds rec_tc (\_ -> Just (TcIdSig sig)) LetLclBndr [bind]
638

639 640
       ; spec_prags <- tcSpecPrags poly_id prag_sigs
       ; poly_id    <- addInlinePrags poly_id prag_sigs
641

642 643 644 645 646
       ; let (_, _, mono_id) = mono_info
             export = ABE { abe_wrap = idHsWrapper
                          , abe_poly = poly_id
                          , abe_mono = mono_id
                          , abe_prags = SpecPrags spec_prags }
647
             abs_bind = L loc $ AbsBinds
648
                        { abs_tvs = tvs
649
                        , abs_ev_vars = ev_vars, abs_ev_binds = [ev_binds]
650
                        , abs_exports = [export], abs_binds = binds' }
651
       ; return (unitBag abs_bind, [poly_id]) }
652

653 654 655
tcPolyCheck _rec_tc _prag_fn sig _bind
  = pprPanic "tcPolyCheck" (ppr sig)

656
------------------
657
tcPolyInfer
658
  :: RecFlag       -- Whether it's recursive after breaking
659
                   -- dependencies based on type signatures
660
  -> TcPragEnv -> TcSigFun
661
  -> Bool         -- True <=> apply the monomorphism restriction
662
  -> [LHsBind Name]
663 664
  -> TcM (LHsBinds TcId, [TcId])
tcPolyInfer rec_tc prag_fn tc_sig_fn mono bind_list
665 666
  = do { ((binds', mono_infos), tclvl, wanted)
             <- pushLevelAndCaptureConstraints  $
667
                tcMonoBinds rec_tc tc_sig_fn LetLclBndr bind_list
668

669
       ; let name_taus = [(name, idType mono_id) | (name, _, mono_id) <- mono_infos]
670 671
             sig_qtvs   = [ tv | (_, Just sig, _) <- mono_infos
                               , (_, tv) <- sig_tvs sig ]
672
       ; traceTc "simplifyInfer call" (ppr name_taus $$ ppr wanted)
673
       ; (qtvs, givens, ev_binds)
674
                 <- simplifyInfer tclvl mono sig_qtvs name_taus wanted
675

676
       ; let inferred_theta = map evVarPred givens
677 678
       ; exports <- checkNoErrs $
                    mapM (mkExport prag_fn qtvs inferred_theta) mono_infos
thomasw's avatar
thomasw committed
679

680
       ; loc <- getSrcSpanM
681
       ; let poly_ids = map abe_poly exports
682
             abs_bind = L loc $
683
                        AbsBinds { abs_tvs = qtvs
684
                                 , abs_ev_vars = givens, abs_ev_binds = [ev_binds]
685
                                 , abs_exports = exports, abs_binds = binds' }
686

687 688
       ; traceTc "Binding:" (ppr (poly_ids `zip` map idType poly_ids))
       ; return (unitBag abs_bind, poly_ids) }
689
         -- poly_ids are guaranteed zonked by mkExport
690 691

--------------
692
mkExport :: TcPragEnv
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
693
         -> [TyVar] -> TcThetaType      -- Both already zonked
Ian Lynagh's avatar
Ian Lynagh committed
694
         -> MonoBindInfo
695
         -> TcM (ABExport Id)
696 697 698 699
-- Only called for generalisation plan IferGen, not by CheckGen or NoGen
--
-- mkExport generates exports with
--      zonked type variables,
Ian Lynagh's avatar
Ian Lynagh committed
700
--      zonked poly_ids
701 702 703 704
-- The former is just because no further unifications will change
-- the quantified type variables, so we can fix their final form
-- right now.
-- The latter is needed because the poly_ids are used to extend the
705
-- type environment; see the invariant on TcEnv.tcExtendIdEnv
706

707
-- Pre-condition: the qtvs and theta are already zonked
708

thomasw's avatar
thomasw committed
709
mkExport prag_fn qtvs inferred_theta (poly_name, mb_sig, mono_id)
710
  = do  { mono_ty <- zonkTcType (idType mono_id)
711

712 713 714
        ; (poly_id, inferred) <- case mb_sig of
              Nothing  -> do { poly_id <- mkInferredPolyId poly_name qtvs inferred_theta mono_ty
                             ; return (poly_id, True) }
715
              Just sig | Just poly_id <- completeIdSigPolyId_maybe sig
716 717 718 719 720
                       -> return (poly_id, False)
                       | otherwise
                       -> do { final_theta <- completeTheta inferred_theta sig
                             ; poly_id <- mkInferredPolyId poly_name qtvs final_theta mono_ty
                             ; return (poly_id, True) }
721 722

        -- NB: poly_id has a zonked type
723
        ; poly_id <- addInlinePrags poly_id prag_sigs
724
        ; spec_prags <- tcSpecPrags poly_id prag_sigs
Ian Lynagh's avatar
Ian Lynagh committed
725
                -- tcPrags requires a zonked poly_id
726

thomasw's avatar
thomasw committed
727
        ; let sel_poly_ty = mkSigmaTy qtvs inferred_theta mono_ty
728
        ; traceTc "mkExport: check sig"
thomasw's avatar
thomasw committed
729
                  (vcat [ ppr poly_name, ppr sel_poly_ty, ppr (idType poly_id) ])
730

Gabor Greif's avatar
Gabor Greif committed
731
        -- Perform the impedance-matching and ambiguity check
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
732 733
        -- right away.  If it fails, we want to fail now (and recover
        -- in tcPolyBinds).  If we delay checking, we get an error cascade.
734
        -- Remember we are in the tcPolyInfer case, so the type envt is
chak@cse.unsw.edu.au.'s avatar
chak@cse.unsw.edu.au. committed
735 736
        -- closed (unless we are doing NoMonoLocalBinds in which case all bets
        -- are off)
737
        -- See Note [Impedence matching]
738
        ; (wrap, wanted) <- addErrCtxtM (mk_bind_msg inferred True poly_name (idType poly_id)) $
739
                            captureConstraints $
740
                            tcSubType_NC sig_ctxt sel_poly_ty (idType poly_id)
741
        ; ev_binds <- simplifyTop wanted
742 743 744 745

        ; return (ABE { abe_wrap = mkWpLet (EvBinds ev_binds) <.> wrap
                      , abe_poly = poly_id
                      , abe_mono = mono_id
746
                      , abe_prags = SpecPrags spec_prags}) }
747
  where
748
    prag_sigs = lookupPragEnv prag_fn poly_name
749
    sig_ctxt  = InfSigCtxt poly_name
750 751 752 753 754 755

mkInferredPolyId :: Name -> [TyVar] -> TcThetaType -> TcType -> TcM Id
-- In the inference case (no signature) this stuff figures out
-- the right type variables and theta to quantify over
-- See Note [Validity of inferred types]
mkInferredPolyId poly_name qtvs theta mono_ty
756 757 758
  = do { fam_envs <- tcGetFamInstEnvs

       ; let (_co, norm_mono_ty) = normaliseType fam_envs Nominal mono_ty
759 760
               -- Unification may not have normalised the type,
               -- (see Note [Lazy flattening] in TcFlatten) so do it
761 762 763
               -- here to make it as uncomplicated as possible.
               -- Example: f :: [F Int] -> Bool
               -- should be rewritten to f :: [Char] -> Bool, if possible
764

765
             my_tvs2 = closeOverKinds (growThetaTyVars theta (tyVarsOfType norm_mono_ty))
766
                  -- Include kind variables!  Trac #7916
767

768 769
       ; my_theta <- pickQuantifiablePreds my_tvs2 theta

Simon Peyton Jones's avatar
Simon Peyton Jones committed
770
       ; let my_tvs = filter (`elemVarSet` my_tvs2) qtvs   -- Maintain original order
771 772 773 774
             inferred_poly_ty = mkSigmaTy my_tvs my_theta norm_mono_ty

       ; addErrCtxtM (mk_bind_msg True False poly_name inferred_poly_ty) $
         checkValidType (InfSigCtxt poly_name) inferred_poly_ty
775

776
       ; return (mkLocalId poly_name inferred_poly_ty) }
777 778 779

mk_bind_msg :: Bool -> Bool -> Name -> TcType -> TidyEnv -> TcM (TidyEnv, SDoc)
mk_bind_msg inferred want_ambig poly_name poly_ty tidy_env
780 781
 = do { (tidy_env', tidy_ty) <- zonkTidyTcType tidy_env poly_ty
      ; return (tidy_env', mk_msg tidy_ty) }
782
 where
783 784 785 786 787
   mk_msg ty = vcat [ ptext (sLit "When checking that") <+> quotes (ppr poly_name)
                      <+> ptext (sLit "has the") <+> what <+> ptext (sLit "type")
                    , nest 2 (ppr poly_name <+> dcolon <+> ppr ty)
                    , ppWhen want_ambig $
                      ptext (sLit "Probable cause: the inferred type is ambiguous") ]
788 789
   what | inferred  = ptext (sLit "inferred")
        | otherwise = ptext (sLit "specified")
thomasw's avatar
thomasw committed
790 791 792 793 794 795


-- | Report the inferred constraints for an extra-constraints wildcard/hole as
-- an error message, unless the PartialTypeSignatures flag is enabled. In this
-- case, the extra inferred constraints are accepted without complaining.
-- Returns the annotated constraints combined with the inferred constraints.
796
completeTheta :: TcThetaType -> TcIdSigInfo -> TcM TcThetaType
thomasw's avatar
thomasw committed
797
completeTheta inferred_theta
798 799 800
              (TISI { sig_bndr  = s_bndr
                    , sig_theta = annotated_theta })
  | PartialSig { sig_cts = Just loc } <- s_bndr
thomasw's avatar
thomasw committed
801 802 803 804 805 806 807
  = do { annotated_theta <- zonkTcThetaType annotated_theta
       ; let inferred_diff = minusList inferred_theta annotated_theta
             final_theta   = annotated_theta ++ inferred_diff
       ; partial_sigs      <- xoptM Opt_PartialTypeSignatures
       ; warn_partial_sigs <- woptM Opt_WarnPartialTypeSignatures
       ; msg <- mkLongErrAt loc (mk_msg inferred_diff partial_sigs) empty
       ; case partial_sigs of
808
           True | warn_partial_sigs -> reportWarning msg
thomasw's avatar
thomasw committed
809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824
                | otherwise         -> return ()
           False                    -> reportError msg
       ; return final_theta }

  | otherwise
  = zonkTcThetaType annotated_theta
    -- No extra-constraints wildcard means no extra constraints will be added
    -- to the context, so just return the possibly empty (zonked)
    -- annotated_theta.
  where
    pts_hint = text "To use the inferred type, enable PartialTypeSignatures"
    mk_msg inferred_diff suppress_hint
       = vcat [ hang ((text "Found hole") <+> quotes (char '_'))
                   2 (text "with inferred constraints:")
                      <+> pprTheta inferred_diff
              , if suppress_hint then empty else pts_hint
825
              , typeSigCtxt s_bndr ]
826

Austin Seipp's avatar
Austin Seipp committed
827
{-
828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850
Note [Partial type signatures and generalisation]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
When we have a partial type signature, like
   f :: _ -> Int
then we *always* use the InferGen plan, and hence tcPolyInfer.
We do this even for a local binding with -XMonoLocalBinds.
Reasons:
  * The TcSigInfo for 'f' has a unification variable for the '_',
    whose TcLevel is one level deeper than the current level.
    (See pushTcLevelM in tcTySig.)  But NoGen doesn't increase
    the TcLevel like InferGen, so we lose the level invariant.

  * The signature might be   f :: forall a. _ -> a
    so it really is polymorphic.  It's not clear what it would
    mean to use NoGen on this, and indeed the ASSERT in tcLhs,
    in the (Just sig) case, checks that if there is a signature
    then we are using LetLclBndr, and hence a nested AbsBinds with
    increased TcLevel

It might be possible to fix these difficulties somehow, but there
doesn't seem much point.  Indeed, adding a partial type signature is a
way to get per-binding inferred generalisation.

851 852
Note [Validity of inferred types]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
853
We need to check inferred type for validity, in case it uses language
854 855 856 857 858 859 860 861 862 863
extensions that are not turned on.  The principle is that if the user
simply adds the inferred type to the program source, it'll compile fine.
See #8883.

Examples that might fail:
 - an inferred theta that requires type equalities e.g. (F a ~ G b)
                                or multi-parameter type classes
 - an inferred type that includes unboxed tuples

However we don't do the ambiguity check (checkValidType omits it for