configure.ac 44.3 KB
Newer Older
1
dnl == autoconf source for the Glasgow FP tools ==
2
dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
sof's avatar
sof committed
3
dnl  (or some such) to see the outline of this file)
4 5
dnl
#
6
# (c) The University of Glasgow 1994-2012
7
#
8
# Configure script template for GHC
9
#
10
# Process with 'autoreconf' to get a working configure script.
11
#
sof's avatar
sof committed
12 13 14 15
# For the generated configure script, do "./configure --help" to
# see what flags are available. (Better yet, read the documentation!)
#

16
AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.9.0], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17

18
# Set this to YES for a released version, otherwise NO
19
: ${RELEASE=NO}
20

21
# The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22
# above.  If this is not a released version, then we will append the
23
# date to the version number (e.g. 7.4.20111220).  The date is
24
# constructed by finding the date of the most recent patch in the
25
# git repository.  If this is a source distribution (not a git
26 27 28
# checkout), then we ship a file 'VERSION' containing the full version
# when the source distribution was created.

29
if test ! -f mk/config.h.in; then
Ben Gamari's avatar
Ben Gamari committed
30
   echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31 32 33
   exit 1
fi

34 35
AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])

36 37 38 39 40
dnl this makes sure `./configure --target=<cross-compile-target>`
dnl works as expected, since we're slightly modifying how Autoconf
dnl interprets build/host/target and how this interacts with $CC tests
test -n "$target_alias" && ac_tool_prefix=$target_alias-

41
dnl ----------------------------------------------------------
42
dnl ** Find unixy sort and find commands,
43 44 45 46
dnl ** which are needed by FP_SETUP_PROJECT_VERSION

dnl ** Find find command (for Win32's benefit)
FP_PROG_FIND
47
FP_PROG_SORT
48 49

dnl ----------------------------------------------------------
50 51 52 53
FP_SETUP_PROJECT_VERSION

# Hmmm, we fix the RPM release number to 1 here... Is this convenient?
AC_SUBST([release], [1])
54

55
# First off, a distrib sanity check..
56
AC_CONFIG_SRCDIR([mk/config.mk.in])
57

58 59 60 61 62 63 64 65
dnl * We require autoconf version 2.69 due to
dnl   https://bugs.ruby-lang.org/issues/8179. Also see #14910.
dnl * We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
dnl * We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
dnl * Using autoconf 2.59 started to give nonsense like this
dnl     #define SIZEOF_CHAR 0
dnl   recently.
AC_PREREQ([2.69])
66

67 68 69
# -------------------------------------------------------------------------
# Prepare to generate the following header files
#
70 71
#
AC_CONFIG_HEADER(mk/config.h)
72

sof's avatar
sof committed
73
# No, semi-sadly, we don't do `--srcdir'...
74
if test x"$srcdir" != 'x.' ; then
75
    echo "This configuration does not support the \`--srcdir' option.."
76 77 78
    exit 1
fi

sof's avatar
sof committed
79 80 81 82 83 84 85 86 87 88
dnl --------------------------------------------------------------
dnl * Project specific configuration options
dnl --------------------------------------------------------------
dnl What follows is a bunch of options that can either be configured
dnl through command line options to the configure script or by
dnl supplying defns in the build tree's mk/build.mk. Having the option to
dnl use either is considered a Feature.

dnl ** What command to use to compile compiler sources ?
dnl --------------------------------------------------------------
89

90 91
AC_ARG_VAR(GHC,[Use as the path to GHC [default=autodetect]])
AC_PATH_PROG([GHC], [ghc])
92
AC_ARG_WITH([ghc],
93 94 95
        AS_HELP_STRING([--with-ghc=ARG], [Use ARG as the path to ghc (obsolete, use GHC=ARG instead) [default=autodetect]]),
        AC_MSG_ERROR([--with-ghc=$withval is obsolete (use './configure GHC=$withval' or 'GHC=$withval ./configure' instead)]))
AC_SUBST(WithGhc,$GHC)
96

97
dnl ** Tell the make system which OS we are using
98
dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
99 100
AC_SUBST(OSTYPE)

Ian Lynagh's avatar
Ian Lynagh committed
101 102 103 104 105 106 107
AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
[AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
                [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
        EnableBootstrapWithDevelSnaphost=YES,
        EnableBootstrapWithDevelSnaphost=NO
)

108 109 110 111 112 113
AC_ARG_ENABLE(tarballs-autodownload,
[AC_HELP_STRING([--enable-tarballs-autodownload],
                [Automatically download Windows distribution binaries if needed.])],
        TarballsAutodownload=YES,
        TarballsAutodownload=NO
)
114

115 116 117 118 119 120 121 122 123 124 125
AC_ARG_ENABLE(distro-toolchain,
[AC_HELP_STRING([--enable-distro-toolchain],
                [Do not use bundled Windows toolchain binaries.])],
        EnableDistroToolchain=YES,
        EnableDistroToolchain=NO
)

if test "$EnableDistroToolchain" = "YES"; then
  TarballsAutodownload=NO
fi

126 127 128 129
dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
dnl but instead used by stage0 for bootstrapping stage1
AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])

130 131
if test "$WithGhc" != ""; then
  FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
Ian Lynagh's avatar
Ian Lynagh committed
132

133
  if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
134
     AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
Ian Lynagh's avatar
Ian Lynagh committed
135 136
  fi

137 138 139 140
  AC_SUBST(GhcVersion)dnl
  AC_SUBST(GhcMajVersion)dnl
  AC_SUBST(GhcMinVersion)dnl
  AC_SUBST(GhcPatchLevel)dnl
141 142
  GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
  GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
143

144 145 146 147 148
  dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
  if test -z "$CC_STAGE0"; then
    BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
  fi

149
  BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
150 151 152
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
  BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
153 154
fi

155
dnl ** Must have GHC to build GHC
ian@well-typed.com's avatar
ian@well-typed.com committed
156 157 158 159
if test "$WithGhc" = ""
then
    AC_MSG_ERROR([GHC is required.])
fi
Ryan Scott's avatar
Ryan Scott committed
160 161
FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.4],
    [AC_MSG_ERROR([GHC version 8.4 or later is required to compile GHC.])])
Simon Marlow's avatar
Simon Marlow committed
162

ian@well-typed.com's avatar
ian@well-typed.com committed
163 164 165 166
if test `expr $GhcMinVersion % 2` = "1"
then
    if test "$EnableBootstrapWithDevelSnaphost" = "NO"
    then
Simon Marlow's avatar
Simon Marlow committed
167 168 169 170
        AC_MSG_ERROR([
     $WithGhc is a development snapshot of GHC, version $GhcVersion.
     Bootstrapping using this version of GHC is not supported, and may not
     work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
171
     or 'GHC=' to specify a different GHC to use.])
ian@well-typed.com's avatar
ian@well-typed.com committed
172 173
    fi
fi
174

175
GHC_PACKAGE_DB_FLAG=package-db
ian@well-typed.com's avatar
ian@well-typed.com committed
176
AC_SUBST(GHC_PACKAGE_DB_FLAG)
Simon Marlow's avatar
Simon Marlow committed
177

178 179 180
# GHC is passed to Cabal, so we need a native path
if test "${WithGhc}" != ""
then
181
    ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
182

183
    if test "$ghc_host_os" = "mingw32"
184
    then
185 186 187 188 189 190 191
        if test "${OSTYPE}" = "msys"
        then
            WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
        else
            # Canonicalise to <drive>:/path/to/ghc
            WithGhc=`cygpath -m "${WithGhc}"`
        fi
192 193 194 195 196
        echo "GHC path canonicalised to: ${WithGhc}"
    fi
fi
AC_SUBST([WithGhc])

197 198 199
dnl ** Without optimization some INLINE trickery fails for GHCi
SRC_CC_OPTS="-O"

200 201 202
dnl--------------------------------------------------------------------
dnl * Choose host(/target/build) platform
dnl--------------------------------------------------------------------
203 204
dnl If we aren't explicitly told what values to use with configure flags,
dnl we ask the bootstrapping compiler what platform it is for
205

206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221
if test "${WithGhc}" != ""
then
        bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        if test "$bootstrap_host" != "$bootstrap_target"
        then
                echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
        fi
fi

# We have to run these unconditionally, but we may discard their
# results in the following code
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

222
FPTOOLS_SET_PLATFORM_VARS
223

224 225
# Verify that the installed (bootstrap) GHC is capable of generating
# code for the requested build platform.
ian@well-typed.com's avatar
ian@well-typed.com committed
226 227 228 229 230 231 232
if test "$BuildPlatform" != "$bootstrap_target"
then
    echo "This GHC (${WithGhc}) does not generate code for the build platform"
    echo "   GHC target platform    : $bootstrap_target"
    echo "   Desired build platform : $BuildPlatform"
    exit 1
fi
233

234 235
# Testing if we shall enable shared libs support on Solaris.
# Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
236

237
SOLARIS_BROKEN_SHLD=NO
238

239 240 241 242 243
case $host in
     i386-*-solaris2)
     # here we go with the test
     MINOR=`uname -r|cut -d '.' -f 2-`
     if test "$MINOR" -lt "11"; then
244
         SOLARIS_BROKEN_SHLD=YES
245 246 247
     fi
     ;;
esac
248

249 250
AC_SUBST(SOLARIS_BROKEN_SHLD)

251 252
dnl ** Do an unregisterised build?
dnl --------------------------------------------------------------
253
case "$TargetArch" in
254
    i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273
        UnregisterisedDefault=NO
        ;;
    *)
        UnregisterisedDefault=YES
        ;;
esac
AC_ARG_ENABLE(unregisterised,
[AC_HELP_STRING([--enable-unregisterised],
[Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
[ if test x"$enableval" = x"yes"; then
        Unregisterised=YES
  else
        Unregisterised=NO
  fi
],
[Unregisterised="$UnregisterisedDefault"]
)
AC_SUBST(Unregisterised)

274 275 276 277 278 279 280 281 282 283 284 285
dnl ** Does target have runtime linker support?
dnl --------------------------------------------------------------
case "$target" in
    powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
        HaskellHaveRTSLinker=NO
        ;;
    *)
        HaskellHaveRTSLinker=YES
        ;;
esac
AC_SUBST(HaskellHaveRTSLinker)

286 287 288
# Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
FP_FIND_ROOT

289
fail() {
290 291 292 293 294
    echo >&2
    echo "$1" >&2
    exit 1
}

295

296 297
if test "$HostOS" = "mingw32"
then
298
    # Find the mingw-w64 7z file to extract.
299 300
    # NB. If you update the tarballs to a new version of gcc, don't
    # forget to tweak the paths in driver/gcc/gcc.c.
301 302 303 304 305 306 307 308 309 310 311 312
    if test "$HostArch" = "i386"
    then
        mingw_arch="i686"
        tarball_dest_dir="mingw-w64/x86"
        tarball_mingw_dir="mingw32"
    else
        mingw_arch="x86_64"
        tarball_dest_dir="mingw-w64/x86_64"
        tarball_mingw_dir="mingw64"
    fi
fi

313 314 315 316
set_up_tarballs() {
    AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
    local action
    if test "$TarballsAutodownload" = "NO"
317
    then
318
        action="verify"
319
    else
320
        action="download"
321
    fi
322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346
    mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
    case $? in
        0)
           rm missing-win32-tarballs
           ;;
        2)
           echo
           echo "Error:"
           echo "Needed msys2 tarballs are missing. You have a few options to get them,"
           echo
           echo "  * run configure with the --enable-tarballs-autodownload option"
           echo
           echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
           echo
           echo "  * manually download the files listed in ./missing-win32-tarballs and place"
           echo "    them in the ghc-tarballs directory."
           echo
           exit 1
           ;;
        *)
           echo
           echo "Error fetching msys2 tarballs; see errors above."
           exit 1
           ;;
    esac
347 348 349 350 351 352

    # Extract all the tarballs in one go
    if ! test -d inplace/mingw
    then
        AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
        rm -rf inplace/mingw
353
        local base_dir="../ghc-tarballs/${tarball_dest_dir}"
354 355 356 357 358 359 360 361 362
        ( cd inplace &&
        find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
        rm ".MTREE" &&
        rm ".PKGINFO" &&
        cd .. ) || fail "Error: Could not extract Windows toolchains."

        mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
        touch inplace/mingw

363 364 365 366 367 368
        # NB. Now since the GCC is hardcoded to use /mingw32 we need to
        # make a wrapper around it to give it the proper paths
        mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
        PATH=`pwd`/inplace/mingw/bin:$PATH
        inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe

369 370 371 372
        AC_MSG_NOTICE([In-tree MingW-w64 tree created])
    fi
}

373
if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
374 375 376 377 378 379
then
    test -d inplace || mkdir inplace

    # NB. Download and extract the MingW-w64 distribution if required
    set_up_tarballs

380
    mingwbin="$hardtop/inplace/mingw/bin/"
381 382 383
    CC="${mingwbin}gcc.exe"
    LD="${mingwbin}ld.exe"
    NM="${mingwbin}nm.exe"
384
    RANLIB="${mingwbin}ranlib.exe"
385
    OBJDUMP="${mingwbin}objdump.exe"
Ian Lynagh's avatar
Ian Lynagh committed
386
    fp_prog_ar="${mingwbin}ar.exe"
387

388
    AC_PATH_PROG([Genlib],[genlib])
389 390
fi

391 392 393 394 395 396 397 398 399 400 401 402 403 404
# We don't want to bundle a MinGW-w64 toolchain
# So we have to find these individual tools.
if test "$EnableDistroToolchain" = "YES"
then
    # Ideally should use AC_CHECK_TARGET_TOOL but our triples
    # are screwed up. Configure doesn't think they're ever equal and
    # so never tried without the prefix.
    AC_PATH_PROG([CC],[gcc], [clang])
    AC_PATH_PROG([NM],[nm])
    AC_PATH_PROG([AR],[ar])
    AC_PATH_PROG([RANLIB],[ranlib])
    AC_PATH_PROG([OBJDUMP],[objdump])
    AC_PATH_PROG([DllWrap],[dllwrap])
    AC_PATH_PROG([Windres],[windres])
405
    AC_PATH_PROG([Genlib],[genlib])
406 407 408 409
else
    AC_CHECK_TARGET_TOOL([Windres],[windres])
    AC_CHECK_TARGET_TOOL([DllWrap],[dllwrap])
    AC_CHECK_TARGET_TOOL([OBJDUMP],[objdump])
Tamar Christina's avatar
Tamar Christina committed
410
fi
411

Tamar Christina's avatar
Tamar Christina committed
412 413
DllWrapCmd="$DllWrap"
WindresCmd="$Windres"
414

415 416 417 418 419 420 421 422 423
HAVE_GENLIB=False
if test "$HostOS" = "mingw32"
then
    if test "$Genlib" != ""; then
        GenlibCmd="$(cygpath -m $Genlib)"
        HAVE_GENLIB=True
    fi
fi

Tamar Christina's avatar
Tamar Christina committed
424 425
AC_SUBST([DllWrapCmd])
AC_SUBST([WindresCmd])
426 427
AC_SUBST([GenlibCmd])
AC_SUBST([HAVE_GENLIB])
428

Ian Lynagh's avatar
Ian Lynagh committed
429 430
FP_ICONV
FP_GMP
431
FP_CURSES
Ian Lynagh's avatar
Ian Lynagh committed
432

433
XCODE_VERSION()
Ian Lynagh's avatar
Ian Lynagh committed
434

435

436 437 438 439
dnl ** Building a cross compiler?
dnl --------------------------------------------------------------
CrossCompiling=NO
# If 'host' and 'target' differ, then this means we are building a cross-compiler.
Tamar Christina's avatar
Tamar Christina committed
440
if test "$TargetPlatform" != "$HostPlatform" ; then
441 442 443 444 445 446
    CrossCompiling=YES
    cross_compiling=yes   # This tells configure that it can accept just 'target',
                          # otherwise you get
                          #   configure: error: cannot run C compiled programs.
                          #   If you meant to cross compile, use `--host'.
fi
447
if test "$BuildPlatform" != "$HostPlatform" ; then
448 449 450
   AC_MSG_ERROR([
You've selected:

Tamar Christina's avatar
Tamar Christina committed
451 452 453
  BUILD:  $BuildPlatform   (the architecture we're building on)
  HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
  TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
454

Simon Marlow's avatar
Simon Marlow committed
455 456 457 458
BUILD must equal HOST; that is, we do not support building GHC itself
with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
1 will be a cross-compiler, and stage 2 will be the cross-compiled
GHC.
459 460
])
fi
461 462 463
# Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
# in calls to subproject configure scripts and thus must be set to the autoconf
# triple, not the normalized GHC triple that TargetPlatform is set to.
464 465 466 467 468 469 470 471
#
# We use the non-canonicalized triple, target_alias, here since the subproject
# configure scripts will use this triple to construct the names of the toolchain
# executables. If we instead passed down the triple produced by
# AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
# name (this is a known problem in the case of the Android NDK, which has
# slightly odd triples).
#
Gabor Greif's avatar
Gabor Greif committed
472
# It may be better to just do away with the GHC triples altogether. This would
473 474 475
# all be taken care of for us if we configured the subprojects using
# AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
# configuration.
476 477
#
# We also use non-canonicalized triple when install stage1 crosscompiler
478 479 480 481 482 483 484
if test -z "${target_alias}"
then
  # --target wasn't given; use result from AC_CANONICAL_TARGET
  TargetPlatformFull="${target}"
else
  TargetPlatformFull="${target_alias}"
fi
485 486 487 488 489 490 491
if test "$CrossCompiling" = "YES"
then
  # Use value passed by user from --target=
  CrossCompilePrefix="${TargetPlatformFull}-"
else
  CrossCompilePrefix=""
fi
Simon Marlow's avatar
Simon Marlow committed
492
AC_SUBST(CrossCompiling)
493 494
AC_SUBST(CrossCompilePrefix)
AC_SUBST(TargetPlatformFull)
495
AC_SUBST(EnableDistroToolchain)
496

497 498 499
dnl ** Which gcc to use?
dnl --------------------------------------------------------------

500 501 502 503 504 505 506 507 508 509 510 511
AC_ARG_WITH([gcc],
        AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
        AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))

AC_ARG_WITH([clang],
        AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
        AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))

dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
dnl later CC is copied to CC_STAGE{1,2,3}
AC_PROG_CC([gcc clang])

512 513
MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])

514 515 516
dnl make extensions visible to allow feature-tests to detect them lateron
AC_USE_SYSTEM_EXTENSIONS

thomie's avatar
thomie committed
517 518 519
dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
AC_PROG_CPP

520 521
# --with-hs-cpp/--with-hs-cpp-flags
FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
thomie's avatar
thomie committed
522 523
AC_SUBST([HaskellCPPCmd])
AC_SUBST([HaskellCPPArgs])
524

525 526 527 528 529
FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])

John Ericson's avatar
John Ericson committed
530
dnl ** Which ld to use
531
dnl --------------------------------------------------------------
532
AC_ARG_VAR(LD,[Use as the path to ld. See also --disable-ld-override.])
533 534 535 536
FIND_LD([$target],[GccUseLdOpt])
CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
LdCmd="$LD"
537
LdNoGoldCmd="$LD_NO_GOLD"
538
CFLAGS="$CFLAGS $GccUseLdOpt"
539
AC_SUBST([LdCmd])
540
AC_SUBST([LdNoGoldCmd])
541

John Ericson's avatar
John Ericson committed
542 543 544 545 546
FP_PROG_LD_IS_GNU
FP_PROG_LD_BUILD_ID
FP_PROG_LD_NO_COMPACT_UNWIND
FP_PROG_LD_FILELIST

547 548
dnl ** Which nm to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
549 550 551 552 553 554 555 556
if test "$HostOS" != "mingw32"; then
    AC_CHECK_TARGET_TOOL([NM], [nm])
    if test "$NM" = ":"; then
        AC_MSG_ERROR([cannot find nm in your PATH])
    fi
fi
NmCmd="$NM"
AC_SUBST([NmCmd])
557 558 559 560 561

if test "$TargetOS_CPP" = "darwin"
then
    AC_MSG_CHECKING(whether nm program is broken)
    # Some versions of XCode ship a broken version of `nm`. Detect and work
562
    # around this issue. See : https://gitlab.haskell.org/ghc/ghc/issues/11744
563 564 565 566 567 568
    nmver=$(${NM} --version | grep version | sed 's/ //g')
    case "$nmver" in
        LLVMversion7.3.0|LLVMversion7.3.1)
            AC_MSG_RESULT(yes)
            echo "The detected nm program is broken."
            echo
569
            echo "See: https://gitlab.haskell.org/ghc/ghc/issues/11744"
570 571 572
            echo
            echo "Try re-running configure with:"
            echo
Alex Biehl's avatar
Alex Biehl committed
573
            echo '   NM=$(xcrun --find nm-classic) ./configure'
574 575 576 577 578 579 580 581 582
            echo
            exit 1
            ;;
        *)
            AC_MSG_RESULT(no)
            ;;
        esac
fi

583 584
dnl ** Which objdump to use?
dnl --------------------------------------------------------------
585 586
dnl Note: we may not have objdump on OS X, and we only need it on
dnl Windows (for DLL checks), OpenBSD, and AIX
Ben Gamari's avatar
Ben Gamari committed
587
case $HostOS_CPP in
588
  cygwin32|mingw32|openbsd|aix)
Ben Gamari's avatar
Ben Gamari committed
589 590 591 592
    AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
    ;;
esac

593 594 595
ObjdumpCmd="$OBJDUMP"
AC_SUBST([ObjdumpCmd])

596 597
dnl ** Which ranlib to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
598 599 600 601
AC_PROG_RANLIB
if test "$RANLIB" = ":"; then
    AC_MSG_ERROR([cannot find ranlib in your PATH])
fi
602
RanlibCmd="$RANLIB"
John Ericson's avatar
John Ericson committed
603
AC_SUBST([RanlibCmd])
604

605 606 607 608 609 610 611
dnl ** which strip to use?
dnl --------------------------------------------------------------
AC_CHECK_TARGET_TOOL([STRIP], [strip])
StripCmd="$STRIP"
AC_SUBST([StripCmd])


Moritz Angermann's avatar
Moritz Angermann committed
612 613
dnl ** which libtool to use?
dnl --------------------------------------------------------------
614 615
# The host normalization on Windows breaks autoconf, it no longer
# thinks that target == host so it never checks the unqualified
616
# tools for Windows. See #14274.
617 618 619 620 621 622 623 624 625
if test "$HostOS" = "mingw32"
then
    AC_PATH_PROG([LIBTOOL],[libtool])
    LibtoolCmd="$(cygpath -m $LIBTOOL)"
else
    AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
    LibtoolCmd="$LIBTOOL"
fi
AC_SUBST([LibtoolCmd])
626

627 628 629 630
# Here is where we re-target which specific version of the LLVM
# tools we are looking for. In the past, GHC supported a number of
# versions of LLVM simultaneously, but that stopped working around
# 3.5/3.6 release of LLVM.
Erik de Castro Lopo's avatar
Erik de Castro Lopo committed
631
LlvmVersion=7
632
AC_SUBST([LlvmVersion])
633 634
sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
635

Moritz Angermann's avatar
Moritz Angermann committed
636 637
dnl ** Which LLVM clang to use?
dnl --------------------------------------------------------------
638
AC_ARG_VAR(CLANG,[Use as the path to clang [default=autodetect]])
Moritz Angermann's avatar
Moritz Angermann committed
639 640 641 642
AC_CHECK_TARGET_TOOL([CLANG], [clang])
ClangCmd="$CLANG"
AC_SUBST([ClangCmd])

643 644
dnl ** Which LLVM llc to use?
dnl --------------------------------------------------------------
645
AC_ARG_VAR(LLC,[Use as the path to LLVM's llc [default=autodetect]])
Ben Gamari's avatar
Ben Gamari committed
646
FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
647 648 649 650 651
LlcCmd="$LLC"
AC_SUBST([LlcCmd])

dnl ** Which LLVM opt to use?
dnl --------------------------------------------------------------
652
AC_ARG_VAR(OPT,[Use as the path to LLVM's opt [default=autodetect]])
Ben Gamari's avatar
Ben Gamari committed
653
FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
654 655 656
OptCmd="$OPT"
AC_SUBST([OptCmd])

sof's avatar
sof committed
657 658 659 660
dnl --------------------------------------------------------------
dnl End of configure script option section
dnl --------------------------------------------------------------

661 662 663
dnl ** Copy the files from the "fs" utility into the right folders.
dnl --------------------------------------------------------------
AC_MSG_NOTICE([Creating links for in-tree file handling routines.])
Ben Gamari's avatar
Ben Gamari committed
664 665 666 667 668
ln -f utils/fs/fs.* utils/lndir/
ln -f utils/fs/fs.* utils/unlit/
ln -f utils/fs/fs.* rts/
ln -f utils/fs/fs.h libraries/base/include/
ln -f utils/fs/fs.c libraries/base/cbits/
669
AC_MSG_NOTICE([Routines in place. Packages can now be build normally.])
sof's avatar
sof committed
670 671

dnl --------------------------------------------------------------
672 673 674
dnl ** Can the unix package be built?
dnl --------------------------------------------------------------

675 676 677
if test "$TargetOS" = "mingw32"
then
    GhcLibsWithUnix=NO
678
else
679
    GhcLibsWithUnix=YES
680 681 682
fi
AC_SUBST([GhcLibsWithUnix])

683 684
dnl ** does #! work?
AC_SYS_INTERPRETER()
sof's avatar
sof committed
685

rrt's avatar
rrt committed
686 687
dnl ** look for GCC and find out which version
dnl     Figure out which C compiler to use.  Gcc is preferred.
Gabor Greif's avatar
Gabor Greif committed
688
dnl     If gcc, make sure it's at least 3.0
rrt's avatar
rrt committed
689
dnl
690
FP_GCC_VERSION
691

Ben Gamari's avatar
Ben Gamari committed
692 693 694
dnl ** See whether gcc supports -no-pie
FP_GCC_SUPPORTS_NO_PIE

695 696 697 698 699
dnl ** Used to determine how to compile ghc-prim's atomics.c, used by
dnl    unregisterised, Sparc, and PPC backends.
FP_GCC_SUPPORTS__ATOMICS
AC_DEFINE([HAVE_C11_ATOMICS], [$CONF_GCC_SUPPORTS__ATOMICS], [Does GCC support __atomic primitives?])

John Ericson's avatar
John Ericson committed
700 701
FP_GCC_EXTRA_FLAGS

702 703 704 705
dnl ** look to see if we have a C compiler using an llvm back end.
dnl
FP_CC_LLVM_BACKEND

706 707 708 709
FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
710
# Stage 3 won't be supported by cross-compilation
711

712 713
# See rules/distdir-way-opts.mk for details.
# Flags passed to the C compiler
714 715 716
AC_SUBST(CONF_CC_OPTS_STAGE0)
AC_SUBST(CONF_CC_OPTS_STAGE1)
AC_SUBST(CONF_CC_OPTS_STAGE2)
717
# Flags passed to the C compiler when we ask it to link
718 719 720
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
721
# Flags passed to the linker when we ask it to link
722 723 724
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
725
# Flags passed to the C preprocessor
726 727 728
AC_SUBST(CONF_CPP_OPTS_STAGE0)
AC_SUBST(CONF_CPP_OPTS_STAGE1)
AC_SUBST(CONF_CPP_OPTS_STAGE2)
729 730 731 732
# Flags passed to the Haskell compiler
AC_SUBST(CONF_HC_OPTS_STAGE0)
AC_SUBST(CONF_HC_OPTS_STAGE1)
AC_SUBST(CONF_HC_OPTS_STAGE2)
rrt's avatar
rrt committed
733

734 735 736 737 738
dnl ** Set up the variables for the platform in the settings file.
dnl May need to use gcc to find platform details.
dnl --------------------------------------------------------------
FPTOOLS_SET_HASKELL_PLATFORM_VARS

739
dnl ** figure out how to do context diffs
740
FP_PROG_CONTEXT_DIFF
sof's avatar
sof committed
741

742 743 744
dnl Let's make sure install-sh is executable here.  If we got it from
dnl a darcs repo, it might not be (see bug #978).
chmod +x install-sh
745 746
dnl ** figure out how to do a BSD-ish install
AC_PROG_INSTALL
sof's avatar
sof committed
747

sof's avatar
sof committed
748
dnl ** how to invoke `ar' and `ranlib'
749
FP_PROG_AR_SUPPORTS_ATFILE
750
FP_PROG_AR_NEEDS_RANLIB
sof's avatar
sof committed
751

752
dnl ** Check to see whether ln -s works
sof's avatar
sof committed
753 754
AC_PROG_LN_S

755
FP_SETTINGS
sof's avatar
sof committed
756 757

dnl ** Find the path to sed
Ian Lynagh's avatar
Ian Lynagh committed
758
AC_PATH_PROGS(SedCmd,gsed sed,sed)
sof's avatar
sof committed
759

sof's avatar
sof committed
760 761

dnl ** check for time command
sof's avatar
sof committed
762 763
AC_PATH_PROG(TimeCmd,time)

sof's avatar
sof committed
764 765
dnl ** check for tar
dnl   if GNU tar is named gtar, look for it first.
766
AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
sof's avatar
sof committed
767

768 769 770 771 772
dnl ** check for compressors
AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
AC_PATH_PROGS(GzipCmd,gzip, gzip)
AC_PATH_PROGS(XzCmd,pxz xz, xz)

Ian Lynagh's avatar
Ian Lynagh committed
773 774 775 776
dnl ** check for patch
dnl if GNU patch is named gpatch, look for it first
AC_PATH_PROGS(PatchCmd,gpatch patch, patch)

777 778 779
dnl ** check for autoreconf
AC_PATH_PROG(AutoreconfCmd, autoreconf, autoreconf)

780
dnl ** check for dtrace (currently only implemented for Mac OS X)
781 782 783 784 785 786 787
AC_ARG_ENABLE(dtrace,
    [AC_HELP_STRING([--enable-dtrace],
        [Enable DTrace])],
    EnableDtrace=$enableval,
    EnableDtrace=yes
)

788
HaveDtrace=NO
789

790
AC_PATH_PROG(DtraceCmd,dtrace)
791 792 793 794 795 796 797
if test "x$EnableDtrace" = "xyes"; then
  if test -n "$DtraceCmd"; then
    if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
      -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
      -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
      HaveDtrace=YES
    fi
798 799 800 801
  fi
fi
AC_SUBST(HaveDtrace)

802
AC_PATH_PROG(HSCOLOUR,HsColour)
803
# HsColour is passed to Cabal, so we need a native path
804
if test "$HostOS"      = "mingw32" && \
805
   test "${OSTYPE}"   != "msys"    && \
806
   test "${HSCOLOUR}" != ""
807 808 809
then
    # Canonicalise to <drive>:/path/to/gcc
    HSCOLOUR=`cygpath -m ${HSCOLOUR}`
810
fi
811

812
dnl ** check for Sphinx toolchain
813 814
AC_PATH_PROG(SPHINXBUILD,sphinx-build)
AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
815 816
changequote(, )dnl
[if test -n "$SPHINXBUILD"; then
817
  fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/.* v\?\([0-9]\.[0-9]\.[0-9]\)/\1/' | head -n1`;
818 819 820
fi;
changequote([, ])dnl
])
821 822
FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
    [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
823 824 825

dnl ** check for xelatex
AC_PATH_PROG(XELATEX,xelatex)
826

reid's avatar
reid committed
827
dnl ** check for ghc-pkg command
828
FP_PROG_GHC_PKG
reid's avatar
reid committed
829

sof's avatar
sof committed
830
dnl ** check for installed happy binary + version
831 832

AC_ARG_VAR(HAPPY,[Use as the path to happy [default=autodetect]])
sof's avatar
sof committed
833
FPTOOLS_HAPPY
sof's avatar
sof committed
834

835
dnl ** check for installed alex binary + version
836 837

AC_ARG_VAR(ALEX,[Use as the path to alex [default=autodetect]])
838 839
FPTOOLS_ALEX

sof's avatar
sof committed
840 841 842
dnl --------------------------------------------------
dnl ### program checking section ends here ###
dnl --------------------------------------------------
sof's avatar
sof committed
843

sof's avatar
sof committed
844 845 846
dnl --------------------------------------------------
dnl * Platform header file and syscall feature tests
dnl ### checking the state of the local header files and syscalls ###
sof's avatar
sof committed
847

848 849
dnl ** check for full ANSI header (.h) files
AC_HEADER_STDC
sof's avatar
sof committed
850

851 852 853 854
dnl ** Enable large file support.  NB. do this before testing the type of
dnl    off_t, because it will affect the result of that test.
AC_SYS_LARGEFILE

855
dnl ** check for specific header (.h) files that we are interested in
856
AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
857 858 859 860 861 862 863

dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
AC_CHECK_HEADERS([sys/cpuset.h], [], [],
[[#if HAVE_SYS_PARAM_H
# include <sys/param.h>
#endif
]])
864

865 866
dnl ** check if it is safe to include both <time.h> and <sys/time.h>
AC_HEADER_TIME
sof's avatar
sof committed
867

868
dnl ** do we have long longs?
869
AC_CHECK_TYPES([long long])
870

reid's avatar
reid committed
871
dnl ** what are the sizes of various types
872 873 874 875 876
FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
877
if test "$ac_cv_type_long_long" = yes; then
878
FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
879
fi
880 881 882 883
FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
884
if test "$ac_cv_type_long_long" = yes; then
885
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
886
fi
887 888 889 890 891 892 893 894 895 896 897 898
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)

FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)

reid's avatar
reid committed
899

900
dnl for use in settings file
901
TargetWordSize=$ac_cv_sizeof_void_p
Moritz Angermann's avatar
Moritz Angermann committed
902 903 904 905 906
if test "x$TargetWordSize" == 8; then
  AC_SUBST([Cabal64bit],[True])
else
  AC_SUBST([Cabal64bit],[False])
fi
907
AC_SUBST(TargetWordSize)
908 909
FP_CHECK_FUNC([WinExec],
  [@%:@include <windows.h>], [WinExec("",0)])
reid's avatar
reid committed
910

911 912
FP_CHECK_FUNC([GetModuleFileName],
  [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
reid's avatar
reid committed
913 914

dnl ** check for more functions
915
dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
916
AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
917

rl@cse.unsw.edu.au's avatar
rl@cse.unsw.edu.au committed
918 919 920 921 922 923 924
dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
dnl ** _POSIX_C_SOURCE is defined
AC_CHECK_DECLS([ctime_r], , ,
[#define _POSIX_SOURCE 1
#define _POSIX_C_SOURCE 199506L
#include <time.h>])

925
dnl ** check for mingwex library
Ben Gamari's avatar
Ben Gamari committed
926 927 928 929 930
AC_CHECK_LIB(
  [mingwex],
  [closedir],
  [AC_SUBST([HaveLibMingwEx],[YES])] [AC_SUBST([CabalMingwex],[True])],
  [AC_SUBST([HaveLibMingwEx],[NO])] [AC_SUBST([CabalMingwex],[False])])
931 932

if test $HaveLibMingwEx = YES ; then
933
  AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
934 935
fi

sebc's avatar
sebc committed
936
dnl ** check for math library
937 938 939
dnl    Keep that check as early as possible.
dnl    as we need to know whether we need libm
dnl    for math functions or not
940
dnl    (see https://gitlab.haskell.org/ghc/ghc/issues/3730)
941 942 943 944
AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
if test $HaveLibM = YES
then
  AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
Moritz Angermann's avatar
Moritz Angermann committed
945 946 947
  AC_SUBST([CabalHaveLibm],[True])
else
  AC_SUBST([CabalHaveLibm],[False])
948
fi
sebc's avatar
sebc committed
949

950
FP_BFD_SUPPORT
951

reid's avatar
reid committed
952 953 954 955
dnl ################################################################
dnl Check for libraries
dnl ################################################################

956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998
# system libffi

AC_ARG_WITH([system-libffi],
[AC_HELP_STRING([--with-system-libffi],
  [Use system provided libffi for RTS [default=no]])
])

AS_IF([test "x$with_system_libffi" = "xyes"],
  [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
)


AC_SUBST(UseSystemLibFFI)

AC_ARG_WITH([ffi-includes],
[AC_HELP_STRING([--with-ffi-includes=ARG],
  [Find includes for libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
 else
    FFIIncludeDir="$withval"
    LIBFFI_CFLAGS="-I$withval"
 fi
])

AC_SUBST(FFIIncludeDir)

AC_ARG_WITH([ffi-libraries],
[AC_HELP_STRING([--with-ffi-libraries=ARG],
  [Find libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
 else
    FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
 fi
])

AC_SUBST(FFILibDir)

Moritz Angermann's avatar
Moritz Angermann committed
999
AC_SUBST([CabalHaveLibffi],[False])
1000 1001 1002 1003 1004
AS_IF([test "$UseSystemLibFFI" = "YES"], [
 CFLAGS2="$CFLAGS"
 CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
 LDFLAGS2="$LDFLAGS"
 LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
1005 1006 1007 1008 1009 1010 1011 1012 1013
 if test "$HostOS" = "openbsd";
 then
   # OpenBSD's libffi is not directly linked to the libpthread but
   # still requires pthread functionality. This means that any client
   # binary which links with libffi also needs to link with
   # libpthread. If it does not, then linking fails with unresolved
   # symbols.
   LDFLAGS="$LDFLAGS -lpthread"
 fi
1014 1015
 AC_CHECK_LIB(ffi, ffi_call,
  [AC_CHECK_HEADERS([ffi.h], [break], [])
Moritz Angermann's avatar
Moritz Angermann committed
1016 1017
   AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])]
   AC_SUBST([CabalHaveLibffi],[True]),
1018 1019 1020 1021 1022
  [AC_MSG_ERROR([Cannot find system libffi])])
 CFLAGS="$CFLAGS2"
 LDFLAGS="$LDFLAGS2"
])

ross's avatar
ross committed
1023
dnl ** check whether we need -ldl to get dlopen()
Moritz Angermann's avatar
Moritz Angermann committed
1024 1025
AC_CHECK_LIB([dl], [dlopen])
AC_CHECK_LIB([dl], [dlopen], [AC_SUBST([CabalHaveLibdl], [True])], [AC_SUBST([CabalHaveLibdl], [False])])
1026

1027
dnl --------------------------------------------------
sof's avatar
sof committed
1028 1029 1030
dnl * Miscellaneous feature tests
dnl --------------------------------------------------

sof's avatar
sof committed
1031
dnl ** can we get alloca?
1032
AC_FUNC_ALLOCA
sof's avatar
sof committed
1033

1034
dnl ** working vfork?
1035
AC_FUNC_FORK
1036

1037 1038
dnl ** determine whether or not const works
AC_C_CONST