Init.hs 26.7 KB
Newer Older
Duncan Coutts's avatar
Duncan Coutts committed
1
{-# LANGUAGE CPP #-}
2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26
-----------------------------------------------------------------------------
-- |
-- Module      :  Distribution.Client.Init
-- Copyright   :  (c) Brent Yorgey 2009
-- License     :  BSD-like
--
-- Maintainer  :  cabal-devel@haskell.org
-- Stability   :  provisional
-- Portability :  portable
--
-- Implementation of the 'cabal init' command, which creates an initial .cabal
-- file for a project.
--
-----------------------------------------------------------------------------

module Distribution.Client.Init (

    -- * Commands
    initCabal

  ) where

import System.IO
  ( hSetBuffering, stdout, BufferMode(..) )
import System.Directory
27 28 29
  ( getCurrentDirectory, doesDirectoryExist )
import System.FilePath
  ( (</>) )
30 31 32 33
import Data.Time
  ( getCurrentTime, utcToLocalTime, toGregorian, localDay, getCurrentTimeZone )

import Data.List
34
  ( intersperse, intercalate, nub, groupBy, (\\) )
35
import Data.Maybe
36 37 38 39
  ( fromMaybe, isJust, catMaybes )
import Data.Function
  ( on )
import qualified Data.Map as M
40 41
import Data.Traversable
  ( traverse )
42 43
import Control.Applicative
  ( (<$>) )
44
import Control.Monad
Duncan Coutts's avatar
Duncan Coutts committed
45 46 47
  ( when )
#if MIN_VERSION_base(3,0,0)
import Control.Monad
48
  ( (>=>), join )
Duncan Coutts's avatar
Duncan Coutts committed
49
#endif
50 51
import Control.Arrow
  ( (&&&) )
52

dterei's avatar
dterei committed
53
import Text.PrettyPrint hiding (mode, cat)
54 55 56 57

import Data.Version
  ( Version(..) )
import Distribution.Version
58 59 60 61 62 63 64 65
  ( orLaterVersion, withinVersion, VersionRange )
import Distribution.Verbosity
  ( Verbosity )
import Distribution.ModuleName
  ( ModuleName, fromString )
import Distribution.InstalledPackageInfo
  ( InstalledPackageInfo, sourcePackageId, exposed )
import qualified Distribution.Package as P
66 67

import Distribution.Client.Init.Types
68
  ( InitFlags(..), PackageType(..), Category(..) )
69
import Distribution.Client.Init.Licenses
70
  ( bsd3, gplv2, gplv3, lgpl2, lgpl3, apache20 )
71 72 73 74 75 76 77 78 79 80 81 82
import Distribution.Client.Init.Heuristics
  ( guessPackageName, guessAuthorNameMail, SourceFileEntry(..), scanForModules, neededBuildPrograms )

import Distribution.License
  ( License(..), knownLicenses )
import Distribution.ModuleName
  ( ) -- for the Text instance

import Distribution.ReadE
  ( runReadE, readP_to_E )
import Distribution.Simple.Setup
  ( Flag(..), flagToMaybe )
83 84 85 86 87 88 89 90
import Distribution.Simple.Configure
  ( getInstalledPackages )
import Distribution.Simple.Compiler
  ( PackageDBStack, Compiler )
import Distribution.Simple.Program
  ( ProgramConfiguration )
import Distribution.Simple.PackageIndex
  ( PackageIndex, moduleNameIndex )
91 92 93
import Distribution.Text
  ( display, Text(..) )

94 95 96 97 98 99 100 101 102 103
initCabal :: Verbosity
          -> PackageDBStack
          -> Compiler
          -> ProgramConfiguration
          -> InitFlags
          -> IO ()
initCabal verbosity packageDBs comp conf initFlags = do

  installedPkgIndex <- getInstalledPackages verbosity comp packageDBs conf

104 105
  hSetBuffering stdout NoBuffering

106
  initFlags' <- extendFlags installedPkgIndex initFlags
107 108 109 110 111 112 113 114 115 116 117 118 119

  writeLicense initFlags'
  writeSetupFile initFlags'
  success <- writeCabalFile initFlags'

  when success $ generateWarnings initFlags'

---------------------------------------------------------------------------
--  Flag acquisition  -----------------------------------------------------
---------------------------------------------------------------------------

-- | Fill in more details by guessing, discovering, or prompting the
--   user.
120 121 122 123 124 125 126 127 128 129 130 131 132
extendFlags :: PackageIndex -> InitFlags -> IO InitFlags
extendFlags pkgIx =
      getPackageName
  >=> getVersion
  >=> getLicense
  >=> getAuthorInfo
  >=> getHomepage
  >=> getSynopsis
  >=> getCategory
  >=> getLibOrExec
  >=> getGenComments
  >=> getSrcDir
  >=> getModulesBuildToolsAndDeps pkgIx
133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160

-- | Combine two actions which may return a value, preferring the first. That
--   is, run the second action only if the first doesn't return a value.
infixr 1 ?>>
(?>>) :: IO (Maybe a) -> IO (Maybe a) -> IO (Maybe a)
f ?>> g = do
  ma <- f
  if isJust ma
    then return ma
    else g

-- | Witness the isomorphism between Maybe and Flag.
maybeToFlag :: Maybe a -> Flag a
maybeToFlag = maybe NoFlag Flag

-- | Get the package name: use the package directory (supplied, or the current
--   directory by default) as a guess.
getPackageName :: InitFlags -> IO InitFlags
getPackageName flags = do
  guess    <-     traverse guessPackageName (flagToMaybe $ packageDir flags)
              ?>> Just `fmap` (getCurrentDirectory >>= guessPackageName)

  pkgName' <-     return (flagToMaybe $ packageName flags)
              ?>> maybePrompt flags (promptStr "Package name" guess)
              ?>> return guess

  return $ flags { packageName = maybeToFlag pkgName' }

161 162
-- | Package version: use 0.1.0.0 as a last resort, but try prompting the user
--  if possible.
163 164
getVersion :: InitFlags -> IO InitFlags
getVersion flags = do
165
  let v = Just $ Version { versionBranch = [0,1,0,0], versionTags = [] }
166 167 168 169 170 171 172 173 174
  v' <-     return (flagToMaybe $ version flags)
        ?>> maybePrompt flags (prompt "Package version" v)
        ?>> return v
  return $ flags { version = maybeToFlag v' }

-- | Choose a license.
getLicense :: InitFlags -> IO InitFlags
getLicense flags = do
  lic <-     return (flagToMaybe $ license flags)
175
         ?>> fmap (fmap (either UnknownLicense id) . join)
176
                  (maybePrompt flags
177
                    (promptListOptional "Please choose a license" listedLicenses))
178
  return $ flags { license = maybeToFlag lic }
179 180
  where
    listedLicenses =
181
      knownLicenses \\ [GPL Nothing, LGPL Nothing, Apache Nothing, OtherLicense]
182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204

-- | The author's name and email. Prompt, or try to guess from an existing
--   darcs repo.
getAuthorInfo :: InitFlags -> IO InitFlags
getAuthorInfo flags = do
  (authorName, authorEmail)  <- (\(a,e) -> (flagToMaybe a, flagToMaybe e)) `fmap` guessAuthorNameMail
  authorName'  <-     return (flagToMaybe $ author flags)
                  ?>> maybePrompt flags (promptStr "Author name" authorName)
                  ?>> return authorName

  authorEmail' <-     return (flagToMaybe $ email flags)
                  ?>> maybePrompt flags (promptStr "Maintainer email" authorEmail)
                  ?>> return authorEmail

  return $ flags { author = maybeToFlag authorName'
                 , email  = maybeToFlag authorEmail'
                 }

-- | Prompt for a homepage URL.
getHomepage :: InitFlags -> IO InitFlags
getHomepage flags = do
  hp  <- queryHomepage
  hp' <-     return (flagToMaybe $ homepage flags)
205
         ?>> maybePrompt flags (promptStr "Project homepage URL" hp)
206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228
         ?>> return hp

  return $ flags { homepage = maybeToFlag hp' }

-- | Right now this does nothing, but it could be changed to do some
--   intelligent guessing.
queryHomepage :: IO (Maybe String)
queryHomepage = return Nothing     -- get default remote darcs repo?

-- | Prompt for a project synopsis.
getSynopsis :: InitFlags -> IO InitFlags
getSynopsis flags = do
  syn <-     return (flagToMaybe $ synopsis flags)
         ?>> maybePrompt flags (promptStr "Project synopsis" Nothing)

  return $ flags { synopsis = maybeToFlag syn }

-- | Prompt for a package category.
--   Note that it should be possible to do some smarter guessing here too, i.e.
--   look at the name of the top level source directory.
getCategory :: InitFlags -> IO InitFlags
getCategory flags = do
  cat <-     return (flagToMaybe $ category flags)
229 230
         ?>> fmap join (maybePrompt flags
                         (promptListOptional "Project category" [Codec ..]))
231 232 233 234 235 236 237 238 239
  return $ flags { category = maybeToFlag cat }

-- | Ask whether the project builds a library or executable.
getLibOrExec :: InitFlags -> IO InitFlags
getLibOrExec flags = do
  isLib <-     return (flagToMaybe $ packageType flags)
           ?>> maybePrompt flags (either (const Library) id `fmap`
                                   (promptList "What does the package build"
                                               [Library, Executable]
240
                                               Nothing display False))
241 242 243 244
           ?>> return (Just Library)

  return $ flags { packageType = maybeToFlag isLib }

245 246 247 248
-- | Ask whether to generate explanitory comments.
getGenComments :: InitFlags -> IO InitFlags
getGenComments flags = do
  genComments <-     return (flagToMaybe $ noComments flags)
249
                 ?>> maybePrompt flags (promptYesNo promptMsg (Just False))
250 251
                 ?>> return (Just False)
  return $ flags { noComments = maybeToFlag (fmap not genComments) }
252
  where
253
    promptMsg = "Include documentation on what each field means (y/n)"
254

255 256 257 258
-- | Try to guess the source root directory (don't prompt the user).
getSrcDir :: InitFlags -> IO InitFlags
getSrcDir flags = do
  srcDirs <-     return (sourceDirs flags)
259
             ?>> Just `fmap` (guessSourceDirs flags)
260 261 262

  return $ flags { sourceDirs = srcDirs }

263 264 265 266 267 268 269 270 271 272
-- | Try to guess source directories.  Could try harder; for the
--   moment just looks to see whether there is a directory called 'src'.
guessSourceDirs :: InitFlags -> IO [String]
guessSourceDirs flags = do
  dir      <- fromMaybe getCurrentDirectory
                (fmap return . flagToMaybe $ packageDir flags)
  srcIsDir <- doesDirectoryExist (dir </> "src")
  if srcIsDir
    then return ["src"]
    else return []
273 274

-- | Get the list of exposed modules and extra tools needed to build them.
275 276
getModulesBuildToolsAndDeps :: PackageIndex -> InitFlags -> IO InitFlags
getModulesBuildToolsAndDeps pkgIx flags = do
277 278 279 280 281 282
  dir <- fromMaybe getCurrentDirectory
                   (fmap return . flagToMaybe $ packageDir flags)

  -- XXX really should use guessed source roots.
  sourceFiles <- scanForModules dir

283
  Just mods <-      return (exposedModules flags)
284 285 286 287 288
           ?>> (return . Just . map moduleName $ sourceFiles)

  tools <-     return (buildTools flags)
           ?>> (return . Just . neededBuildPrograms $ sourceFiles)

289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354
  deps <-      return (dependencies flags)
           ?>> Just <$> importsToDeps flags
                        (fromString "Prelude" : concatMap imports sourceFiles)
                        pkgIx

  return $ flags { exposedModules = Just mods
                 , buildTools     = tools
                 , dependencies   = deps
                 }

importsToDeps :: InitFlags -> [ModuleName] -> PackageIndex -> IO [P.Dependency]
importsToDeps flags mods pkgIx = do

  let modMap :: M.Map ModuleName [InstalledPackageInfo]
      modMap  = M.map (filter exposed) $ moduleNameIndex pkgIx

      modDeps :: [(ModuleName, Maybe [InstalledPackageInfo])]
      modDeps = map (id &&& flip M.lookup modMap) mods

  message flags "\nGuessing dependencies..."
  nub . catMaybes <$> mapM (chooseDep flags) modDeps

-- Given a module and a list of installed packages providing it,
-- choose a dependency (i.e. package + version range) to use for that
-- module.
chooseDep :: InitFlags -> (ModuleName, Maybe [InstalledPackageInfo])
          -> IO (Maybe P.Dependency)

chooseDep flags (m, Nothing)
  = message flags ("\nWarning: no package found providing " ++ display m ++ ".")
    >> return Nothing

chooseDep flags (m, Just [])
  = message flags ("\nWarning: no package found providing " ++ display m ++ ".")
    >> return Nothing

    -- We found some packages: group them by name.
chooseDep flags (m, Just ps)
  = case pkgGroups of
      -- if there's only one group, i.e. multiple versions of a single package,
      -- we make it into a dependency, choosing the latest-ish version (see toDep).
      [grp] -> Just <$> toDep grp
      -- otherwise, we refuse to choose between different packages and make the user
      -- do it.
      grps  -> do message flags ("\nWarning: multiple packages found providing "
                                 ++ display m
                                 ++ ": " ++ intercalate ", " (map (display . P.pkgName . head) grps))
                  message flags ("You will need to pick one and manually add it to the Build-depends: field.")
                  return Nothing
  where
    pkgGroups = groupBy ((==) `on` P.pkgName) (map sourcePackageId ps)

    -- Given a list of available versions of the same package, pick a dependency.
    toDep :: [P.PackageIdentifier] -> IO P.Dependency

    -- If only one version, easy.  We change e.g. 0.4.2  into  0.4.*
    toDep [pid] = return $ P.Dependency (P.pkgName pid) (pvpize . P.pkgVersion $ pid)

    -- Otherwise, choose the latest version and issue a warning.
    toDep pids  = do
      message flags ("\nWarning: multiple versions of " ++ display (P.pkgName . head $ pids) ++ " provide " ++ display m ++ ", choosing the latest.")
      return $ P.Dependency (P.pkgName . head $ pids)
                            (pvpize . maximum . map P.pkgVersion $ pids)

    pvpize :: Version -> VersionRange
    pvpize v = withinVersion $ v { versionBranch = take 2 (versionBranch v) }
355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372

---------------------------------------------------------------------------
--  Prompting/user interaction  -------------------------------------------
---------------------------------------------------------------------------

-- | Run a prompt or not based on the nonInteractive flag of the
--   InitFlags structure.
maybePrompt :: InitFlags -> IO t -> IO (Maybe t)
maybePrompt flags p =
  case nonInteractive flags of
    Flag True -> return Nothing
    _         -> Just `fmap` p

-- | Create a prompt with optional default value that returns a
--   String.
promptStr :: String -> Maybe String -> IO String
promptStr = promptDefault' Just id

373 374 375 376 377 378 379 380 381 382 383 384
-- | Create a yes/no prompt with optional default value.
--
promptYesNo :: String -> Maybe Bool -> IO Bool
promptYesNo =
    promptDefault' recogniseYesNo showYesNo
  where
    recogniseYesNo s | s == "y" || s == "Y" = Just True
                     | s == "n" || s == "N" = Just False
                     | otherwise            = Nothing
    showYesNo True  = "y"
    showYesNo False = "n"

385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410
-- | Create a prompt with optional default value that returns a value
--   of some Text instance.
prompt :: Text t => String -> Maybe t -> IO t
prompt = promptDefault'
           (either (const Nothing) Just . runReadE (readP_to_E id parse))
           display

-- | Create a prompt with an optional default value.
promptDefault' :: (String -> Maybe t)       -- ^ parser
               -> (t -> String)             -- ^ pretty-printer
               -> String                    -- ^ prompt message
               -> Maybe t                   -- ^ optional default value
               -> IO t
promptDefault' parser pretty pr def = do
  putStr $ mkDefPrompt pr (pretty `fmap` def)
  inp <- getLine
  case (inp, def) of
    ("", Just d)  -> return d
    _  -> case parser inp of
            Just t  -> return t
            Nothing -> do putStrLn $ "Couldn't parse " ++ inp ++ ", please try again!"
                          promptDefault' parser pretty pr def

-- | Create a prompt from a prompt string and a String representation
--   of an optional default value.
mkDefPrompt :: String -> Maybe String -> String
411 412
mkDefPrompt pr def = pr ++ "?" ++ defStr def
  where defStr Nothing  = " "
413 414 415 416 417 418 419 420 421 422 423 424
        defStr (Just s) = " [default: " ++ s ++ "] "

promptListOptional :: (Text t, Eq t)
                   => String            -- ^ prompt
                   -> [t]               -- ^ choices
                   -> IO (Maybe (Either String t))
promptListOptional pr choices =
    fmap rearrange
  $ promptList pr (Nothing : map Just choices) (Just Nothing)
               (maybe "(none)" display) True
  where
    rearrange = either (Just . Left) (maybe Nothing (Just . Right))
425 426

-- | Create a prompt from a list of items.
427
promptList :: Eq t
428 429 430
           => String            -- ^ prompt
           -> [t]               -- ^ choices
           -> Maybe t           -- ^ optional default value
431
           -> (t -> String)     -- ^ show an item
432 433
           -> Bool              -- ^ whether to allow an 'other' option
           -> IO (Either String t)
434
promptList pr choices def displayItem other = do
435
  putStrLn $ pr ++ ":"
436
  let options1 = map (\c -> (Just c == def, displayItem c)) choices
437 438 439 440
      options2 = zip ([1..]::[Int])
                     (options1 ++ if other then [(False, "Other (specify)")]
                                           else [])
  mapM_ (putStrLn . \(n,(i,s)) -> showOption n i ++ s) options2
441
  promptList' displayItem (length options2) choices def other
442 443 444 445 446 447
 where showOption n i | n < 10 = " " ++ star i ++ " " ++ rest
                      | otherwise = " " ++ star i ++ rest
                  where rest = show n ++ ") "
                        star True = "*"
                        star False = " "

448 449 450
promptList' :: (t -> String) -> Int -> [t] -> Maybe t -> Bool -> IO (Either String t)
promptList' displayItem numChoices choices def other = do
  putStr $ mkDefPrompt "Your choice" (displayItem `fmap` def)
451 452 453 454 455 456 457
  inp <- getLine
  case (inp, def) of
    ("", Just d) -> return $ Right d
    _  -> case readMaybe inp of
            Nothing -> invalidChoice inp
            Just n  -> getChoice n
 where invalidChoice inp = do putStrLn $ inp ++ " is not a valid choice."
458
                              promptList' displayItem numChoices choices def other
459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475
       getChoice n | n < 1 || n > numChoices = invalidChoice (show n)
                   | n < numChoices ||
                     (n == numChoices && not other)
                                  = return . Right $ choices !! (n-1)
                   | otherwise    = Left `fmap` promptStr "Please specify" Nothing

readMaybe :: (Read a) => String -> Maybe a
readMaybe s = case reads s of
                [(a,"")] -> Just a
                _        -> Nothing

---------------------------------------------------------------------------
--  File generation  ------------------------------------------------------
---------------------------------------------------------------------------

writeLicense :: InitFlags -> IO ()
writeLicense flags = do
476
  message flags "\nGenerating LICENSE..."
477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497
  year <- getYear
  let licenseFile =
        case license flags of
          Flag BSD3 -> Just $ bsd3 (fromMaybe "???"
                                  . flagToMaybe
                                  . author
                                  $ flags)
                              (show year)

          Flag (GPL (Just (Version {versionBranch = [2]})))
            -> Just gplv2

          Flag (GPL (Just (Version {versionBranch = [3]})))
            -> Just gplv3

          Flag (LGPL (Just (Version {versionBranch = [2]})))
            -> Just lgpl2

          Flag (LGPL (Just (Version {versionBranch = [3]})))
            -> Just lgpl3

498 499 500
          Flag (Apache (Just (Version {versionBranch = [2, 0]})))
            -> Just apache20

501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520
          _ -> Nothing

  case licenseFile of
    Just licenseText -> writeFile "LICENSE" licenseText
    Nothing -> message flags "Warning: unknown license type, you must put a copy in LICENSE yourself."

getYear :: IO Integer
getYear = do
  u <- getCurrentTime
  z <- getCurrentTimeZone
  let l = utcToLocalTime z u
      (y, _, _) = toGregorian $ localDay l
  return y

writeSetupFile :: InitFlags -> IO ()
writeSetupFile flags = do
  message flags "Generating Setup.hs..."
  writeFile "Setup.hs" setupFile
 where
  setupFile = unlines
521
    [ "import Distribution.Simple"
522 523 524
    , "main = defaultMain"
    ]

525 526
-- XXX ought to do something sensible if a .cabal file already exists,
-- instead of overwriting.
527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545
writeCabalFile :: InitFlags -> IO Bool
writeCabalFile flags@(InitFlags{packageName = NoFlag}) = do
  message flags "Error: no package name provided."
  return False
writeCabalFile flags@(InitFlags{packageName = Flag p}) = do
  let cabalFileName = p ++ ".cabal"
  message flags $ "Generating " ++ cabalFileName ++ "..."
  writeFile cabalFileName (generateCabalFile cabalFileName flags)
  return True

-- | Generate a .cabal file from an InitFlags structure.  NOTE: this
--   is rather ad-hoc!  What we would REALLY like is to have a
--   standard low-level AST type representing .cabal files, which
--   preserves things like comments, and to write an *inverse*
--   parser/pretty-printer pair between .cabal files and this AST.
--   Then instead of this ad-hoc code we could just map an InitFlags
--   structure onto a low-level AST structure and use the existing
--   pretty-printing code to generate the file.
generateCabalFile :: String -> InitFlags -> String
546 547
generateCabalFile fileName c =
  renderStyle style { lineLength = 79, ribbonsPerLine = 1.1 } $
548
  (if (minimal c /= Flag True)
549 550 551 552
    then showComment (Just $ "Initial " ++ fileName ++ " generated by cabal "
                          ++ "init.  For further documentation, see "
                          ++ "http://haskell.org/cabal/users-guide/")
         $$ text ""
553 554
    else empty)
  $$
555
  vcat [ fieldS "name"          (packageName   c)
556 557 558
                (Just "The name of the package.")
                True

559
       , field  "version"       (version       c)
560 561 562 563
                (Just $ "The package version.  See the Haskell package versioning policy (PVP) for standards guiding when and how versions should be incremented.\nhttp://www.haskell.org/haskellwiki/Package_versioning_policy\n"
                ++ "PVP summary:      +-+------- breaking API changes\n"
                ++ "                  | | +----- non-breaking API additions\n"
                ++ "                  | | | +--- code changes with no API change")
564 565
                True

566
       , fieldS "synopsis"      (synopsis      c)
567 568 569
                (Just "A short (one-line) description of the package.")
                True

570
       , fieldS "description"   NoFlag
571 572 573
                (Just "A longer description of the package.")
                True

574
       , fieldS "homepage"      (homepage     c)
575 576 577
                (Just "URL for the project homepage or repository.")
                False

578
       , fieldS "bug-reports"   NoFlag
579 580 581
                (Just "A URL where users can report bugs.")
                False

582
       , field  "license"       (license      c)
583 584 585
                (Just "The license under which the package is released.")
                True

586
       , fieldS "license-file" (Flag "LICENSE")
587 588 589
                (Just "The file containing the license text.")
                True

590
       , fieldS "author"        (author       c)
591 592 593
                (Just "The package author(s).")
                True

594
       , fieldS "maintainer"    (email        c)
595 596 597
                (Just "An email address to which users can send suggestions, bug reports, and patches.")
                True

598
       , fieldS "copyright"     NoFlag
599 600 601
                (Just "A copyright notice.")
                True

602
       , fieldS "category"      (either id display `fmap` category c)
603 604 605
                Nothing
                True

606
       , fieldS "build-type"    (Flag "Simple")
607 608 609
                Nothing
                True

610
       , fieldS "extra-source-files" NoFlag
611
                (Just "Extra files to be distributed with the package, such as examples or a README.")
612
                False
613

614
       , field  "cabal-version" (Flag $ orLaterVersion (Version [1,8] []))
615 616 617 618 619
                (Just "Constraint on the version of Cabal needed to build this package.")
                False

       , case packageType c of
           Flag Executable ->
620 621
             text "\nexecutable" <+> text (fromMaybe "" . flagToMaybe $ packageName c) $$ (nest 2 $ vcat
             [ fieldS "main-is" NoFlag (Just ".hs or .lhs file containing the Main module.") True
622

623
             , generateBuildInfo Executable c
624
             ])
625 626
           Flag Library    -> text "\nlibrary" $$ (nest 2 $ vcat
             [ fieldS "exposed-modules" (listField (exposedModules c))
627 628 629
                      (Just "Modules exported by the library.")
                      True

630
             , generateBuildInfo Library c
631 632 633 634
             ])
           _               -> empty
       ]
 where
635 636 637 638 639 640
   generateBuildInfo :: PackageType -> InitFlags -> Doc
   generateBuildInfo pkgtype c' = vcat
     [ fieldS "other-modules" (listField (otherModules c'))
              (Just $ case pkgtype of
                 Library    -> "Modules included in this library but not exported."
                 Executable -> "Modules included in this executable, other than Main.")
641 642
              True

643 644
     , fieldS "build-depends" (listField (dependencies c'))
              (Just "Other library packages from which modules are imported.")
645 646 647
              True

     , fieldS "hs-source-dirs" (listFieldS (sourceDirs c'))
648
              (Just "Directories containing source files.")
649 650
              False

651
     , fieldS "build-tools" (listFieldS (buildTools c'))
652
              (Just "Extra tools (e.g. alex, hsc2hs, ...) needed to build the source.")
653
              False
654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687
     ]

   listField :: Text s => Maybe [s] -> Flag String
   listField = listFieldS . fmap (map display)

   listFieldS :: Maybe [String] -> Flag String
   listFieldS = Flag . maybe "" (concat . intersperse ", ")

   field :: Text t => String -> Flag t -> Maybe String -> Bool -> Doc
   field s f = fieldS s (fmap display f)

   fieldS :: String        -- ^ Name of the field
          -> Flag String   -- ^ Field contents
          -> Maybe String  -- ^ Comment to explain the field
          -> Bool          -- ^ Should the field be included (commented out) even if blank?
          -> Doc
   fieldS _ NoFlag _    inc | not inc || (minimal c == Flag True) = empty
   fieldS _ (Flag "") _ inc | not inc || (minimal c == Flag True) = empty
   fieldS s f com _ = case (isJust com, noComments c, minimal c) of
                        (_, _, Flag True) -> id
                        (_, Flag True, _) -> id
                        (True, _, _)      -> (showComment com $$) . ($$ text "")
                        (False, _, _)     -> ($$ text "")
                      $
                      comment f <> text s <> colon
                                <> text (take (20 - length s) (repeat ' '))
                                <> text (fromMaybe "" . flagToMaybe $ f)
   comment NoFlag    = text "-- "
   comment (Flag "") = text "-- "
   comment _         = text ""

   showComment :: Maybe String -> Doc
   showComment (Just t) = vcat . map text
                        . map ("-- "++) . lines
688 689 690 691
                        . renderStyle style {
                            lineLength = 76,
                            ribbonsPerLine = 1.05
                          }
692 693 694 695
                        . vcat
                        . map (fcat . map text . breakLine)
                        . lines
                        $ t
696 697
   showComment Nothing  = text ""

698 699 700 701 702
   breakLine  [] = []
   breakLine  cs = case break (==' ') cs of (w,cs') -> w : breakLine' cs'
   breakLine' [] = []
   breakLine' cs = case span (==' ') cs of (w,cs') -> w : breakLine cs'

703 704 705 706 707 708 709 710 711 712 713 714 715 716
-- | Generate warnings for missing fields etc.
generateWarnings :: InitFlags -> IO ()
generateWarnings flags = do
  message flags ""
  when (synopsis flags `elem` [NoFlag, Flag ""])
       (message flags "Warning: no synopsis given. You should edit the .cabal file and add one.")

  message flags "You may want to edit the .cabal file and add a Description field."

-- | Possibly generate a message to stdout, taking into account the
--   --quiet flag.
message :: InitFlags -> String -> IO ()
message (InitFlags{quiet = Flag True}) _ = return ()
message _ s = putStrLn s
Duncan Coutts's avatar
Duncan Coutts committed
717 718 719 720 721 722

#if MIN_VERSION_base(3,0,0)
#else
(>=>)       :: Monad m => (a -> m b) -> (b -> m c) -> (a -> m c)
f >=> g     = \x -> f x >>= g
#endif