configure.ac 44 KB
Newer Older
1
dnl == autoconf source for the Glasgow FP tools ==
2
dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
sof's avatar
sof committed
3
dnl  (or some such) to see the outline of this file)
4 5
dnl
#
6
# (c) The University of Glasgow 1994-2012
7
#
8
# Configure script template for GHC
9
#
10
# Process with 'autoreconf' to get a working configure script.
11
#
sof's avatar
sof committed
12 13 14 15
# For the generated configure script, do "./configure --help" to
# see what flags are available. (Better yet, read the documentation!)
#

Ben Gamari's avatar
Ben Gamari committed
16
AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.4.2], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17

18
# Set this to YES for a released version, otherwise NO
Ben Gamari's avatar
Ben Gamari committed
19
: ${RELEASE=YES}
20

21
# The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22
# above.  If this is not a released version, then we will append the
23
# date to the version number (e.g. 7.4.20111220).  The date is
24
# constructed by finding the date of the most recent patch in the
25
# git repository.  If this is a source distribution (not a git
26 27 28
# checkout), then we ship a file 'VERSION' containing the full version
# when the source distribution was created.

29
if test ! -f mk/config.h.in; then
Ben Gamari's avatar
Ben Gamari committed
30
   echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31 32 33
   exit 1
fi

34 35
AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])

36 37 38 39 40
dnl this makes sure `./configure --target=<cross-compile-target>`
dnl works as expected, since we're slightly modifying how Autoconf
dnl interprets build/host/target and how this interacts with $CC tests
test -n "$target_alias" && ac_tool_prefix=$target_alias-

41
dnl ----------------------------------------------------------
42
dnl ** Find unixy sort and find commands,
43 44 45 46
dnl ** which are needed by FP_SETUP_PROJECT_VERSION

dnl ** Find find command (for Win32's benefit)
FP_PROG_FIND
47
FP_PROG_SORT
48 49

dnl ----------------------------------------------------------
50 51 52 53
FP_SETUP_PROJECT_VERSION

# Hmmm, we fix the RPM release number to 1 here... Is this convenient?
AC_SUBST([release], [1])
54

55
# First off, a distrib sanity check..
56
AC_CONFIG_SRCDIR([mk/config.mk.in])
57

Gabor Greif's avatar
Gabor Greif committed
58
dnl * We require autoconf version 2.60
59 60
dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
Gabor Greif's avatar
Gabor Greif committed
61 62 63 64
dnl Using autoconf 2.59 started to give nonsense like this
dnl  #define SIZEOF_CHAR 0
dnl recently.
AC_PREREQ([2.60])
65

66 67 68
# -------------------------------------------------------------------------
# Prepare to generate the following header files
#
69 70
#
AC_CONFIG_HEADER(mk/config.h)
71

sof's avatar
sof committed
72
# No, semi-sadly, we don't do `--srcdir'...
73
if test x"$srcdir" != 'x.' ; then
74
    echo "This configuration does not support the \`--srcdir' option.."
75 76 77
    exit 1
fi

sof's avatar
sof committed
78 79 80 81 82 83 84 85 86 87
dnl --------------------------------------------------------------
dnl * Project specific configuration options
dnl --------------------------------------------------------------
dnl What follows is a bunch of options that can either be configured
dnl through command line options to the configure script or by
dnl supplying defns in the build tree's mk/build.mk. Having the option to
dnl use either is considered a Feature.

dnl ** What command to use to compile compiler sources ?
dnl --------------------------------------------------------------
88

89
AC_ARG_WITH([ghc],
90
[AC_HELP_STRING([--with-ghc=ARG],
91 92 93 94
  [Use ARG as the path to GHC  [default=autodetect]])],
  [WithGhc="$withval"],
  [if test "$GHC" = ""; then
    AC_PATH_PROG([GHC], [ghc])
95
  fi
96
  WithGhc="$GHC"])
97

98
dnl ** Tell the make system which OS we are using
99
dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 101
AC_SUBST(OSTYPE)

Ian Lynagh's avatar
Ian Lynagh committed
102 103 104 105 106 107 108
AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
[AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
                [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
        EnableBootstrapWithDevelSnaphost=YES,
        EnableBootstrapWithDevelSnaphost=NO
)

109 110 111 112 113 114
AC_ARG_ENABLE(tarballs-autodownload,
[AC_HELP_STRING([--enable-tarballs-autodownload],
                [Automatically download Windows distribution binaries if needed.])],
        TarballsAutodownload=YES,
        TarballsAutodownload=NO
)
115

116 117 118 119 120 121 122 123 124 125 126
AC_ARG_ENABLE(distro-toolchain,
[AC_HELP_STRING([--enable-distro-toolchain],
                [Do not use bundled Windows toolchain binaries.])],
        EnableDistroToolchain=YES,
        EnableDistroToolchain=NO
)

if test "$EnableDistroToolchain" = "YES"; then
  TarballsAutodownload=NO
fi

127 128 129 130
dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
dnl but instead used by stage0 for bootstrapping stage1
AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])

131 132
if test "$WithGhc" != ""; then
  FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
Ian Lynagh's avatar
Ian Lynagh committed
133

134
  if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135
     AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
Ian Lynagh's avatar
Ian Lynagh committed
136 137
  fi

138 139 140 141
  AC_SUBST(GhcVersion)dnl
  AC_SUBST(GhcMajVersion)dnl
  AC_SUBST(GhcMinVersion)dnl
  AC_SUBST(GhcPatchLevel)dnl
142 143
  GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
  GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144

145 146 147 148 149
  dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
  if test -z "$CC_STAGE0"; then
    BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
  fi

150
  BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151 152 153
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
  BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
  BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 155
fi

156
dnl ** Must have GHC to build GHC
ian@well-typed.com's avatar
ian@well-typed.com committed
157 158 159 160
if test "$WithGhc" = ""
then
    AC_MSG_ERROR([GHC is required.])
fi
161 162
FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.0],
    [AC_MSG_ERROR([GHC version 8.0 or later is required to compile GHC.])])
Simon Marlow's avatar
Simon Marlow committed
163

ian@well-typed.com's avatar
ian@well-typed.com committed
164 165 166 167
if test `expr $GhcMinVersion % 2` = "1"
then
    if test "$EnableBootstrapWithDevelSnaphost" = "NO"
    then
Simon Marlow's avatar
Simon Marlow committed
168 169 170 171 172
        AC_MSG_ERROR([
     $WithGhc is a development snapshot of GHC, version $GhcVersion.
     Bootstrapping using this version of GHC is not supported, and may not
     work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
     or --with-ghc to specify a different GHC to use.])
ian@well-typed.com's avatar
ian@well-typed.com committed
173 174
    fi
fi
175

176
GHC_PACKAGE_DB_FLAG=package-db
ian@well-typed.com's avatar
ian@well-typed.com committed
177
AC_SUBST(GHC_PACKAGE_DB_FLAG)
Simon Marlow's avatar
Simon Marlow committed
178

179 180 181
# GHC is passed to Cabal, so we need a native path
if test "${WithGhc}" != ""
then
182
    ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
183

184
    if test "$ghc_host_os" = "mingw32"
185
    then
186 187 188 189 190 191 192
        if test "${OSTYPE}" = "msys"
        then
            WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
        else
            # Canonicalise to <drive>:/path/to/ghc
            WithGhc=`cygpath -m "${WithGhc}"`
        fi
193 194 195 196 197
        echo "GHC path canonicalised to: ${WithGhc}"
    fi
fi
AC_SUBST([WithGhc])

198 199 200
dnl ** Without optimization some INLINE trickery fails for GHCi
SRC_CC_OPTS="-O"

201 202 203
dnl--------------------------------------------------------------------
dnl * Choose host(/target/build) platform
dnl--------------------------------------------------------------------
204 205
dnl If we aren't explicitly told what values to use with configure flags,
dnl we ask the bootstrapping compiler what platform it is for
206

207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222
if test "${WithGhc}" != ""
then
        bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
        if test "$bootstrap_host" != "$bootstrap_target"
        then
                echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
        fi
fi

# We have to run these unconditionally, but we may discard their
# results in the following code
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

223
FPTOOLS_SET_PLATFORM_VARS
224

225 226
# Verify that the installed (bootstrap) GHC is capable of generating
# code for the requested build platform.
ian@well-typed.com's avatar
ian@well-typed.com committed
227 228 229 230 231 232 233
if test "$BuildPlatform" != "$bootstrap_target"
then
    echo "This GHC (${WithGhc}) does not generate code for the build platform"
    echo "   GHC target platform    : $bootstrap_target"
    echo "   Desired build platform : $BuildPlatform"
    exit 1
fi
234

235 236
# Testing if we shall enable shared libs support on Solaris.
# Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
237

238
SOLARIS_BROKEN_SHLD=NO
239

240 241 242 243 244
case $host in
     i386-*-solaris2)
     # here we go with the test
     MINOR=`uname -r|cut -d '.' -f 2-`
     if test "$MINOR" -lt "11"; then
245
         SOLARIS_BROKEN_SHLD=YES
246 247 248
     fi
     ;;
esac
249

250 251
AC_SUBST(SOLARIS_BROKEN_SHLD)

252 253
dnl ** Do an unregisterised build?
dnl --------------------------------------------------------------
254
case "$TargetArch" in
255
    i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274
        UnregisterisedDefault=NO
        ;;
    *)
        UnregisterisedDefault=YES
        ;;
esac
AC_ARG_ENABLE(unregisterised,
[AC_HELP_STRING([--enable-unregisterised],
[Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
[ if test x"$enableval" = x"yes"; then
        Unregisterised=YES
  else
        Unregisterised=NO
  fi
],
[Unregisterised="$UnregisterisedDefault"]
)
AC_SUBST(Unregisterised)

275 276 277 278 279 280 281 282 283 284 285 286
dnl ** Does target have runtime linker support?
dnl --------------------------------------------------------------
case "$target" in
    powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
        HaskellHaveRTSLinker=NO
        ;;
    *)
        HaskellHaveRTSLinker=YES
        ;;
esac
AC_SUBST(HaskellHaveRTSLinker)

287 288 289
# Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
FP_FIND_ROOT

290
fail() {
291 292 293 294 295
    echo >&2
    echo "$1" >&2
    exit 1
}

296

297 298
if test "$HostOS" = "mingw32"
then
299
    # Find the mingw-w64 7z file to extract.
300 301
    # NB. If you update the tarballs to a new version of gcc, don't
    # forget to tweak the paths in driver/gcc/gcc.c.
302 303 304 305 306 307 308 309 310 311 312 313
    if test "$HostArch" = "i386"
    then
        mingw_arch="i686"
        tarball_dest_dir="mingw-w64/x86"
        tarball_mingw_dir="mingw32"
    else
        mingw_arch="x86_64"
        tarball_dest_dir="mingw-w64/x86_64"
        tarball_mingw_dir="mingw64"
    fi
fi

314 315 316 317
set_up_tarballs() {
    AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
    local action
    if test "$TarballsAutodownload" = "NO"
318
    then
319
        action="verify"
320
    else
321
        action="download"
322
    fi
323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347
    mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
    case $? in
        0)
           rm missing-win32-tarballs
           ;;
        2)
           echo
           echo "Error:"
           echo "Needed msys2 tarballs are missing. You have a few options to get them,"
           echo
           echo "  * run configure with the --enable-tarballs-autodownload option"
           echo
           echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
           echo
           echo "  * manually download the files listed in ./missing-win32-tarballs and place"
           echo "    them in the ghc-tarballs directory."
           echo
           exit 1
           ;;
        *)
           echo
           echo "Error fetching msys2 tarballs; see errors above."
           exit 1
           ;;
    esac
348 349 350 351 352 353

    # Extract all the tarballs in one go
    if ! test -d inplace/mingw
    then
        AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
        rm -rf inplace/mingw
354
        local base_dir="../ghc-tarballs/${tarball_dest_dir}"
355 356 357 358 359 360 361 362 363
        ( cd inplace &&
        find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
        rm ".MTREE" &&
        rm ".PKGINFO" &&
        cd .. ) || fail "Error: Could not extract Windows toolchains."

        mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
        touch inplace/mingw

364 365 366 367 368 369
        # NB. Now since the GCC is hardcoded to use /mingw32 we need to
        # make a wrapper around it to give it the proper paths
        mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
        PATH=`pwd`/inplace/mingw/bin:$PATH
        inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe

370 371 372 373
        AC_MSG_NOTICE([In-tree MingW-w64 tree created])
    fi
}

374
if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
375 376 377 378 379 380
then
    test -d inplace || mkdir inplace

    # NB. Download and extract the MingW-w64 distribution if required
    set_up_tarballs

381
    mingwbin="$hardtop/inplace/mingw/bin/"
382 383 384
    CC="${mingwbin}gcc.exe"
    LD="${mingwbin}ld.exe"
    NM="${mingwbin}nm.exe"
385
    RANLIB="${mingwbin}ranlib.exe"
386
    OBJDUMP="${mingwbin}objdump.exe"
Ian Lynagh's avatar
Ian Lynagh committed
387
    fp_prog_ar="${mingwbin}ar.exe"
388

389 390
    AC_PATH_PROG([Genlib],[genlib])

391
    # NB. Download the perl binaries if required
392 393 394 395 396 397 398 399 400 401 402 403
    if ! test -d inplace/perl ||
         test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
    then
        AC_MSG_NOTICE([Making in-tree perl tree])
        rm -rf inplace/perl
        mkdir inplace/perl
        (
            cd inplace/perl &&
            tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
        )
        AC_MSG_NOTICE([In-tree perl tree created])
    fi
404 405
fi

406 407 408 409 410 411 412 413 414 415 416 417 418 419
# We don't want to bundle a MinGW-w64 toolchain
# So we have to find these individual tools.
if test "$EnableDistroToolchain" = "YES"
then
    # Ideally should use AC_CHECK_TARGET_TOOL but our triples
    # are screwed up. Configure doesn't think they're ever equal and
    # so never tried without the prefix.
    AC_PATH_PROG([CC],[gcc], [clang])
    AC_PATH_PROG([NM],[nm])
    AC_PATH_PROG([AR],[ar])
    AC_PATH_PROG([RANLIB],[ranlib])
    AC_PATH_PROG([OBJDUMP],[objdump])
    AC_PATH_PROG([DllWrap],[dllwrap])
    AC_PATH_PROG([Windres],[windres])
420
    AC_PATH_PROG([Genlib],[genlib])
Tamar Christina's avatar
Tamar Christina committed
421
fi
422

Tamar Christina's avatar
Tamar Christina committed
423 424
DllWrapCmd="$DllWrap"
WindresCmd="$Windres"
425

426 427 428 429 430 431 432 433 434
HAVE_GENLIB=False
if test "$HostOS" = "mingw32"
then
    if test "$Genlib" != ""; then
        GenlibCmd="$(cygpath -m $Genlib)"
        HAVE_GENLIB=True
    fi
fi

Tamar Christina's avatar
Tamar Christina committed
435 436
AC_SUBST([DllWrapCmd])
AC_SUBST([WindresCmd])
437 438
AC_SUBST([GenlibCmd])
AC_SUBST([HAVE_GENLIB])
439

Ian Lynagh's avatar
Ian Lynagh committed
440 441
FP_ICONV
FP_GMP
442
FP_CURSES
Ian Lynagh's avatar
Ian Lynagh committed
443

444
XCODE_VERSION()
Ian Lynagh's avatar
Ian Lynagh committed
445

446

447 448 449 450
dnl ** Building a cross compiler?
dnl --------------------------------------------------------------
CrossCompiling=NO
# If 'host' and 'target' differ, then this means we are building a cross-compiler.
Tamar Christina's avatar
Tamar Christina committed
451
if test "$TargetPlatform" != "$HostPlatform" ; then
452 453 454 455 456 457
    CrossCompiling=YES
    cross_compiling=yes   # This tells configure that it can accept just 'target',
                          # otherwise you get
                          #   configure: error: cannot run C compiled programs.
                          #   If you meant to cross compile, use `--host'.
fi
458
if test "$BuildPlatform" != "$HostPlatform" ; then
459 460 461
   AC_MSG_ERROR([
You've selected:

Tamar Christina's avatar
Tamar Christina committed
462 463 464
  BUILD:  $BuildPlatform   (the architecture we're building on)
  HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
  TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
465

Simon Marlow's avatar
Simon Marlow committed
466 467 468 469
BUILD must equal HOST; that is, we do not support building GHC itself
with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
1 will be a cross-compiler, and stage 2 will be the cross-compiled
GHC.
470 471
])
fi
472 473 474
# Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
# in calls to subproject configure scripts and thus must be set to the autoconf
# triple, not the normalized GHC triple that TargetPlatform is set to.
475 476 477 478 479 480 481 482
#
# We use the non-canonicalized triple, target_alias, here since the subproject
# configure scripts will use this triple to construct the names of the toolchain
# executables. If we instead passed down the triple produced by
# AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
# name (this is a known problem in the case of the Android NDK, which has
# slightly odd triples).
#
Gabor Greif's avatar
Gabor Greif committed
483
# It may be better to just do away with the GHC triples altogether. This would
484 485 486
# all be taken care of for us if we configured the subprojects using
# AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
# configuration.
487 488
#
# We also use non-canonicalized triple when install stage1 crosscompiler
489 490 491 492 493 494 495
if test -z "${target_alias}"
then
  # --target wasn't given; use result from AC_CANONICAL_TARGET
  TargetPlatformFull="${target}"
else
  TargetPlatformFull="${target_alias}"
fi
496 497 498 499 500 501 502
if test "$CrossCompiling" = "YES"
then
  # Use value passed by user from --target=
  CrossCompilePrefix="${TargetPlatformFull}-"
else
  CrossCompilePrefix=""
fi
Simon Marlow's avatar
Simon Marlow committed
503
AC_SUBST(CrossCompiling)
504 505
AC_SUBST(CrossCompilePrefix)
AC_SUBST(TargetPlatformFull)
506
AC_SUBST(EnableDistroToolchain)
507

508 509 510
dnl ** Which gcc to use?
dnl --------------------------------------------------------------

511 512 513 514 515 516 517 518 519 520 521 522
AC_ARG_WITH([gcc],
        AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
        AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))

AC_ARG_WITH([clang],
        AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
        AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))

dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
dnl later CC is copied to CC_STAGE{1,2,3}
AC_PROG_CC([gcc clang])

523 524
MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])

525 526 527
dnl make extensions visible to allow feature-tests to detect them lateron
AC_USE_SYSTEM_EXTENSIONS

thomie's avatar
thomie committed
528 529 530
dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
AC_PROG_CPP

531 532
# --with-hs-cpp/--with-hs-cpp-flags
FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
thomie's avatar
thomie committed
533 534
AC_SUBST([HaskellCPPCmd])
AC_SUBST([HaskellCPPArgs])
535

536 537 538 539 540
FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])

John Ericson's avatar
John Ericson committed
541
dnl ** Which ld to use
542
dnl --------------------------------------------------------------
543 544 545 546
FIND_LD([$target],[GccUseLdOpt])
CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
LdCmd="$LD"
547
LdNoGoldCmd="$LD_NO_GOLD"
548
CFLAGS="$CFLAGS $GccUseLdOpt"
549
AC_SUBST([LdCmd])
550
AC_SUBST([LdNoGoldCmd])
551

John Ericson's avatar
John Ericson committed
552 553 554 555 556
FP_PROG_LD_IS_GNU
FP_PROG_LD_BUILD_ID
FP_PROG_LD_NO_COMPACT_UNWIND
FP_PROG_LD_FILELIST

557 558
dnl ** Which nm to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
559 560 561 562 563 564 565 566
if test "$HostOS" != "mingw32"; then
    AC_CHECK_TARGET_TOOL([NM], [nm])
    if test "$NM" = ":"; then
        AC_MSG_ERROR([cannot find nm in your PATH])
    fi
fi
NmCmd="$NM"
AC_SUBST([NmCmd])
567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582

if test "$TargetOS_CPP" = "darwin"
then
    AC_MSG_CHECKING(whether nm program is broken)
    # Some versions of XCode ship a broken version of `nm`. Detect and work
    # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
    nmver=$(${NM} --version | grep version | sed 's/ //g')
    case "$nmver" in
        LLVMversion7.3.0|LLVMversion7.3.1)
            AC_MSG_RESULT(yes)
            echo "The detected nm program is broken."
            echo
            echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
            echo
            echo "Try re-running configure with:"
            echo
Alex Biehl's avatar
Alex Biehl committed
583
            echo '   NM=$(xcrun --find nm-classic) ./configure'
584 585 586 587 588 589 590 591 592
            echo
            exit 1
            ;;
        *)
            AC_MSG_RESULT(no)
            ;;
        esac
fi

593 594
dnl ** Which objdump to use?
dnl --------------------------------------------------------------
595 596
dnl Note: we may not have objdump on OS X, and we only need it on
dnl Windows (for DLL checks), OpenBSD, and AIX
Ben Gamari's avatar
Ben Gamari committed
597
case $HostOS_CPP in
598
  cygwin32|mingw32|openbsd|aix)
Ben Gamari's avatar
Ben Gamari committed
599 600 601 602
    AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
    ;;
esac

603 604 605
ObjdumpCmd="$OBJDUMP"
AC_SUBST([ObjdumpCmd])

606 607
dnl ** Which ranlib to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
608 609 610 611
AC_PROG_RANLIB
if test "$RANLIB" = ":"; then
    AC_MSG_ERROR([cannot find ranlib in your PATH])
fi
612
RanlibCmd="$RANLIB"
John Ericson's avatar
John Ericson committed
613
AC_SUBST([RanlibCmd])
614

615 616 617 618 619 620 621
dnl ** which strip to use?
dnl --------------------------------------------------------------
AC_CHECK_TARGET_TOOL([STRIP], [strip])
StripCmd="$STRIP"
AC_SUBST([StripCmd])


Moritz Angermann's avatar
Moritz Angermann committed
622 623
dnl ** which libtool to use?
dnl --------------------------------------------------------------
624 625
# The host normalization on Windows breaks autoconf, it no longer
# thinks that target == host so it never checks the unqualified
626
# tools for Windows. See #14274.
627 628 629 630 631 632 633 634 635
if test "$HostOS" = "mingw32"
then
    AC_PATH_PROG([LIBTOOL],[libtool])
    LibtoolCmd="$(cygpath -m $LIBTOOL)"
else
    AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
    LibtoolCmd="$LIBTOOL"
fi
AC_SUBST([LibtoolCmd])
636

637 638 639 640
# Here is where we re-target which specific version of the LLVM
# tools we are looking for. In the past, GHC supported a number of
# versions of LLVM simultaneously, but that stopped working around
# 3.5/3.6 release of LLVM.
Moritz Angermann's avatar
Moritz Angermann committed
641
LlvmVersion=5.0
642
AC_SUBST([LlvmVersion])
643 644
sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
645

Moritz Angermann's avatar
Moritz Angermann committed
646 647 648 649 650 651
dnl ** Which LLVM clang to use?
dnl --------------------------------------------------------------
AC_CHECK_TARGET_TOOL([CLANG], [clang])
ClangCmd="$CLANG"
AC_SUBST([ClangCmd])

652 653
dnl ** Which LLVM llc to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
654
FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
655 656 657 658 659
LlcCmd="$LLC"
AC_SUBST([LlcCmd])

dnl ** Which LLVM opt to use?
dnl --------------------------------------------------------------
Ben Gamari's avatar
Ben Gamari committed
660
FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
661 662 663
OptCmd="$OPT"
AC_SUBST([OptCmd])

sof's avatar
sof committed
664 665 666 667 668 669
dnl --------------------------------------------------------------
dnl End of configure script option section
dnl --------------------------------------------------------------


dnl --------------------------------------------------------------
670 671 672
dnl ** Can the unix package be built?
dnl --------------------------------------------------------------

673 674 675
if test "$TargetOS" = "mingw32"
then
    GhcLibsWithUnix=NO
676
else
677
    GhcLibsWithUnix=YES
678 679 680
fi
AC_SUBST([GhcLibsWithUnix])

681 682
dnl ** does #! work?
AC_SYS_INTERPRETER()
sof's avatar
sof committed
683

684 685
# Check for split-objs
SplitObjsBroken=NO
Ian Lynagh's avatar
Ian Lynagh committed
686
dnl ** look for `perl'
rrt's avatar
rrt committed
687 688
case $HostOS_CPP in
cygwin32|mingw32)
689 690 691 692 693
  if test "$EnableDistroToolchain" = "NO"; then
    PerlCmd=$hardtop/inplace/perl/perl
  else
    AC_PATH_PROG([PerlCmd],[perl])
  fi
694
  ;;
rrt's avatar
rrt committed
695
*)
696
    AC_PATH_PROG([PerlCmd],[perl])
Ian Lynagh's avatar
Ian Lynagh committed
697 698
    if test -z "$PerlCmd"
    then
699 700
        AC_MSG_WARN([No Perl on PATH, disabling split object support])
        SplitObjsBroken=YES
Ian Lynagh's avatar
Ian Lynagh committed
701 702 703 704
    else
        FPTOOLS_CHECK_PERL_VERSION
    fi
    ;;
rrt's avatar
rrt committed
705
esac
706
AC_SUBST([SplitObjsBroken])
sof's avatar
sof committed
707

rrt's avatar
rrt committed
708 709
dnl ** look for GCC and find out which version
dnl     Figure out which C compiler to use.  Gcc is preferred.
Gabor Greif's avatar
Gabor Greif committed
710
dnl     If gcc, make sure it's at least 3.0
rrt's avatar
rrt committed
711
dnl
712
FP_GCC_VERSION
713

Ben Gamari's avatar
Ben Gamari committed
714 715 716
dnl ** See whether gcc supports -no-pie
FP_GCC_SUPPORTS_NO_PIE

717 718 719 720 721
dnl ** Used to determine how to compile ghc-prim's atomics.c, used by
dnl    unregisterised, Sparc, and PPC backends.
FP_GCC_SUPPORTS__ATOMICS
AC_DEFINE([HAVE_C11_ATOMICS], [$CONF_GCC_SUPPORTS__ATOMICS], [Does GCC support __atomic primitives?])

John Ericson's avatar
John Ericson committed
722 723
FP_GCC_EXTRA_FLAGS

724 725 726 727
dnl ** look to see if we have a C compiler using an llvm back end.
dnl
FP_CC_LLVM_BACKEND

728 729 730 731
FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
732
# Stage 3 won't be supported by cross-compilation
733

734 735
# See rules/distdir-way-opts.mk for details.
# Flags passed to the C compiler
736 737 738
AC_SUBST(CONF_CC_OPTS_STAGE0)
AC_SUBST(CONF_CC_OPTS_STAGE1)
AC_SUBST(CONF_CC_OPTS_STAGE2)
739
# Flags passed to the C compiler when we ask it to link
740 741 742
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
743
# Flags passed to the linker when we ask it to link
744 745 746
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
747
# Flags passed to the C preprocessor
748 749 750
AC_SUBST(CONF_CPP_OPTS_STAGE0)
AC_SUBST(CONF_CPP_OPTS_STAGE1)
AC_SUBST(CONF_CPP_OPTS_STAGE2)
751 752 753 754
# Flags passed to the Haskell compiler
AC_SUBST(CONF_HC_OPTS_STAGE0)
AC_SUBST(CONF_HC_OPTS_STAGE1)
AC_SUBST(CONF_HC_OPTS_STAGE2)
rrt's avatar
rrt committed
755

756 757 758 759 760
dnl ** Set up the variables for the platform in the settings file.
dnl May need to use gcc to find platform details.
dnl --------------------------------------------------------------
FPTOOLS_SET_HASKELL_PLATFORM_VARS

761
dnl ** figure out how to do context diffs
762
FP_PROG_CONTEXT_DIFF
sof's avatar
sof committed
763

764 765 766
dnl Let's make sure install-sh is executable here.  If we got it from
dnl a darcs repo, it might not be (see bug #978).
chmod +x install-sh
767 768
dnl ** figure out how to do a BSD-ish install
AC_PROG_INSTALL
sof's avatar
sof committed
769

sof's avatar
sof committed
770
dnl ** how to invoke `ar' and `ranlib'
771
FP_PROG_AR_SUPPORTS_ATFILE
772
FP_PROG_AR_NEEDS_RANLIB
sof's avatar
sof committed
773

774
dnl ** Check to see whether ln -s works
sof's avatar
sof committed
775 776
AC_PROG_LN_S

777
FP_SETTINGS
sof's avatar
sof committed
778 779

dnl ** Find the path to sed
Ian Lynagh's avatar
Ian Lynagh committed
780
AC_PATH_PROGS(SedCmd,gsed sed,sed)
sof's avatar
sof committed
781

sof's avatar
sof committed
782 783

dnl ** check for time command
sof's avatar
sof committed
784 785
AC_PATH_PROG(TimeCmd,time)

sof's avatar
sof committed
786 787
dnl ** check for tar
dnl   if GNU tar is named gtar, look for it first.
788
AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
sof's avatar
sof committed
789

790 791 792 793 794
dnl ** check for compressors
AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
AC_PATH_PROGS(GzipCmd,gzip, gzip)
AC_PATH_PROGS(XzCmd,pxz xz, xz)

Ian Lynagh's avatar
Ian Lynagh committed
795 796 797 798
dnl ** check for patch
dnl if GNU patch is named gpatch, look for it first
AC_PATH_PROGS(PatchCmd,gpatch patch, patch)

799
dnl ** check for dtrace (currently only implemented for Mac OS X)
800 801 802 803 804 805 806
AC_ARG_ENABLE(dtrace,
    [AC_HELP_STRING([--enable-dtrace],
        [Enable DTrace])],
    EnableDtrace=$enableval,
    EnableDtrace=yes
)

807
HaveDtrace=NO
808

809
AC_PATH_PROG(DtraceCmd,dtrace)
810 811 812 813 814 815 816
if test "x$EnableDtrace" = "xyes"; then
  if test -n "$DtraceCmd"; then
    if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
      -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
      -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
      HaveDtrace=YES
    fi
817 818 819 820
  fi
fi
AC_SUBST(HaveDtrace)

821
AC_PATH_PROG(HSCOLOUR,HsColour)
822
# HsColour is passed to Cabal, so we need a native path
823
if test "$HostOS"      = "mingw32" && \
824
   test "${OSTYPE}"   != "msys"    && \
825
   test "${HSCOLOUR}" != ""
826 827 828
then
    # Canonicalise to <drive>:/path/to/gcc
    HSCOLOUR=`cygpath -m ${HSCOLOUR}`
829
fi
830

831
dnl ** check for Sphinx toolchain
832 833
AC_PATH_PROG(SPHINXBUILD,sphinx-build)
AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
834 835
changequote(, )dnl
[if test -n "$SPHINXBUILD"; then
836
  fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
837 838 839
fi;
changequote([, ])dnl
])
840 841
FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
    [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
842 843 844

dnl ** check for xelatex
AC_PATH_PROG(XELATEX,xelatex)
845

reid's avatar
reid committed
846
dnl ** check for ghc-pkg command
847
FP_PROG_GHC_PKG
reid's avatar
reid committed
848

sof's avatar
sof committed
849
dnl ** check for installed happy binary + version
sof's avatar
sof committed
850
FPTOOLS_HAPPY
sof's avatar
sof committed
851

852 853 854
dnl ** check for installed alex binary + version
FPTOOLS_ALEX

sof's avatar
sof committed
855 856 857
dnl --------------------------------------------------
dnl ### program checking section ends here ###
dnl --------------------------------------------------
sof's avatar
sof committed
858

sof's avatar
sof committed
859 860 861
dnl --------------------------------------------------
dnl * Platform header file and syscall feature tests
dnl ### checking the state of the local header files and syscalls ###
sof's avatar
sof committed
862

863 864
dnl ** check for full ANSI header (.h) files
AC_HEADER_STDC
sof's avatar
sof committed
865

866 867 868 869
dnl ** Enable large file support.  NB. do this before testing the type of
dnl    off_t, because it will affect the result of that test.
AC_SYS_LARGEFILE

870
dnl ** check for specific header (.h) files that we are interested in
871
AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
872 873 874 875 876 877 878

dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
AC_CHECK_HEADERS([sys/cpuset.h], [], [],
[[#if HAVE_SYS_PARAM_H
# include <sys/param.h>
#endif
]])
879

880 881
dnl ** check if it is safe to include both <time.h> and <sys/time.h>
AC_HEADER_TIME
sof's avatar
sof committed
882

883
dnl ** do we have long longs?
884
AC_CHECK_TYPES([long long])
885

reid's avatar
reid committed
886
dnl ** what are the sizes of various types
887 888 889 890 891
FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
892
if test "$ac_cv_type_long_long" = yes; then
893
FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
894
fi
895 896 897 898
FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
899
if test "$ac_cv_type_long_long" = yes; then
900
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
901
fi
902 903 904 905 906 907 908 909 910 911 912 913
FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)

FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)

reid's avatar
reid committed
914

915
dnl for use in settings.in
916
TargetWordSize=$ac_cv_sizeof_void_p
Moritz Angermann's avatar
Moritz Angermann committed
917 918 919 920 921
if test "x$TargetWordSize" == 8; then
  AC_SUBST([Cabal64bit],[True])
else
  AC_SUBST([Cabal64bit],[False])
fi
922
AC_SUBST(TargetWordSize)
923 924
FP_CHECK_FUNC([WinExec],
  [@%:@include <windows.h>], [WinExec("",0)])
reid's avatar
reid committed
925

926 927
FP_CHECK_FUNC([GetModuleFileName],
  [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
reid's avatar
reid committed
928 929

dnl ** check for more functions
930
dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
931
AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
932

rl@cse.unsw.edu.au's avatar
rl@cse.unsw.edu.au committed
933 934 935 936 937 938 939
dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
dnl ** _POSIX_C_SOURCE is defined
AC_CHECK_DECLS([ctime_r], , ,
[#define _POSIX_SOURCE 1
#define _POSIX_C_SOURCE 199506L
#include <time.h>])

940
dnl ** check for mingwex library
Ben Gamari's avatar
Ben Gamari committed
941 942 943 944 945
AC_CHECK_LIB(
  [mingwex],
  [closedir],
  [AC_SUBST([HaveLibMingwEx],[YES])] [AC_SUBST([CabalMingwex],[True])],
  [AC_SUBST([HaveLibMingwEx],[NO])] [AC_SUBST([CabalMingwex],[False])])
946 947

if test $HaveLibMingwEx = YES ; then
948
  AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
949 950
fi

sebc's avatar
sebc committed
951
dnl ** check for math library
952 953 954
dnl    Keep that check as early as possible.
dnl    as we need to know whether we need libm
dnl    for math functions or not
955
dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
956 957 958 959
AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
if test $HaveLibM = YES
then
  AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
Moritz Angermann's avatar
Moritz Angermann committed
960 961 962
  AC_SUBST([CabalHaveLibm],[True])
else
  AC_SUBST([CabalHaveLibm],[False])
963
fi
sebc's avatar
sebc committed
964

965
FP_BFD_SUPPORT
966

reid's avatar
reid committed
967 968 969 970
dnl ################################################################
dnl Check for libraries
dnl ################################################################

971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013
# system libffi

AC_ARG_WITH([system-libffi],
[AC_HELP_STRING([--with-system-libffi],
  [Use system provided libffi for RTS [default=no]])
])

AS_IF([test "x$with_system_libffi" = "xyes"],
  [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
)


AC_SUBST(UseSystemLibFFI)

AC_ARG_WITH([ffi-includes],
[AC_HELP_STRING([--with-ffi-includes=ARG],
  [Find includes for libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
 else
    FFIIncludeDir="$withval"
    LIBFFI_CFLAGS="-I$withval"
 fi
])

AC_SUBST(FFIIncludeDir)

AC_ARG_WITH([ffi-libraries],
[AC_HELP_STRING([--with-ffi-libraries=ARG],
  [Find libffi in ARG [default=system default]])
],
[
 if test "x$UseSystemLibFFI" != "xYES"; then
    AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
 else
    FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
 fi
])

AC_SUBST(FFILibDir)

Moritz Angermann's avatar
Moritz Angermann committed
1014
AC_SUBST([CabalHaveLibffi],[False])
1015 1016 1017 1018 1019
AS_IF([test "$UseSystemLibFFI" = "YES"], [
 CFLAGS2="$CFLAGS"
 CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
 LDFLAGS2="$LDFLAGS"
 LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
1020 1021 1022 1023 1024 1025 1026 1027 1028
 if test "$HostOS" = "openbsd";
 then
   # OpenBSD's libffi is not directly linked to the libpthread but
   # still requires pthread functionality. This means that any client
   # binary which links with libffi also needs to link with
   # libpthread. If it does not, then linking fails with unresolved
   # symbols.
   LDFLAGS="$LDFLAGS -lpthread"
 fi
1029 1030
 AC_CHECK_LIB(ffi, ffi_call,
  [AC_CHECK_HEADERS([ffi.h], [break], [])
Moritz Angermann's avatar
Moritz Angermann committed
1031 1032
   AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])]
   AC_SUBST([CabalHaveLibffi],[True]),
1033 1034 1035 1036 1037
  [AC_MSG_ERROR([Cannot find system libffi])])
 CFLAGS="$CFLAGS2"
 LDFLAGS="$LDFLAGS2"
])

ross's avatar
ross committed
1038
dnl ** check whether we need -ldl to get dlopen()
Moritz Angermann's avatar
Moritz Angermann committed
1039 1040
AC_CHECK_LIB([dl], [dlopen])
AC_CHECK_LIB([dl], [dlopen], [AC_SUBST([CabalHaveLibdl], [True])], [AC_SUBST([CabalHaveLibdl], [False])])
1041

1042
dnl --------------------------------------------------
sof's avatar
sof committed
1043 1044 1045
dnl * Miscellaneous feature tests
dnl --------------------------------------------------

sof's avatar
sof committed
1046
dnl ** can we get alloca?
1047
AC_FUNC_ALLOCA
sof's avatar
sof committed
1048

1049
dnl ** working vfork?
1050
AC_FUNC_FORK
1051

1052 1053
dnl ** determine whether or not const works
AC_C_CONST
sof's avatar
sof committed
1054

1055 1056
dnl ** are we big endian?
AC_C_BIGENDIAN
1057
FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
sof's avatar
sof committed
1058

1059
dnl ** check for leading underscores in symbol names
1060
FP_LEADING_UNDERSCORE
1061

1062 1063
FP_VISIBILITY_HIDDEN

1064
dnl ** check for librt
Moritz Angermann's avatar
Moritz Angermann committed
1065 1066
AC_CHECK_LIB([rt], [clock_gettime])
AC_CHECK_LIB([rt], [clock_gettime], [AC_SUBST([CabalHaveLibrt], [True])], [AC_SUBST([CabalHaveLibrt], [False])])
1067
AC_CHECK_FUNCS(clock_gettime timer_settime)
1068
FP_CHECK_TIMER_CREATE
1069

1070
dnl ** check for Apple's "interesting" long double compatibility scheme
1071 1072
AC_MSG_CHECKING(for printf\$LDBLStub)
AC_TRY_LINK_FUNC(printf\$LDBLStub,
1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083
    [
        AC_MSG_RESULT(yes)
        AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
            [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
    ],
    [
        AC_MSG_RESULT(no)
        AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
            [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
    ])

1084 1085 1086 1087 1088 1089 1090 1091 1092
dnl Some platforms (e.g. Android's Bionic) have pthreads support available
dnl without linking against libpthread. Check whether -lpthread is necessary
dnl to use pthreads.
dnl
dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
AC_CHECK_FUNC(pthread_create,
    [
        AC_MSG_RESULT(no)
Moritz Angermann's avatar
Moritz Angermann committed
1093
        AC_SUBST([CabalNeedLibpthread],[False])
1094 1095 1096 1097 1098 1099
        need_lpthread=0
    ],
    [
        AC_CHECK_LIB(pthread, pthread_create,
            [
                AC_MSG_RESULT(yes)
Moritz Angermann's avatar
Moritz Angermann committed
1100
                AC_SUBST([CabalNeedLibpthread],[True])
1101 1102 1103
                need_lpthread=1
            ],
            [
Moritz Angermann's avatar
Moritz Angermann committed
1104
                AC_SUBST([CabalNeedLibpthread],[False])
1105 1106 1107 1108 1109 1110 1111
                AC_MSG_RESULT([no pthreads support found.])
                need_lpthread=0
            ])
    ])
AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
    [Define 1 if we need to link code using pthreads with -lpthread])

1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127
dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
dnl    a different single-argument version.
AC_CHECK_LIB(pthread, pthread_setname_np)
AC_MSG_CHECKING(for pthread_setname_np)
AC_TRY_LINK(
[
#define _GNU_SOURCE
#include <pthread.h>
],
[pthread_setname_np(pthread_self(), "name");],
    AC_MSG_RESULT(yes)
    AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
      [Define to 1 if you have the glibc version of pthread_setname_np]),
    AC_MSG_RESULT(no)
)

1128 1129 1130 1131
dnl ** check for eventfd which is needed by the I/O manager
AC_CHECK_HEADERS([sys/eventfd.h])
AC_CHECK_FUNCS([eventfd])

1132 1133 1134 1135 1136 1137
dnl ** Check for __thread support in the compiler
AC_MSG_CHECKING(for __thread support)
AC_COMPILE_IFELSE(
  [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
  [
   AC_MSG_RESULT(yes)
1138
   AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1139 1140 1141
  ],
  [
   AC_MSG_RESULT(no)
Peter Trommler's avatar