Syntax.hs 44.7 KB
Newer Older
1
{-# LANGUAGE UnboxedTuples #-}
2

3 4 5 6 7
-----------------------------------------------------------------------------
-- |
-- Module      :  Language.Haskell.Syntax
-- Copyright   :  (c) The University of Glasgow 2003
-- License     :  BSD-style (see the file libraries/base/LICENSE)
Jan Stolarek's avatar
Jan Stolarek committed
8
--
9 10 11 12 13 14 15 16
-- Maintainer  :  libraries@haskell.org
-- Stability   :  experimental
-- Portability :  portable
--
-- Abstract syntax definitions for Template Haskell.
--
-----------------------------------------------------------------------------

17
module Language.Haskell.TH.Syntax where
18

19
import GHC.Exts
20
import Data.Data (Data(..), Typeable, mkConstr, mkDataType, constrIndex)
Ross Paterson's avatar
Ross Paterson committed
21
import qualified Data.Data as Data
22
import Control.Applicative( Applicative(..) )
23
import Data.IORef
24
import System.IO.Unsafe	( unsafePerformIO )
25
import Control.Monad (liftM)
26
import System.IO	( hPutStrLn, stderr )
27
import Data.Char        ( isAlpha )
reinerp's avatar
reinerp committed
28
import Data.Word        ( Word8 )
29 30 31 32 33 34 35

-----------------------------------------------------
--
--		The Quasi class
--
-----------------------------------------------------

36
class (Monad m, Applicative m) => Quasi m where
37
  qNewName :: String -> m Name
aavogt's avatar
aavogt committed
38
	-- ^ Fresh names
39 40

	-- Error reporting and recovery
aavogt's avatar
aavogt committed
41
  qReport  :: Bool -> String -> m ()	-- ^ Report an error (True) or warning (False)
42
					-- ...but carry on; use 'fail' to stop
aavogt's avatar
aavogt committed
43 44 45
  qRecover :: m a -- ^ the error handler
           -> m a -- ^ action which may fail
           -> m a		-- ^ Recover from the monadic 'fail'
Jan Stolarek's avatar
Jan Stolarek committed
46

47
	-- Inspect the type-checker's environment
48 49 50 51 52
  qLookupName :: Bool -> String -> m (Maybe Name)
       -- True <=> type namespace, False <=> value namespace
  qReify          :: Name -> m Info
  qReifyInstances :: Name -> [Type] -> m [Dec]
       -- Is (n tys) an instance?
Jan Stolarek's avatar
Jan Stolarek committed
53
       -- Returns list of matching instance Decs
54 55
       --    (with empty sub-Decs)
       -- Works for classes and type functions
56
  qReifyRoles     :: Name -> m [Role]
57

58
  qLocation :: m Loc
59 60

  qRunIO :: IO a -> m a
aavogt's avatar
aavogt committed
61
  -- ^ Input/output (dangerous)
62

GregWeber's avatar
GregWeber committed
63
  qAddDependentFile :: FilePath -> m ()
64 65 66

-----------------------------------------------------
--	The IO instance of Quasi
Jan Stolarek's avatar
Jan Stolarek committed
67
--
68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83
--  This instance is used only when running a Q
--  computation in the IO monad, usually just to
--  print the result.  There is no interesting
--  type environment, so reification isn't going to
--  work.
--
-----------------------------------------------------

instance Quasi IO where
  qNewName s = do { n <- readIORef counter
                 ; writeIORef counter (n+1)
                 ; return (mkNameU s n) }

  qReport True  msg = hPutStrLn stderr ("Template Haskell error: " ++ msg)
  qReport False msg = hPutStrLn stderr ("Template Haskell error: " ++ msg)

84
  qLookupName _ _     = badIO "lookupName"
85
  qReify _            = badIO "reify"
86
  qReifyInstances _ _ = badIO "classInstances"
87
  qReifyRoles _       = badIO "reifyRoles"
88 89
  qLocation    	      = badIO "currentLocation"
  qRecover _ _ 	      = badIO "recover" -- Maybe we could fix this?
GregWeber's avatar
GregWeber committed
90
  qAddDependentFile _ = badIO "addDependentFile"
91 92

  qRunIO m = m
Jan Stolarek's avatar
Jan Stolarek committed
93

94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111
badIO :: String -> IO a
badIO op = do	{ qReport True ("Can't do `" ++ op ++ "' in the IO monad")
		; fail "Template Haskell failure" }

-- Global variable to generate unique symbols
counter :: IORef Int
{-# NOINLINE counter #-}
counter = unsafePerformIO (newIORef 0)


-----------------------------------------------------
--
--		The Q monad
--
-----------------------------------------------------

newtype Q a = Q { unQ :: forall m. Quasi m => m a }

112 113 114 115 116
-- \"Runs\" the 'Q' monad. Normal users of Template Haskell
-- should not need this function, as the splice brackets @$( ... )@
-- are the usual way of running a 'Q' computation.
--
-- This function is primarily used in GHC internals, and for debugging
Jan Stolarek's avatar
Jan Stolarek committed
117
-- splices by running them in 'IO'.
118 119 120 121 122
--
-- Note that many functions in 'Q', such as 'reify' and other compiler
-- queries, are not supported when running 'Q' in 'IO'; these operations
-- simply fail at runtime. Indeed, the only operations guaranteed to succeed
-- are 'newName', 'runIO', 'reportError' and 'reportWarning'.
123 124 125 126 127 128 129
runQ :: Quasi m => Q a -> m a
runQ (Q m) = m

instance Monad Q where
  return x   = Q (return x)
  Q m >>= k  = Q (m >>= \x -> unQ (k x))
  Q m >> Q n = Q (m >> n)
130
  fail s     = report True s >> Q (fail "Q monad failure")
131

132 133 134
instance Functor Q where
  fmap f (Q x) = Q (fmap f x)

Jan Stolarek's avatar
Jan Stolarek committed
135 136 137
instance Applicative Q where
  pure x = Q (pure x)
  Q f <*> Q x = Q (f <*> x)
138

gmainland's avatar
gmainland committed
139 140 141 142 143 144 145 146
-----------------------------------------------------
--
--		The TExp type
--
-----------------------------------------------------

newtype TExp a = TExp { unType :: Q Exp }

147 148
----------------------------------------------------
-- Packaged versions for the programmer, hiding the Quasi-ness
149

Jan Stolarek's avatar
Jan Stolarek committed
150 151
{- |
Generate a fresh name, which cannot be captured.
152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183

For example, this:

@f = $(do
  nm1 <- newName \"x\"
  let nm2 = 'mkName' \"x\"
  return ('LamE' ['VarP' nm1] (LamE [VarP nm2] ('VarE' nm1)))
 )@

will produce the splice

>f = \x0 -> \x -> x0

In particular, the occurrence @VarE nm1@ refers to the binding @VarP nm1@,
and is not captured by the binding @VarP nm2@.

Although names generated by @newName@ cannot /be captured/, they can
/capture/ other names. For example, this:

>g = $(do
>  nm1 <- newName "x"
>  let nm2 = mkName "x"
>  return (LamE [VarP nm2] (LamE [VarP nm1] (VarE nm2)))
> )

will produce the splice

>g = \x -> \x0 -> x0

since the occurrence @VarE nm2@ is captured by the innermost binding
of @x@, namely @VarP nm1@.
-}
184 185 186
newName :: String -> Q Name
newName s = Q (qNewName s)

Jan Stolarek's avatar
Jan Stolarek committed
187
-- | Report an error (True) or warning (False),
188
-- but carry on; use 'fail' to stop.
189 190
report  :: Bool -> String -> Q ()
report b s = Q (qReport b s)
191
{-# DEPRECATED report "Use reportError or reportWarning instead" #-} -- deprecated in 7.6
192 193 194 195 196 197 198 199

-- | Report an error to the user, but allow the current splice's computation to carry on. To abort the computation, use 'fail'.
reportError :: String -> Q ()
reportError = report True

-- | Report a warning to the user, and carry on.
reportWarning :: String -> Q ()
reportWarning = report False
200

201 202 203
-- | Recover from errors raised by 'reportError' or 'fail'.
recover :: Q a -- ^ handler to invoke on failure
        -> Q a -- ^ computation to run
aavogt's avatar
aavogt committed
204
        -> Q a
205 206
recover (Q r) (Q m) = Q (qRecover r m)

207 208 209 210 211
-- We don't export lookupName; the Bool isn't a great API
-- Instead we export lookupTypeName, lookupValueName
lookupName :: Bool -> String -> Q (Maybe Name)
lookupName ns s = Q (qLookupName ns s)

212 213
-- | Look up the given name in the (type namespace of the) current splice's scope. See "Language.Haskell.TH.Syntax#namelookup" for more details.
lookupTypeName :: String -> Q (Maybe Name)
214
lookupTypeName  s = Q (qLookupName True s)
215 216 217

-- | Look up the given name in the (value namespace of the) current splice's scope. See "Language.Haskell.TH.Syntax#namelookup" for more details.
lookupValueName :: String -> Q (Maybe Name)
218 219
lookupValueName s = Q (qLookupName False s)

220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235
{-
Note [Name lookup]
~~~~~~~~~~~~~~~~~~
-}
{- $namelookup #namelookup#
The functions 'lookupTypeName' and 'lookupValueName' provide
a way to query the current splice's context for what names
are in scope. The function 'lookupTypeName' queries the type
namespace, whereas 'lookupValueName' queries the value namespace,
but the functions are otherwise identical.

A call @lookupValueName s@ will check if there is a value
with name @s@ in scope at the current splice's location. If
there is, the @Name@ of this value is returned;
if not, then @Nothing@ is returned.

Jan Stolarek's avatar
Jan Stolarek committed
236
The returned name cannot be \"captured\".
237 238 239 240 241 242 243 244 245 246 247 248 249 250 251
For example:

> f = "global"
> g = $( do
>          Just nm <- lookupValueName "f"
>          [| let f = "local" in $( varE nm ) |]

In this case, @g = \"global\"@; the call to @lookupValueName@
returned the global @f@, and this name was /not/ captured by
the local definition of @f@.

The lookup is performed in the context of the /top-level/ splice
being run. For example:

> f = "global"
Jan Stolarek's avatar
Jan Stolarek committed
252
> g = $( [| let f = "local" in
253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288
>            $(do
>                Just nm <- lookupValueName "f"
>                varE nm
>             ) |] )

Again in this example, @g = \"global\"@, because the call to
@lookupValueName@ queries the context of the outer-most @$(...)@.

Operators should be queried without any surrounding parentheses, like so:

> lookupValueName "+"

Qualified names are also supported, like so:

> lookupValueName "Prelude.+"
> lookupValueName "Prelude.map"

-}


{- | 'reify' looks up information about the 'Name'.

It is sometimes useful to construct the argument name using 'lookupTypeName' or 'lookupValueName'
to ensure that we are reifying from the right namespace. For instance, in this context:

> data D = D

which @D@ does @reify (mkName \"D\")@ return information about? (Answer: @D@-the-type, but don't rely on it.)
To ensure we get information about @D@-the-value, use 'lookupValueName':

> do
>   Just nm <- lookupValueName "D"
>   reify nm

and to get information about @D@-the-type, use 'lookupTypeName'.
-}
289 290 291
reify :: Name -> Q Info
reify v = Q (qReify v)

Jan Stolarek's avatar
Jan Stolarek committed
292
{- | @reifyInstances nm tys@ returns a list of visible instances of @nm tys@. That is,
293 294 295 296 297
if @nm@ is the name of a type class, then all instances of this class at the types @tys@
are returned. Alternatively, if @nm@ is the name of a data family or type family,
all instances of this family at the types @tys@ are returned.
-}
reifyInstances :: Name -> [Type] -> Q [InstanceDec]
298
reifyInstances cls tys = Q (qReifyInstances cls tys)
299

300 301 302 303 304 305 306
{- | @reifyRoles nm@ returns the list of roles associated with the parameters of
the tycon @nm@. Fails if @nm@ cannot be found or is not a tycon.
The returned list should never contain 'InferR'.
-}
reifyRoles :: Name -> Q [Role]
reifyRoles nm = Q (qReifyRoles nm)

307
-- | Is the list of instances returned by 'reifyInstances' nonempty?
308 309 310
isInstance :: Name -> [Type] -> Q Bool
isInstance nm tys = do { decs <- reifyInstances nm tys
                       ; return (not (null decs)) }
311

312
-- | The location at which this computation is spliced.
313 314
location :: Q Loc
location = Q qLocation
315

dons's avatar
dons committed
316
-- |The 'runIO' function lets you run an I\/O computation in the 'Q' monad.
Jan Stolarek's avatar
Jan Stolarek committed
317 318
-- Take care: you are guaranteed the ordering of calls to 'runIO' within
-- a single 'Q' computation, but not about the order in which splices are run.
319
--
Jan Stolarek's avatar
Jan Stolarek committed
320
-- Note: for various murky reasons, stdout and stderr handles are not
321 322
-- necesarily flushed when the  compiler finishes running, so you should
-- flush them yourself.
323 324 325
runIO :: IO a -> Q a
runIO m = Q (qRunIO m)

GregWeber's avatar
GregWeber committed
326 327 328 329 330 331 332
-- | Record external files that runIO is using (dependent upon).
-- The compiler can then recognize that it should re-compile the file using this TH when the external file changes.
-- Note that ghc -M will still not know about these dependencies - it does not execute TH.
-- Expects an absolute file path.
addDependentFile :: FilePath -> Q ()
addDependentFile fp = Q (qAddDependentFile fp)

333
instance Quasi Q where
GregWeber's avatar
GregWeber committed
334 335
  qNewName  	    = newName
  qReport   	    = report
Jan Stolarek's avatar
Jan Stolarek committed
336
  qRecover  	    = recover
GregWeber's avatar
GregWeber committed
337 338
  qReify    	    = reify
  qReifyInstances   = reifyInstances
339
  qReifyRoles       = reifyRoles
GregWeber's avatar
GregWeber committed
340 341 342 343
  qLookupName       = lookupName
  qLocation 	    = location
  qRunIO    	    = runIO
  qAddDependentFile = addDependentFile
344 345 346 347


----------------------------------------------------
-- The following operations are used solely in DsMeta when desugaring brackets
348
-- They are not necessary for the user, who can use ordinary return and (>>=) etc
349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367

returnQ :: a -> Q a
returnQ = return

bindQ :: Q a -> (a -> Q b) -> Q b
bindQ = (>>=)

sequenceQ :: [Q a] -> Q [a]
sequenceQ = sequence


-----------------------------------------------------
--
--		The Lift class
--
-----------------------------------------------------

class Lift t where
  lift :: t -> Q Exp
Jan Stolarek's avatar
Jan Stolarek committed
368

369 370 371 372 373 374 375 376 377 378 379 380 381
instance Lift Integer where
  lift x = return (LitE (IntegerL x))

instance Lift Int where
  lift x= return (LitE (IntegerL (fromIntegral x)))

instance Lift Char where
  lift x = return (LitE (CharL x))

instance Lift Bool where
  lift True  = return (ConE trueName)
  lift False = return (ConE falseName)

382 383 384 385 386 387 388 389
instance Lift a => Lift (Maybe a) where
  lift Nothing  = return (ConE nothingName)
  lift (Just x) = liftM (ConE justName `AppE`) (lift x)

instance (Lift a, Lift b) => Lift (Either a b) where
  lift (Left x)  = liftM (ConE leftName  `AppE`) (lift x)
  lift (Right y) = liftM (ConE rightName `AppE`) (lift y)

390 391 392
instance Lift a => Lift [a] where
  lift xs = do { xs' <- mapM lift xs; return (ListE xs') }

393 394 395 396
liftString :: String -> Q Exp
-- Used in TcExpr to short-circuit the lifting for strings
liftString s = return (LitE (StringL s))

397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423
instance (Lift a, Lift b) => Lift (a, b) where
  lift (a, b)
    = liftM TupE $ sequence [lift a, lift b]

instance (Lift a, Lift b, Lift c) => Lift (a, b, c) where
  lift (a, b, c)
    = liftM TupE $ sequence [lift a, lift b, lift c]

instance (Lift a, Lift b, Lift c, Lift d) => Lift (a, b, c, d) where
  lift (a, b, c, d)
    = liftM TupE $ sequence [lift a, lift b, lift c, lift d]

instance (Lift a, Lift b, Lift c, Lift d, Lift e)
      => Lift (a, b, c, d, e) where
  lift (a, b, c, d, e)
    = liftM TupE $ sequence [lift a, lift b, lift c, lift d, lift e]

instance (Lift a, Lift b, Lift c, Lift d, Lift e, Lift f)
      => Lift (a, b, c, d, e, f) where
  lift (a, b, c, d, e, f)
    = liftM TupE $ sequence [lift a, lift b, lift c, lift d, lift e, lift f]

instance (Lift a, Lift b, Lift c, Lift d, Lift e, Lift f, Lift g)
      => Lift (a, b, c, d, e, f, g) where
  lift (a, b, c, d, e, f, g)
    = liftM TupE $ sequence [lift a, lift b, lift c, lift d, lift e, lift f, lift g]

424 425 426 427
-- TH has a special form for literal strings,
-- which we should take advantage of.
-- NB: the lhs of the rule has no args, so that
--     the rule will apply to a 'lift' all on its own
Jan Stolarek's avatar
Jan Stolarek committed
428
--     which happens to be the way the type checker
429 430 431 432 433
--     creates it.
{-# RULES "TH:liftString" lift = \s -> return (LitE (StringL s)) #-}


trueName, falseName :: Name
Ian Lynagh's avatar
Ian Lynagh committed
434 435
trueName  = mkNameG DataName "ghc-prim" "GHC.Types" "True"
falseName = mkNameG DataName "ghc-prim" "GHC.Types" "False"
436

437 438 439 440 441 442 443 444
nothingName, justName :: Name
nothingName = mkNameG DataName "base" "Data.Maybe" "Nothing"
justName    = mkNameG DataName "base" "Data.Maybe" "Just"

leftName, rightName :: Name
leftName  = mkNameG DataName "base" "Data.Either" "Left"
rightName = mkNameG DataName "base" "Data.Either" "Right"

445 446

-----------------------------------------------------
Jan Stolarek's avatar
Jan Stolarek committed
447
--		Names and uniques
448 449
-----------------------------------------------------

450 451 452 453 454 455 456 457 458
newtype ModName = ModName String	-- Module name
 deriving (Eq,Ord,Typeable,Data)

newtype PkgName = PkgName String	-- package name
 deriving (Eq,Ord,Typeable,Data)

newtype OccName = OccName String
 deriving (Eq,Ord,Typeable,Data)

459
mkModName :: String -> ModName
460
mkModName s = ModName s
461 462

modString :: ModName -> String
463
modString (ModName m) = m
464

465 466

mkPkgName :: String -> PkgName
467
mkPkgName s = PkgName s
468 469

pkgString :: PkgName -> String
470
pkgString (PkgName m) = m
471 472


473 474 475 476 477
-----------------------------------------------------
--		OccName
-----------------------------------------------------

mkOccName :: String -> OccName
478
mkOccName s = OccName s
479 480

occString :: OccName -> String
481
occString (OccName occ) = occ
482 483 484 485 486


-----------------------------------------------------
--		 Names
-----------------------------------------------------
Jan Stolarek's avatar
Jan Stolarek committed
487
--
aavogt's avatar
aavogt committed
488
-- For "global" names ('NameG') we need a totally unique name,
489 490
-- so we must include the name-space of the thing
--
aavogt's avatar
aavogt committed
491
-- For unique-numbered things ('NameU'), we've got a unique reference
492 493
-- anyway, so no need for name space
--
aavogt's avatar
aavogt committed
494
-- For dynamically bound thing ('NameS') we probably want them to
495 496
-- in a context-dependent way, so again we don't want the name
-- space.  For example:
aavogt's avatar
aavogt committed
497 498 499
--
-- > let v = mkName "T" in [| data $v = $v |]
--
500
-- Here we use the same Name for both type constructor and data constructor
aavogt's avatar
aavogt committed
501 502 503 504 505 506 507 508 509 510
--
--
-- NameL and NameG are bound *outside* the TH syntax tree
-- either globally (NameG) or locally (NameL). Ex:
--
-- > f x = $(h [| (map, x) |])
--
-- The 'map' will be a NameG, and 'x' wil be a NameL
--
-- These Names should never appear in a binding position in a TH syntax tree
511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535

{- $namecapture #namecapture#
Much of 'Name' API is concerned with the problem of /name capture/, which
can be seen in the following example.

> f expr = [| let x = 0 in $expr |]
> ...
> g x = $( f [| x |] )
> h y = $( f [| y |] )

A naive desugaring of this would yield:

> g x = let x = 0 in x
> h y = let x = 0 in y

All of a sudden, @g@ and @h@ have different meanings! In this case,
we say that the @x@ in the RHS of @g@ has been /captured/
by the binding of @x@ in @f@.

What we actually want is for the @x@ in @f@ to be distinct from the
@x@ in @g@, so we get the following desugaring:

> g x = let x' = 0 in x
> h y = let x' = 0 in y

Jan Stolarek's avatar
Jan Stolarek committed
536
which avoids name capture as desired.
537 538 539 540 541 542 543 544 545 546 547 548

In the general case, we say that a @Name@ can be captured if
the thing it refers to can be changed by adding new declarations.
-}

{- |
An abstract type representing names in the syntax tree.

'Name's can be constructed in several ways, which come with different
name-capture guarantees (see "Language.Haskell.TH.Syntax#namecapture" for
an explanation of name capture):

Jan Stolarek's avatar
Jan Stolarek committed
549 550
  * the built-in syntax @'f@ and @''T@ can be used to construct names,
    The expression @'f@ gives a @Name@ which refers to the value @f@
551 552
    currently in scope, and @''T@ gives a @Name@ which refers to the
    type @T@ currently in scope. These names can never be captured.
Jan Stolarek's avatar
Jan Stolarek committed
553 554

  * 'lookupValueName' and 'lookupTypeName' are similar to @'f@ and
555 556 557 558 559 560
     @''T@ respectively, but the @Name@s are looked up at the point
     where the current splice is being run. These names can never be
     captured.

  * 'newName' monadically generates a new name, which can never
     be captured.
Jan Stolarek's avatar
Jan Stolarek committed
561

562 563 564 565 566 567
  * 'mkName' generates a capturable name.

Names constructed using @newName@ and @mkName@ may be used in bindings
(such as @let x = ...@ or @\x -> ...@), but names constructed using
@lookupValueName@, @lookupTypeName@, @'f@, @''T@ may not.
-}
568
data Name = Name OccName NameFlavour deriving (Typeable, Data)
569 570

data NameFlavour
aavogt's avatar
aavogt committed
571 572 573 574 575 576
  = NameS           -- ^ An unqualified name; dynamically bound
  | NameQ ModName   -- ^ A qualified name; dynamically bound
  | NameU Int#      -- ^ A unique local name
  | NameL Int#      -- ^ Local name bound outside of the TH AST
  | NameG NameSpace PkgName ModName -- ^ Global name bound outside of the TH AST:
                -- An original name (occurrences only, not binders)
Jan Stolarek's avatar
Jan Stolarek committed
577
		-- Need the namespace too to be sure which
578
		-- thing we are naming
579 580
  deriving ( Typeable )

aavogt's avatar
aavogt committed
581
-- |
582 583 584 585 586 587 588
-- Although the NameFlavour type is abstract, the Data instance is not. The reason for this
-- is that currently we use Data to serialize values in annotations, and in order for that to
-- work for Template Haskell names introduced via the 'x syntax we need gunfold on NameFlavour
-- to work. Bleh!
--
-- The long term solution to this is to use the binary package for annotation serialization and
-- then remove this instance. However, to do _that_ we need to wait on binary to become stable, since
Gabor Greif's avatar
Gabor Greif committed
589
-- boot libraries cannot be upgraded separately from GHC itself.
590 591
--
-- This instance cannot be derived automatically due to bug #2701
592
instance Data NameFlavour where
593 594 595 596 597 598 599 600 601 602 603 604
     gfoldl _ z NameS          = z NameS
     gfoldl k z (NameQ mn)     = z NameQ `k` mn
     gfoldl k z (NameU i)      = z (\(I# i') -> NameU i') `k` (I# i)
     gfoldl k z (NameL i)      = z (\(I# i') -> NameL i') `k` (I# i)
     gfoldl k z (NameG ns p m) = z NameG `k` ns `k` p `k` m
     gunfold k z c = case constrIndex c of
         1 -> z NameS
         2 -> k $ z NameQ
         3 -> k $ z (\(I# i) -> NameU i)
         4 -> k $ z (\(I# i) -> NameL i)
         5 -> k $ k $ k $ z NameG
         _ -> error "gunfold: NameFlavour"
605 606 607 608 609 610 611
     toConstr NameS = con_NameS
     toConstr (NameQ _) = con_NameQ
     toConstr (NameU _) = con_NameU
     toConstr (NameL _) = con_NameL
     toConstr (NameG _ _ _) = con_NameG
     dataTypeOf _ = ty_NameFlavour

Ross Paterson's avatar
Ross Paterson committed
612 613 614 615 616 617
con_NameS, con_NameQ, con_NameU, con_NameL, con_NameG :: Data.Constr
con_NameS = mkConstr ty_NameFlavour "NameS" [] Data.Prefix
con_NameQ = mkConstr ty_NameFlavour "NameQ" [] Data.Prefix
con_NameU = mkConstr ty_NameFlavour "NameU" [] Data.Prefix
con_NameL = mkConstr ty_NameFlavour "NameL" [] Data.Prefix
con_NameG = mkConstr ty_NameFlavour "NameG" [] Data.Prefix
Ian Lynagh's avatar
Ian Lynagh committed
618

Ross Paterson's avatar
Ross Paterson committed
619
ty_NameFlavour :: Data.DataType
620 621 622
ty_NameFlavour = mkDataType "Language.Haskell.TH.Syntax.NameFlavour"
                            [con_NameS, con_NameQ, con_NameU,
                             con_NameL, con_NameG]
623

aavogt's avatar
aavogt committed
624
data NameSpace = VarName	-- ^ Variables
Jan Stolarek's avatar
Jan Stolarek committed
625
	       | DataName	-- ^ Data constructors
aavogt's avatar
aavogt committed
626
	       | TcClsName	-- ^ Type constructors and classes; Haskell has them
627
				-- in the same name space for now.
628
	       deriving( Eq, Ord, Data, Typeable )
629 630 631

type Uniq = Int

632
-- | The name without its module prefix
633 634 635
nameBase :: Name -> String
nameBase (Name occ _) = occString occ

636
-- | Module prefix of a name, if it exists
637
nameModule :: Name -> Maybe String
Ian Lynagh's avatar
Ian Lynagh committed
638
nameModule (Name _ (NameQ m))     = Just (modString m)
639
nameModule (Name _ (NameG _ _ m)) = Just (modString m)
Ian Lynagh's avatar
Ian Lynagh committed
640
nameModule _                      = Nothing
641

Jan Stolarek's avatar
Jan Stolarek committed
642
{- |
643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665
Generate a capturable name. Occurrences of such names will be
resolved according to the Haskell scoping rules at the occurrence
site.

For example:

> f = [| pi + $(varE (mkName "pi")) |]
> ...
> g = let pi = 3 in $f

In this case, @g@ is desugared to

> g = Prelude.pi + 3

Note that @mkName@ may be used with qualified names:

> mkName "Prelude.pi"

See also 'Language.Haskell.TH.Lib.dyn' for a useful combinator. The above example could
be rewritten using 'dyn' as

> f = [| pi + $(dyn "pi") |]
-}
666
mkName :: String -> Name
667
-- The string can have a '.', thus "Foo.baz",
668 669 670 671 672
-- giving a dynamically-bound qualified name,
-- in which case we want to generate a NameQ
--
-- Parse the string to see if it has a "." in it
-- so we know whether to generate a qualified or unqualified name
Jan Stolarek's avatar
Jan Stolarek committed
673
-- It's a bit tricky because we need to parse
aavogt's avatar
aavogt committed
674 675 676
--
-- > Foo.Baz.x   as    Qual Foo.Baz x
--
677 678 679 680 681
-- So we parse it from back to front
mkName str
  = split [] (reverse str)
  where
    split occ []        = Name (mkOccName occ) NameS
Jan Stolarek's avatar
Jan Stolarek committed
682
    split occ ('.':rev)	| not (null occ),
683 684 685 686 687 688 689 690
			  not (null rev), head rev /= '.'
			= Name (mkOccName occ) (NameQ (mkModName (reverse rev)))
	-- The 'not (null occ)' guard ensures that
	-- 	mkName "&." = Name "&." NameS
	-- The 'rev' guards ensure that
	--	mkName ".&" = Name ".&" NameS
	--	mkName "Data.Bits..&" = Name ".&" (NameQ "Data.Bits")
	-- This rather bizarre case actually happened; (.&.) is in Data.Bits
691
    split occ (c:rev)   = split (c:occ) rev
692

aavogt's avatar
aavogt committed
693 694
-- | Only used internally
mkNameU :: String -> Uniq -> Name
695 696
mkNameU s (I# u) = Name (mkOccName s) (NameU u)

aavogt's avatar
aavogt committed
697 698
-- | Only used internally
mkNameL :: String -> Uniq -> Name
699 700
mkNameL s (I# u) = Name (mkOccName s) (NameL u)

aavogt's avatar
aavogt committed
701 702 703
-- | Used for 'x etc, but not available to the programmer
mkNameG :: NameSpace -> String -> String -> String -> Name
mkNameG ns pkg modu occ
Ian Lynagh's avatar
Ian Lynagh committed
704
  = Name (mkOccName occ) (NameG ns (mkPkgName pkg) (mkModName modu))
705

706
mkNameG_v, mkNameG_tc, mkNameG_d :: String -> String -> String -> Name
707 708 709 710 711 712 713 714 715 716 717 718 719 720 721
mkNameG_v  = mkNameG VarName
mkNameG_tc = mkNameG TcClsName
mkNameG_d  = mkNameG DataName

instance Eq Name where
  v1 == v2 = cmpEq (v1 `compare` v2)

instance Ord Name where
  (Name o1 f1) `compare` (Name o2 f2) = (f1 `compare` f2)   `thenCmp`
				        (o1 `compare` o2)

instance Eq NameFlavour where
  f1 == f2 = cmpEq (f1 `compare` f2)

instance Ord NameFlavour where
722
	-- NameS < NameQ < NameU < NameL < NameG
723
  NameS `compare` NameS = EQ
Ian Lynagh's avatar
Ian Lynagh committed
724
  NameS `compare` _     = LT
725

726 727
  (NameQ _)  `compare` NameS      = GT
  (NameQ m1) `compare` (NameQ m2) = m1 `compare` m2
Ian Lynagh's avatar
Ian Lynagh committed
728
  (NameQ _)  `compare` _          = LT
729 730 731

  (NameU _)  `compare` NameS      = GT
  (NameU _)  `compare` (NameQ _)  = GT
732 733 734
  (NameU u1) `compare` (NameU u2) | isTrue# (u1  <# u2) = LT
				  | isTrue# (u1 ==# u2) = EQ
				  | otherwise           = GT
Ian Lynagh's avatar
Ian Lynagh committed
735
  (NameU _)  `compare` _     = LT
736

737 738 739
  (NameL _)  `compare` NameS      = GT
  (NameL _)  `compare` (NameQ _)  = GT
  (NameL _)  `compare` (NameU _)  = GT
740 741 742
  (NameL u1) `compare` (NameL u2) | isTrue# (u1  <# u2) = LT
				  | isTrue# (u1 ==# u2) = EQ
				  | otherwise           = GT
Ian Lynagh's avatar
Ian Lynagh committed
743
  (NameL _)  `compare` _          = LT
744

745 746
  (NameG ns1 p1 m1) `compare` (NameG ns2 p2 m2) = (ns1 `compare` ns2) `thenCmp`
                                            (p1 `compare` p2) `thenCmp`
747
					    (m1 `compare` m2)
Ian Lynagh's avatar
Ian Lynagh committed
748
  (NameG _ _ _)    `compare` _ = GT
749

Ian Lynagh's avatar
Ian Lynagh committed
750 751 752 753 754 755 756 757 758 759 760 761 762 763 764
data NameIs = Alone | Applied | Infix

showName :: Name -> String
showName = showName' Alone

showName' :: NameIs -> Name -> String
showName' ni nm
 = case ni of
       Alone        -> nms
       Applied
        | pnam      -> nms
        | otherwise -> "(" ++ nms ++ ")"
       Infix
        | pnam      -> "`" ++ nms ++ "`"
        | otherwise -> nms
765
    where
766 767 768 769 770
	-- For now, we make the NameQ and NameG print the same, even though
	-- NameQ is a qualified name (so what it means depends on what the
	-- current scope is), and NameG is an original name (so its meaning
	-- should be independent of what's in scope.
	-- We may well want to distinguish them in the end.
771 772
	-- Ditto NameU and NameL
        nms = case nm of
Ian Lynagh's avatar
Ian Lynagh committed
773 774 775 776 777
                    Name occ NameS         -> occString occ
                    Name occ (NameQ m)     -> modString m ++ "." ++ occString occ
                    Name occ (NameG _ _ m) -> modString m ++ "." ++ occString occ
                    Name occ (NameU u)     -> occString occ ++ "_" ++ show (I# u)
                    Name occ (NameL u)     -> occString occ ++ "_" ++ show (I# u)
778 779 780

        pnam = classify nms

Ian Lynagh's avatar
Ian Lynagh committed
781 782
        -- True if we are function style, e.g. f, [], (,)
        -- False if we are operator style, e.g. +, :+
783
        classify "" = False -- shouldn't happen; . operator is handled below
Ian Lynagh's avatar
Ian Lynagh committed
784
        classify (x:xs) | isAlpha x || (x `elem` "_[]()") =
785 786 787 788
                            case dropWhile (/='.') xs of
                                  (_:xs') -> classify xs'
                                  []      -> True
                        | otherwise = False
789

790
instance Show Name where
Ian Lynagh's avatar
Ian Lynagh committed
791
  show = showName
792

793
-- Tuple data and type constructors
794 795 796 797
-- | Tuple data constructor
tupleDataName :: Int -> Name
-- | Tuple type constructor
tupleTypeName :: Int -> Name
798

799
tupleDataName 0 = mk_tup_name 0 DataName
800
tupleDataName 1 = error "tupleDataName 1"
801
tupleDataName n = mk_tup_name (n-1) DataName
802

803
tupleTypeName 0 = mk_tup_name 0 TcClsName
804
tupleTypeName 1 = error "tupleTypeName 1"
805
tupleTypeName n = mk_tup_name (n-1) TcClsName
806

Ian Lynagh's avatar
Ian Lynagh committed
807
mk_tup_name :: Int -> NameSpace -> Name
808
mk_tup_name n_commas space
Ian Lynagh's avatar
Ian Lynagh committed
809
  = Name occ (NameG space (mkPkgName "ghc-prim") tup_mod)
810 811
  where
    occ = mkOccName ('(' : replicate n_commas ',' ++ ")")
Ian Lynagh's avatar
Ian Lynagh committed
812
    tup_mod = mkModName "GHC.Tuple"
813

814
-- Unboxed tuple data and type constructors
815 816 817 818
-- | Unboxed tuple data constructor
unboxedTupleDataName :: Int -> Name
-- | Unboxed tuple type constructor
unboxedTupleTypeName :: Int -> Name
819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834

unboxedTupleDataName 0 = error "unboxedTupleDataName 0"
unboxedTupleDataName 1 = error "unboxedTupleDataName 1"
unboxedTupleDataName n = mk_unboxed_tup_name (n-1) DataName

unboxedTupleTypeName 0 = error "unboxedTupleTypeName 0"
unboxedTupleTypeName 1 = error "unboxedTupleTypeName 1"
unboxedTupleTypeName n = mk_unboxed_tup_name (n-1) TcClsName

mk_unboxed_tup_name :: Int -> NameSpace -> Name
mk_unboxed_tup_name n_commas space
  = Name occ (NameG space (mkPkgName "ghc-prim") tup_mod)
  where
    occ = mkOccName ("(#" ++ replicate n_commas ',' ++ "#)")
    tup_mod = mkModName "GHC.Tuple"

835

836

837 838 839 840 841 842 843 844 845 846 847
-----------------------------------------------------
--		Locations
-----------------------------------------------------

data Loc
  = Loc { loc_filename :: String
	, loc_package  :: String
	, loc_module   :: String
	, loc_start    :: CharPos
	, loc_end      :: CharPos }

848
type CharPos = (Int, Int)	-- ^ Line and character position
849

850

851 852 853 854 855 856
-----------------------------------------------------
--
--	The Info returned by reification
--
-----------------------------------------------------

aavogt's avatar
aavogt committed
857 858
-- | Obtained from 'reify' in the 'Q' Monad.
data Info
Jan Stolarek's avatar
Jan Stolarek committed
859
  =
860
  -- | A class, with a list of its visible instances
Jan Stolarek's avatar
Jan Stolarek committed
861
  ClassI
862 863
      Dec
      [InstanceDec]
Jan Stolarek's avatar
Jan Stolarek committed
864

865
  -- | A class method
866
  | ClassOpI
867 868 869 870
       Name
       Type
       ParentName
       Fixity
Jan Stolarek's avatar
Jan Stolarek committed
871

872
  -- | A \"plain\" type constructor. \"Fancier\" type constructors are returned using 'PrimTyConI' or 'FamilyI' as appropriate
Jan Stolarek's avatar
Jan Stolarek committed
873
  | TyConI
874 875
        Dec

876 877
  -- | A type or data family, with a list of its visible instances. A closed
  -- type family is returned with 0 instances.
Jan Stolarek's avatar
Jan Stolarek committed
878
  | FamilyI
879 880
        Dec
        [InstanceDec]
Jan Stolarek's avatar
Jan Stolarek committed
881

882
  -- | A \"primitive\" type constructor, which can't be expressed with a 'Dec'. Examples: @(->)@, @Int#@.
Jan Stolarek's avatar
Jan Stolarek committed
883
  | PrimTyConI
884 885 886
       Name
       Arity
       Unlifted
Jan Stolarek's avatar
Jan Stolarek committed
887

888
  -- | A data constructor
Jan Stolarek's avatar
Jan Stolarek committed
889
  | DataConI
890 891 892 893
       Name
       Type
       ParentName
       Fixity
894

Jan Stolarek's avatar
Jan Stolarek committed
895
  {- |
896
  A \"value\" variable (as opposed to a type variable, see 'TyVarI').
Jan Stolarek's avatar
Jan Stolarek committed
897 898 899

  The @Maybe Dec@ field contains @Just@ the declaration which
  defined the variable -- including the RHS of the declaration --
900 901 902 903 904
  or else @Nothing@, in the case where the RHS is unavailable to
  the compiler. At present, this value is _always_ @Nothing@:
  returning the RHS has not yet been implemented because of
  lack of interest.
  -}
Jan Stolarek's avatar
Jan Stolarek committed
905
  | VarI
906 907 908 909
       Name
       Type
       (Maybe Dec)
       Fixity
910

Jan Stolarek's avatar
Jan Stolarek committed
911
  {- |
912
  A type variable.
Jan Stolarek's avatar
Jan Stolarek committed
913

914 915 916 917
  The @Type@ field contains the type which underlies the variable.
  At present, this is always @'VarT' theName@, but future changes
  may permit refinement of this.
  -}
918 919 920
  | TyVarI 	-- Scoped type variable
	Name
	Type	-- What it is bound to
921
  deriving( Show, Data, Typeable )
922

Jan Stolarek's avatar
Jan Stolarek committed
923
{- |
924 925 926 927 928 929 930 931 932 933 934
In 'ClassOpI' and 'DataConI', name of the parent class or type
-}
type ParentName = Name

-- | In 'PrimTyConI', arity of the type constructor
type Arity = Int

-- | In 'PrimTyConI', is the type constructor unlifted?
type Unlifted = Bool

-- | 'InstanceDec' desribes a single instance of a class or type function.
935
-- It is just a 'Dec', but guaranteed to be one of the following:
936 937 938 939 940 941
--
--   * 'InstanceD' (with empty @['Dec']@)
--
--   * 'DataInstD' or 'NewtypeInstD' (with empty derived @['Name']@)
--
--   * 'TySynInstD'
942
type InstanceDec = Dec
943

944 945 946 947
data Fixity          = Fixity Int FixityDirection
    deriving( Eq, Show, Data, Typeable )
data FixityDirection = InfixL | InfixR | InfixN
    deriving( Eq, Show, Data, Typeable )
948

949
-- | Highest allowed operator precedence for 'Fixity' constructor (answer: 9)
950
maxPrecedence :: Int
951
maxPrecedence = (9::Int)
952

953
-- | Default fixity: @infixl 9@
954
defaultFixity :: Fixity
955 956 957
defaultFixity = Fixity maxPrecedence InfixL


958
{-
959 960
Note [Unresolved infix]
~~~~~~~~~~~~~~~~~~~~~~~
961 962
-}
{- $infix #infix#
963 964 965
When implementing antiquotation for quasiquoters, one often wants
to parse strings into expressions:

966
> parse :: String -> Maybe Exp
967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020

But how should we parse @a + b * c@? If we don't know the fixities of
@+@ and @*@, we don't know whether to parse it as @a + (b * c)@ or @(a
+ b) * c@.

In cases like this, use 'UInfixE' or 'UInfixP', which stand for
\"unresolved infix expression\" and \"unresolved infix pattern\". When
the compiler is given a splice containing a tree of @UInfixE@
applications such as

> UInfixE
>   (UInfixE e1 op1 e2)
>   op2
>   (UInfixE e3 op3 e4)

it will look up and the fixities of the relevant operators and
reassociate the tree as necessary.

  * trees will not be reassociated across 'ParensE' or 'ParensP',
    which are of use for parsing expressions like

    > (a + b * c) + d * e

  * 'InfixE' and 'InfixP' expressions are never reassociated.

  * The 'UInfixE' constructor doesn't support sections. Sections
    such as @(a *)@ have no ambiguity, so 'InfixE' suffices. For longer
    sections such as @(a + b * c -)@, use an 'InfixE' constructor for the
    outer-most section, and use 'UInfixE' constructors for all
    other operators:

    > InfixE
    >   Just (UInfixE ...a + b * c...)
    >   op
    >   Nothing

    Sections such as @(a + b +)@ and @((a + b) +)@ should be rendered
    into 'Exp's differently:

    > (+ a + b)   ---> InfixE Nothing + (Just $ UInfixE a + b)
    >                    -- will result in a fixity error if (+) is left-infix
    > (+ (a + b)) ---> InfixE Nothing + (Just $ ParensE $ UInfixE a + b)
    >                    -- no fixity errors

  * Quoted expressions such as

    > [| a * b + c |] :: Q Exp
    > [p| a : b : c |] :: Q Pat

    will never contain 'UInfixE', 'UInfixP', 'ParensE', or 'ParensP'
    constructors.

-}

1021 1022 1023 1024 1025 1026
-----------------------------------------------------
--
--	The main syntax data types
--
-----------------------------------------------------

Jan Stolarek's avatar
Jan Stolarek committed
1027 1028
data Lit = CharL Char
         | StringL String
aavogt's avatar
aavogt committed
1029
         | IntegerL Integer     -- ^ Used for overloaded and non-overloaded
1030 1031 1032 1033 1034
                                -- literals. We don't have a good way to
                                -- represent non-overloaded literals at
                                -- the moment. Maybe that doesn't matter?
         | RationalL Rational   -- Ditto
         | IntPrimL Integer
1035
         | WordPrimL Integer
1036 1037
         | FloatPrimL Rational
         | DoublePrimL Rational
reinerp's avatar
reinerp committed
1038
         | StringPrimL [Word8]	-- ^ A primitive C-style string, type Addr#
1039
    deriving( Show, Eq, Data, Typeable )
1040

Jan Stolarek's avatar
Jan Stolarek committed
1041
    -- We could add Int, Float, Double etc, as we do in HsLit,
1042 1043 1044
    -- but that could complicate the
    -- suppposedly-simple TH.Syntax literal type

aavogt's avatar
aavogt committed
1045
-- | Pattern in Haskell given in @{}@
Jan Stolarek's avatar
Jan Stolarek committed
1046
data Pat
aavogt's avatar
aavogt committed
1047 1048 1049
  = LitP Lit                      -- ^ @{ 5 or 'c' }@
  | VarP Name                     -- ^ @{ x }@
  | TupP [Pat]                    -- ^ @{ (p1,p2) }@
1050
  | UnboxedTupP [Pat]             -- ^ @{ (# p1,p2 #) }@
aavogt's avatar
aavogt committed
1051 1052
  | ConP Name [Pat]               -- ^ @data T1 = C1 t1 t2; {C1 p1 p1} = e@
  | InfixP Pat Name Pat           -- ^ @foo ({x :+ y}) = e@
1053 1054
  | UInfixP Pat Name Pat          -- ^ @foo ({x :+ y}) = e@
                                  --
1055
                                  -- See "Language.Haskell.TH.Syntax#infix"
1056 1057
  | ParensP Pat                   -- ^ @{(p)}@
                                  --
1058
                                  -- See "Language.Haskell.TH.Syntax#infix"
aavogt's avatar
aavogt committed
1059 1060 1061 1062 1063 1064 1065
  | TildeP Pat                    -- ^ @{ ~p }@
  | BangP Pat                     -- ^ @{ !p }@
  | AsP Name Pat                  -- ^ @{ x \@ p }@
  | WildP                         -- ^ @{ _ }@
  | RecP Name [FieldPat]          -- ^ @f (Pt { pointx = x }) = g x@
  | ListP [ Pat ]                 -- ^ @{ [1,2,3] }@
  | SigP Pat Type                 -- ^ @{ p :: t }@
reinerp's avatar
reinerp committed
1066
  | ViewP Exp Pat                 -- ^ @{ e -> p }@