Lexer.x 96.1 KB
Newer Older
1
-----------------------------------------------------------------------------
2
-- (c) The University of Glasgow, 2006
3
--
4
-- GHC's lexer for Haskell 2010 [1].
5
--
6 7
-- This is a combination of an Alex-generated lexer [2] from a regex
-- definition, with some hand-coded bits. [3]
8 9
--
-- Completely accurate information about token-spans within the source
Ian Lynagh's avatar
Ian Lynagh committed
10 11
-- file is maintained.  Every token has a start and end RealSrcLoc
-- attached to it.
12
--
13 14 15 16 17
-- References:
-- [1] https://www.haskell.org/onlinereport/haskell2010/haskellch2.html
-- [2] http://www.haskell.org/alex/
-- [3] https://ghc.haskell.org/trac/ghc/wiki/Commentary/Compiler/Parser
--
18 19 20 21 22 23 24 25 26 27
-----------------------------------------------------------------------------

--   ToDo / known bugs:
--    - parsing integers is a bit slow
--    - readRational is a bit slow
--
--   Known bugs, that were also in the previous version:
--    - M... should be 3 tokens, not 1.
--    - pragma-end should be only valid in a pragma

28
--   qualified operator NOTES.
Ian Lynagh's avatar
Ian Lynagh committed
29
--
30 31 32 33 34 35 36 37 38
--   - If M.(+) is a single lexeme, then..
--     - Probably (+) should be a single lexeme too, for consistency.
--       Otherwise ( + ) would be a prefix operator, but M.( + ) would not be.
--     - But we have to rule out reserved operators, otherwise (..) becomes
--       a different lexeme.
--     - Should we therefore also rule out reserved operators in the qualified
--       form?  This is quite difficult to achieve.  We don't do it for
--       qualified varids.

39 40 41 42

-- -----------------------------------------------------------------------------
-- Alex "Haskell code fragment top"

43
{
44
-- XXX The above flags turn off warnings in the generated code:
45
{-# LANGUAGE BangPatterns #-}
46 47 48 49 50 51 52 53
{-# OPTIONS_GHC -fno-warn-unused-matches #-}
{-# OPTIONS_GHC -fno-warn-unused-binds #-}
{-# OPTIONS_GHC -fno-warn-unused-imports #-}
{-# OPTIONS_GHC -fno-warn-missing-signatures #-}
-- But alex still generates some code that causes the "lazy unlifted bindings"
-- warning, and old compilers don't know about it so we can't easily turn
-- it off, so for now we use the sledge hammer:
{-# OPTIONS_GHC -w #-}
54

55 56
{-# OPTIONS_GHC -funbox-strict-fields #-}

57
module Lexer (
58
   Token(..), lexer, pragState, mkPState, PState(..),
Ian Lynagh's avatar
Ian Lynagh committed
59
   P(..), ParseResult(..), getSrcLoc,
60
   getPState, getDynFlags, withThisPackage,
61
   failLocMsgP, failSpanMsgP, srcParseFail,
Ian Lynagh's avatar
Ian Lynagh committed
62
   getMessages,
63
   popContext, pushCurrentContext, setLastToken, setSrcLoc,
vivian's avatar
vivian committed
64
   activeContext, nextIsEOF,
simonpj@microsoft.com's avatar
simonpj@microsoft.com committed
65
   getLexState, popLexState, pushLexState,
66
   extension, bangPatEnabled, datatypeContextsEnabled,
67
   traditionalRecordSyntaxEnabled,
68 69
   explicitForallEnabled,
   inRulePrag,
cactus's avatar
cactus committed
70 71 72
   explicitNamespacesEnabled,
   patternSynonymsEnabled,
   sccProfilingOn, hpcEnabled,
Jedai's avatar
Jedai committed
73 74
   addWarning,
   lexTokenStream
75 76
  ) where

rodlogic's avatar
rodlogic committed
77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94
-- base
import Control.Applicative
import Control.Monad
import Data.Bits
import Data.Char
import Data.List
import Data.Maybe
import Data.Ratio
import Data.Word

-- bytestring
import Data.ByteString (ByteString)

-- containers
import Data.Map (Map)
import qualified Data.Map as Map

-- compiler/utils
95
import Bag
96 97 98 99
import Outputable
import StringBuffer
import FastString
import UniqFM
rodlogic's avatar
rodlogic committed
100 101 102 103
import Util             ( readRational )

-- compiler/main
import ErrUtils
104
import DynFlags
rodlogic's avatar
rodlogic committed
105 106 107

-- compiler/basicTypes
import SrcLoc
108
import Module
Ian Lynagh's avatar
Ian Lynagh committed
109
import BasicTypes       ( InlineSpec(..), RuleMatchInfo(..), FractionalLit(..) )
110

rodlogic's avatar
rodlogic committed
111 112
-- compiler/parser
import Ctype
113 114
}

115 116 117
-- -----------------------------------------------------------------------------
-- Alex "Character set macros"

118 119
-- NB: The logic behind these definitions is also reflected in basicTypes/Lexeme.hs
-- Any changes here should likely be reflected there.
120 121 122 123
$unispace    = \x05 -- Trick Alex into handling Unicode. See alexGetByte.
$nl          = [\n\r\f]
$whitechar   = [$nl\v\ $unispace]
$white_no_nl = $whitechar # \n -- TODO #8424
124
$tab         = \t
125 126

$ascdigit  = 0-9
127
$unidigit  = \x03 -- Trick Alex into handling Unicode. See alexGetByte.
128
$decdigit  = $ascdigit -- for now, should really be $digit (ToDo)
129 130 131
$digit     = [$ascdigit $unidigit]

$special   = [\(\)\,\;\[\]\`\{\}]
132 133 134
$ascsymbol = [\!\#\$\%\&\*\+\.\/\<\=\>\?\@\\\^\|\-\~\:]
$unisymbol = \x04 -- Trick Alex into handling Unicode. See alexGetByte.
$symbol    = [$ascsymbol $unisymbol] # [$special \_\"\']
135

136
$unilarge  = \x01 -- Trick Alex into handling Unicode. See alexGetByte.
137
$asclarge  = [A-Z]
138 139
$large     = [$asclarge $unilarge]

140
$unismall  = \x02 -- Trick Alex into handling Unicode. See alexGetByte.
141
$ascsmall  = [a-z]
142 143
$small     = [$ascsmall $unismall \_]

144 145
$unigraphic = \x06 -- Trick Alex into handling Unicode. See alexGetByte.
$graphic   = [$small $large $symbol $digit $special $unigraphic \"\']
146

147
$binit     = 0-1
Ian Lynagh's avatar
Ian Lynagh committed
148
$octit     = 0-7
149
$hexit     = [$decdigit A-F a-f]
150 151
$idchar    = [$small $large $digit \']

152 153
$pragmachar = [$small $large $digit]

154 155
$docsym    = [\| \^ \* \$]

156

157 158 159 160 161 162 163 164
-- -----------------------------------------------------------------------------
-- Alex "Regular expression macros"

@varid     = $small $idchar*          -- variable identifiers
@conid     = $large $idchar*          -- constructor identifiers

@varsym    = ($symbol # \:) $symbol*  -- variable (operator) symbol
@consym    = \: $symbol*              -- constructor (operator) symbol
165

166
@decimal     = $decdigit+
167
@binary      = $binit+
168 169 170 171 172
@octal       = $octit+
@hexadecimal = $hexit+
@exponent    = [eE] [\-\+]? @decimal

@qual = (@conid \.)+
173 174 175 176
@qvarid = @qual @varid
@qconid = @qual @conid
@qvarsym = @qual @varsym
@qconsym = @qual @consym
177 178 179

@floating_point = @decimal \. @decimal @exponent? | @decimal @exponent

180 181 182 183 184
-- normal signed numerical literals can only be explicitly negative,
-- not explicitly positive (contrast @exponent)
@negative = \-
@signed = @negative ?

185 186 187 188

-- -----------------------------------------------------------------------------
-- Alex "Identifier"

189 190
haskell :-

191 192 193 194 195

-- -----------------------------------------------------------------------------
-- Alex "Rules"

-- everywhere: skip whitespace
Ian Lynagh's avatar
Ian Lynagh committed
196
$white_no_nl+ ;
197
$tab+         { warn Opt_WarnTabs (text "Tab character") }
198 199 200 201 202

-- Everywhere: deal with nested comments.  We explicitly rule out
-- pragmas, "{-#", so that we don't accidentally treat them as comments.
-- (this can happen even though pragmas will normally take precedence due to
-- longest-match, because pragmas aren't valid in every state, but comments
203 204 205 206
-- are). We also rule out nested Haddock comments, if the -haddock flag is
-- set.

"{-" / { isNormalComment } { nested_comment lexToken }
207 208 209 210

-- Single-line comments are a bit tricky.  Haskell 98 says that two or
-- more dashes followed by a symbol should be parsed as a varsym, so we
-- have to exclude those.
211 212

-- Since Haddock comments aren't valid in every state, we need to rule them
Ian Lynagh's avatar
Ian Lynagh committed
213
-- out here.
214 215 216 217 218 219 220

-- The following two rules match comments that begin with two dashes, but
-- continue with a different character. The rules test that this character
-- is not a symbol (in which case we'd have a varsym), and that it's not a
-- space followed by a Haddock comment symbol (docsym) (in which case we'd
-- have a Haddock comment). The rules then munch the rest of the line.

Jedai's avatar
Jedai committed
221
"-- " ~[$docsym \#] .* { lineCommentToken }
222
"--" [^$symbol \ ] .* { lineCommentToken }
223 224 225

-- Next, match Haddock comments if no -haddock flag

Jedai's avatar
Jedai committed
226
"-- " [$docsym \#] .* / { ifExtension (not . haddockEnabled) } { lineCommentToken }
227 228 229 230 231 232 233

-- Now, when we've matched comments that begin with 2 dashes and continue
-- with a different character, we need to match comments that begin with three
-- or more dashes (which clearly can't be Haddock comments). We only need to
-- make sure that the first non-dash character isn't a symbol, and munch the
-- rest of the line.

234
"---"\-* ~$symbol .* { lineCommentToken }
235 236 237 238

-- Since the previous rules all match dashes followed by at least one
-- character, we also need to match a whole line filled with just dashes.

Jedai's avatar
Jedai committed
239
"--"\-* / { atEOL } { lineCommentToken }
240 241 242 243

-- We need this rule since none of the other single line comment rules
-- actually match this case.

Jedai's avatar
Jedai committed
244
"-- " / { atEOL } { lineCommentToken }
245 246 247 248 249 250 251 252 253 254 255

-- 'bol' state: beginning of a line.  Slurp up all the whitespace (including
-- blank lines) until we find a non-whitespace character, then do layout
-- processing.
--
-- One slight wibble here: what if the line begins with {-#? In
-- theory, we have to lex the pragma to see if it's one we recognise,
-- and if it is, then we backtrack and do_bol, otherwise we treat it
-- as a nested comment.  We don't bother with this: if the line begins
-- with {-#, then we'll assume it's a pragma we know about and go for do_bol.
<bol> {
Ian Lynagh's avatar
Ian Lynagh committed
256 257 258 259 260
  \n                                    ;
  ^\# (line)?                           { begin line_prag1 }
  ^\# pragma .* \n                      ; -- GCC 3.3 CPP generated, apparently
  ^\# \! .* \n                          ; -- #!, for scripts
  ()                                    { do_bol }
261 262 263 264 265
}

-- after a layout keyword (let, where, do, of), we begin a new layout
-- context if the curly brace is missing.
-- Careful! This stuff is quite delicate.
266
<layout, layout_do, layout_if> {
Ian Lynagh's avatar
Ian Lynagh committed
267 268 269 270
  \{ / { notFollowedBy '-' }            { hopefully_open_brace }
        -- we might encounter {-# here, but {- has been handled already
  \n                                    ;
  ^\# (line)?                           { begin line_prag1 }
271 272
}

273 274 275 276 277 278
-- after an 'if', a vertical bar starts a layout context for MultiWayIf
<layout_if> {
  \| / { notFollowedBySymbol }          { new_layout_context True ITvbar }
  ()                                    { pop }
}

279
-- do is treated in a subtly different way, see new_layout_context
280 281
<layout>    ()                          { new_layout_context True  ITvocurly }
<layout_do> ()                          { new_layout_context False ITvocurly }
282 283 284 285

-- after a new layout context which was found to be to the left of the
-- previous context, we have generated a '{' token, and we now need to
-- generate a matching '}' token.
Ian Lynagh's avatar
Ian Lynagh committed
286
<layout_left>  ()                       { do_layout_left }
287

Ian Lynagh's avatar
Ian Lynagh committed
288
<0,option_prags> \n                     { begin bol }
289

290 291
"{-#" $whitechar* $pragmachar+ / { known_pragma linePrags }
                                { dispatch_pragmas linePrags }
292 293 294

-- single-line line pragmas, of the form
--    # <line> "<file>" <extra-stuff> \n
295
<line_prag1> @decimal                   { setLine line_prag1a }
Ian Lynagh's avatar
Ian Lynagh committed
296 297
<line_prag1a> \" [$graphic \ ]* \"      { setFile line_prag1b }
<line_prag1b> .*                        { pop }
298 299 300

-- Haskell-style line pragmas, of the form
--    {-# LINE <line> "<file>" #-}
301
<line_prag2> @decimal                   { setLine line_prag2a }
Ian Lynagh's avatar
Ian Lynagh committed
302 303
<line_prag2a> \" [$graphic \ ]* \"      { setFile line_prag2b }
<line_prag2b> "#-}"|"-}"                { pop }
304 305
   -- NOTE: accept -} at the end of a LINE pragma, for compatibility
   -- with older versions of GHC which generated these.
306

307
<0,option_prags> {
Ian Lynagh's avatar
Ian Lynagh committed
308
  "{-#" $whitechar* $pragmachar+
309 310 311 312 313
        $whitechar+ $pragmachar+ / { known_pragma twoWordPrags }
                                 { dispatch_pragmas twoWordPrags }

  "{-#" $whitechar* $pragmachar+ / { known_pragma oneWordPrags }
                                 { dispatch_pragmas oneWordPrags }
314

315
  -- We ignore all these pragmas, but don't generate a warning for them
316 317
  "{-#" $whitechar* $pragmachar+ / { known_pragma ignoredPrags }
                                 { dispatch_pragmas ignoredPrags }
318 319

  -- ToDo: should only be valid inside a pragma:
Ian Lynagh's avatar
Ian Lynagh committed
320
  "#-}"                          { endPrag }
321 322
}

323
<option_prags> {
324 325 326
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
                                   { dispatch_pragmas fileHeaderPrags }

Ian Lynagh's avatar
Ian Lynagh committed
327
  "-- #"                           { multiline_doc_comment }
David Waern's avatar
David Waern committed
328 329
}

330 331
<0> {
  -- In the "0" mode we ignore these pragmas
332
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
333 334 335
                     { nested_comment lexToken }
}

David Waern's avatar
David Waern committed
336
<0> {
Jedai's avatar
Jedai committed
337
  "-- #" .* { lineCommentToken }
338
}
339

340
<0,option_prags> {
341 342
  "{-#"  { warnThen Opt_WarnUnrecognisedPragmas (text "Unrecognised pragma")
                    (nested_comment lexToken) }
343 344
}

345 346
-- '0' state: ordinary lexemes

347 348
-- Haddock comments

349
<0,option_prags> {
David Waern's avatar
David Waern committed
350 351
  "-- " $docsym      / { ifExtension haddockEnabled } { multiline_doc_comment }
  "{-" \ ? $docsym   / { ifExtension haddockEnabled } { nested_doc_comment }
352 353
}

354 355
-- "special" symbols

356
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
357 358
  "[:" / { ifExtension parrEnabled }    { token ITopabrack }
  ":]" / { ifExtension parrEnabled }    { token ITcpabrack }
359
}
Ian Lynagh's avatar
Ian Lynagh committed
360

361
<0> {
362 363 364
  "[|"        / { ifExtension thEnabled } { token ITopenExpQuote }
  "[||"       / { ifExtension thEnabled } { token ITopenTExpQuote }
  "[e|"       / { ifExtension thEnabled } { token ITopenExpQuote }
365
  "[e||"      / { ifExtension thEnabled } { token ITopenTExpQuote }
366 367 368 369 370 371 372 373 374
  "[p|"       / { ifExtension thEnabled } { token ITopenPatQuote }
  "[d|"       / { ifExtension thEnabled } { layout_token ITopenDecQuote }
  "[t|"       / { ifExtension thEnabled } { token ITopenTypQuote }
  "|]"        / { ifExtension thEnabled } { token ITcloseQuote }
  "||]"       / { ifExtension thEnabled } { token ITcloseTExpQuote }
  \$ @varid   / { ifExtension thEnabled } { skip_one_varid ITidEscape }
  "$$" @varid / { ifExtension thEnabled } { skip_two_varid ITidTyEscape }
  "$("        / { ifExtension thEnabled } { token ITparenEscape }
  "$$("       / { ifExtension thEnabled } { token ITparenTyEscape }
375

376 377 378 379
-- For backward compatibility, accept the old dollar syntax
  "[$" @varid "|"  / { ifExtension qqEnabled }
                     { lex_quasiquote_tok }

380
  "[" @varid "|"  / { ifExtension qqEnabled }
381
                     { lex_quasiquote_tok }
382 383

  -- qualified quasi-quote (#5555)
384 385
  "[" @qvarid "|"  / { ifExtension qqEnabled }
                     { lex_qquasiquote_tok }
386 387
}

388
<0> {
ross's avatar
ross committed
389
  "(|" / { ifExtension arrowsEnabled `alexAndPred` notFollowedBySymbol }
Ian Lynagh's avatar
Ian Lynagh committed
390
                                        { special IToparenbar }
391 392 393
  "|)" / { ifExtension arrowsEnabled }  { special ITcparenbar }
}

394
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
395
  \? @varid / { ifExtension ipEnabled } { skip_one_varid ITdupipvarid }
396 397
}

398
<0> {
399
  "(#" / { ifExtension unboxedTuplesEnabled }
Ian Lynagh's avatar
Ian Lynagh committed
400 401 402 403 404
         { token IToubxparen }
  "#)" / { ifExtension unboxedTuplesEnabled }
         { token ITcubxparen }
}

405
<0,option_prags> {
Ian Lynagh's avatar
Ian Lynagh committed
406 407 408 409 410 411 412 413 414 415
  \(                                    { special IToparen }
  \)                                    { special ITcparen }
  \[                                    { special ITobrack }
  \]                                    { special ITcbrack }
  \,                                    { special ITcomma }
  \;                                    { special ITsemi }
  \`                                    { special ITbackquote }

  \{                                    { open_brace }
  \}                                    { close_brace }
416 417
}

418
<0,option_prags> {
419 420
  @qvarid                       { idtoken qvarid }
  @qconid                       { idtoken qconid }
Ian Lynagh's avatar
Ian Lynagh committed
421
  @varid                        { varid }
422
  @conid                        { idtoken conid }
423 424
}

425
<0> {
426 427
  @qvarid "#"+      / { ifExtension magicHashEnabled } { idtoken qvarid }
  @qconid "#"+      / { ifExtension magicHashEnabled } { idtoken qconid }
428
  @varid "#"+       / { ifExtension magicHashEnabled } { varid }
429
  @conid "#"+       / { ifExtension magicHashEnabled } { idtoken conid }
430 431
}

432 433
-- ToDo: - move `var` and (sym) into lexical syntax?
--       - remove backquote from $special?
434
<0> {
435 436
  @qvarsym                                         { idtoken qvarsym }
  @qconsym                                         { idtoken qconsym }
437 438
  @varsym                                          { varsym }
  @consym                                          { consym }
439 440
}

441 442
-- For the normal boxed literals we need to be careful
-- when trying to be close to Haskell98
443
<0> {
444
  -- Normal integral literals (:: Num a => a, from Integer)
445
  @decimal                                                               { tok_num positive 0 0 decimal }
446
  0[bB] @binary                / { ifExtension binaryLiteralsEnabled }   { tok_num positive 2 2 binary }
447 448 449
  0[oO] @octal                                                           { tok_num positive 2 2 octal }
  0[xX] @hexadecimal                                                     { tok_num positive 2 2 hexadecimal }
  @negative @decimal           / { ifExtension negativeLiteralsEnabled } { tok_num negative 1 1 decimal }
450 451
  @negative 0[bB] @binary      / { ifExtension negativeLiteralsEnabled `alexAndPred`
                                   ifExtension binaryLiteralsEnabled }   { tok_num negative 3 3 binary }
452 453
  @negative 0[oO] @octal       / { ifExtension negativeLiteralsEnabled } { tok_num negative 3 3 octal }
  @negative 0[xX] @hexadecimal / { ifExtension negativeLiteralsEnabled } { tok_num negative 3 3 hexadecimal }
454 455

  -- Normal rational literals (:: Fractional a => a, from Rational)
456 457
  @floating_point                                                        { strtoken tok_float }
  @negative @floating_point    / { ifExtension negativeLiteralsEnabled } { strtoken tok_float }
458 459
}

460
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
461
  -- Unboxed ints (:: Int#) and words (:: Word#)
462 463
  -- It's simpler (and faster?) to give separate cases to the negatives,
  -- especially considering octal/hexadecimal prefixes.
Ian Lynagh's avatar
Ian Lynagh committed
464
  @decimal                     \# / { ifExtension magicHashEnabled } { tok_primint positive 0 1 decimal }
465 466
  0[bB] @binary                \# / { ifExtension magicHashEnabled `alexAndPred`
                                      ifExtension binaryLiteralsEnabled } { tok_primint positive 2 3 binary }
Ian Lynagh's avatar
Ian Lynagh committed
467 468 469
  0[oO] @octal                 \# / { ifExtension magicHashEnabled } { tok_primint positive 2 3 octal }
  0[xX] @hexadecimal           \# / { ifExtension magicHashEnabled } { tok_primint positive 2 3 hexadecimal }
  @negative @decimal           \# / { ifExtension magicHashEnabled } { tok_primint negative 1 2 decimal }
470 471
  @negative 0[bB] @binary      \# / { ifExtension magicHashEnabled `alexAndPred`
                                      ifExtension binaryLiteralsEnabled } { tok_primint negative 3 4 binary }
Ian Lynagh's avatar
Ian Lynagh committed
472
  @negative 0[oO] @octal       \# / { ifExtension magicHashEnabled } { tok_primint negative 3 4 octal }
473
  @negative 0[xX] @hexadecimal \# / { ifExtension magicHashEnabled } { tok_primint negative 3 4 hexadecimal }
474

Ian Lynagh's avatar
Ian Lynagh committed
475
  @decimal                     \# \# / { ifExtension magicHashEnabled } { tok_primword 0 2 decimal }
476 477
  0[bB] @binary                \# \# / { ifExtension magicHashEnabled `alexAndPred`
                                         ifExtension binaryLiteralsEnabled } { tok_primword 2 4 binary }
Ian Lynagh's avatar
Ian Lynagh committed
478 479 480
  0[oO] @octal                 \# \# / { ifExtension magicHashEnabled } { tok_primword 2 4 octal }
  0[xX] @hexadecimal           \# \# / { ifExtension magicHashEnabled } { tok_primword 2 4 hexadecimal }

481 482
  -- Unboxed floats and doubles (:: Float#, :: Double#)
  -- prim_{float,double} work with signed literals
483 484
  @signed @floating_point \# / { ifExtension magicHashEnabled } { init_strtoken 1 tok_primfloat }
  @signed @floating_point \# \# / { ifExtension magicHashEnabled } { init_strtoken 2 tok_primdouble }
485 486 487 488 489 490
}

-- Strings and chars are lexed by hand-written code.  The reason is
-- that even if we recognise the string or char here in the regex
-- lexer, we would still have to parse the string afterward in order
-- to convert it to a String.
491
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
492 493
  \'                            { lex_char_tok }
  \"                            { lex_string_tok }
494 495
}

496 497 498 499

-- -----------------------------------------------------------------------------
-- Alex "Haskell code fragment bottom"

500 501 502 503
{
-- -----------------------------------------------------------------------------
-- The token type

504
data Token
Ian Lynagh's avatar
Ian Lynagh committed
505
  = ITas                        -- Haskell keywords
506 507 508 509 510 511 512 513
  | ITcase
  | ITclass
  | ITdata
  | ITdefault
  | ITderiving
  | ITdo
  | ITelse
  | IThiding
514
  | ITforeign
515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530
  | ITif
  | ITimport
  | ITin
  | ITinfix
  | ITinfixl
  | ITinfixr
  | ITinstance
  | ITlet
  | ITmodule
  | ITnewtype
  | ITof
  | ITqualified
  | ITthen
  | ITtype
  | ITwhere

Ian Lynagh's avatar
Ian Lynagh committed
531
  | ITforall                    -- GHC extension keywords
532 533 534 535
  | ITexport
  | ITlabel
  | ITdynamic
  | ITsafe
536
  | ITinterruptible
537 538 539
  | ITunsafe
  | ITstdcallconv
  | ITccallconv
540
  | ITcapiconv
541
  | ITprimcallconv
thoughtpolice's avatar
thoughtpolice committed
542
  | ITjavascriptcallconv
543
  | ITmdo
544
  | ITfamily
545
  | ITrole
546 547 548
  | ITgroup
  | ITby
  | ITusing
cactus's avatar
cactus committed
549
  | ITpattern
550

Ian Lynagh's avatar
Ian Lynagh committed
551
  -- Pragmas
552
  | ITinline_prag InlineSpec RuleMatchInfo
Ian Lynagh's avatar
Ian Lynagh committed
553 554
  | ITspec_prag                 -- SPECIALISE
  | ITspec_inline_prag Bool     -- SPECIALISE INLINE (or NOINLINE)
555 556
  | ITsource_prag
  | ITrules_prag
Ian Lynagh's avatar
Ian Lynagh committed
557
  | ITwarning_prag
558 559 560
  | ITdeprecated_prag
  | ITline_prag
  | ITscc_prag
andy@galois.com's avatar
andy@galois.com committed
561
  | ITgenerated_prag
562
  | ITcore_prag                 -- hdaume: core annotations
563
  | ITunpack_prag
564
  | ITnounpack_prag
565
  | ITann_prag
566
  | ITclose_prag
567 568 569
  | IToptions_prag String
  | ITinclude_prag String
  | ITlanguage_prag
570 571
  | ITvect_prag
  | ITvect_scalar_prag
572
  | ITnovect_prag
573
  | ITminimal_prag
574 575 576
  | IToverlappable_prag         -- instance overlap mode
  | IToverlapping_prag          -- instance overlap mode
  | IToverlaps_prag             -- instance overlap mode
577
  | ITincoherent_prag           -- instance overlap mode
578
  | ITctype
579

Ian Lynagh's avatar
Ian Lynagh committed
580
  | ITdotdot                    -- reserved symbols
581 582 583 584
  | ITcolon
  | ITdcolon
  | ITequal
  | ITlam
585
  | ITlcase
586 587 588 589 590
  | ITvbar
  | ITlarrow
  | ITrarrow
  | ITat
  | ITtilde
batterseapower's avatar
batterseapower committed
591
  | ITtildehsh
592 593 594 595 596 597
  | ITdarrow
  | ITminus
  | ITbang
  | ITstar
  | ITdot

Ian Lynagh's avatar
Ian Lynagh committed
598
  | ITbiglam                    -- GHC-extension symbols
599

Ian Lynagh's avatar
Ian Lynagh committed
600
  | ITocurly                    -- special symbols
601 602 603 604
  | ITccurly
  | ITvocurly
  | ITvccurly
  | ITobrack
Ian Lynagh's avatar
Ian Lynagh committed
605 606
  | ITopabrack                  -- [:, for parallel arrays with -XParallelArrays
  | ITcpabrack                  -- :], for parallel arrays with -XParallelArrays
607 608 609 610 611 612 613 614 615
  | ITcbrack
  | IToparen
  | ITcparen
  | IToubxparen
  | ITcubxparen
  | ITsemi
  | ITcomma
  | ITunderscore
  | ITbackquote
dreixel's avatar
dreixel committed
616
  | ITsimpleQuote               --  '
617

Ian Lynagh's avatar
Ian Lynagh committed
618
  | ITvarid   FastString        -- identifiers
619 620 621 622 623 624 625
  | ITconid   FastString
  | ITvarsym  FastString
  | ITconsym  FastString
  | ITqvarid  (FastString,FastString)
  | ITqconid  (FastString,FastString)
  | ITqvarsym (FastString,FastString)
  | ITqconsym (FastString,FastString)
626 627
  | ITprefixqvarsym (FastString,FastString)
  | ITprefixqconsym (FastString,FastString)
628

Ian Lynagh's avatar
Ian Lynagh committed
629
  | ITdupipvarid   FastString   -- GHC extension: implicit param: ?x
630 631 632 633

  | ITchar       Char
  | ITstring     FastString
  | ITinteger    Integer
634
  | ITrational   FractionalLit
635 636

  | ITprimchar   Char
637
  | ITprimstring ByteString
638
  | ITprimint    Integer
Ian Lynagh's avatar
Ian Lynagh committed
639
  | ITprimword   Integer
640 641
  | ITprimfloat  FractionalLit
  | ITprimdouble FractionalLit
642

643
  -- Template Haskell extension tokens
Ian Lynagh's avatar
Ian Lynagh committed
644 645 646 647 648
  | ITopenExpQuote              --  [| or [e|
  | ITopenPatQuote              --  [p|
  | ITopenDecQuote              --  [d|
  | ITopenTypQuote              --  [t|
  | ITcloseQuote                --  |]
649 650
  | ITopenTExpQuote             --  [||
  | ITcloseTExpQuote            --  ||]
Ian Lynagh's avatar
Ian Lynagh committed
651 652
  | ITidEscape   FastString     --  $x
  | ITparenEscape               --  $(
653 654
  | ITidTyEscape   FastString   --  $$x
  | ITparenTyEscape             --  $$(
Ian Lynagh's avatar
Ian Lynagh committed
655
  | ITtyQuote                   --  ''
656 657 658 659 660 661 662 663
  | ITquasiQuote (FastString,FastString,RealSrcSpan)
    -- ITquasiQuote(quoter, quote, loc)
    -- represents a quasi-quote of the form
    -- [quoter| quote |]
  | ITqQuasiQuote (FastString,FastString,FastString,RealSrcSpan)
    -- ITqQuasiQuote(Qual, quoter, quote, loc)
    -- represents a qualified quasi-quote of the form
    -- [Qual.quoter| quote |]
664 665 666 667

  -- Arrow notation extension
  | ITproc
  | ITrec
Ian Lynagh's avatar
Ian Lynagh committed
668 669 670 671 672 673
  | IToparenbar                 --  (|
  | ITcparenbar                 --  |)
  | ITlarrowtail                --  -<
  | ITrarrowtail                --  >-
  | ITLarrowtail                --  -<<
  | ITRarrowtail                --  >>-
674

Ian Lynagh's avatar
Ian Lynagh committed
675 676
  | ITunknown String            -- Used when the lexer can't make sense of it
  | ITeof                       -- end of file token
677 678 679 680 681 682 683

  -- Documentation annotations
  | ITdocCommentNext  String     -- something beginning '-- |'
  | ITdocCommentPrev  String     -- something beginning '-- ^'
  | ITdocCommentNamed String     -- something beginning '-- $'
  | ITdocSection      Int String -- a section heading
  | ITdocOptions      String     -- doc options (prune, ignore-exports, etc)
David Waern's avatar
David Waern committed
684
  | ITdocOptionsOld   String     -- doc options declared "-- # ..."-style
Jedai's avatar
Jedai committed
685 686
  | ITlineComment     String     -- comment starting by "--"
  | ITblockComment    String     -- comment in {- -}
687

688
  deriving Show
689 690 691 692 693 694 695 696

-- the bitmap provided as the third component indicates whether the
-- corresponding extension keyword is valid under the extension options
-- provided to the compiler; if the extension corresponding to *any* of the
-- bits set in the bitmap is enabled, the keyword is valid (this setup
-- facilitates using a keyword in two different extensions that can be
-- activated independently)
--
697
reservedWordsFM :: UniqFM (Token, ExtsBitmap)
698
reservedWordsFM = listToUFM $
Ian Lynagh's avatar
Ian Lynagh committed
699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725
    map (\(x, y, z) -> (mkFastString x, (y, z)))
        [( "_",              ITunderscore,    0 ),
         ( "as",             ITas,            0 ),
         ( "case",           ITcase,          0 ),
         ( "class",          ITclass,         0 ),
         ( "data",           ITdata,          0 ),
         ( "default",        ITdefault,       0 ),
         ( "deriving",       ITderiving,      0 ),
         ( "do",             ITdo,            0 ),
         ( "else",           ITelse,          0 ),
         ( "hiding",         IThiding,        0 ),
         ( "if",             ITif,            0 ),
         ( "import",         ITimport,        0 ),
         ( "in",             ITin,            0 ),
         ( "infix",          ITinfix,         0 ),
         ( "infixl",         ITinfixl,        0 ),
         ( "infixr",         ITinfixr,        0 ),
         ( "instance",       ITinstance,      0 ),
         ( "let",            ITlet,           0 ),
         ( "module",         ITmodule,        0 ),
         ( "newtype",        ITnewtype,       0 ),
         ( "of",             ITof,            0 ),
         ( "qualified",      ITqualified,     0 ),
         ( "then",           ITthen,          0 ),
         ( "type",           ITtype,          0 ),
         ( "where",          ITwhere,         0 ),

726 727 728
         ( "forall",         ITforall,        xbit ExplicitForallBit .|.
                                              xbit InRulePragBit),
         ( "mdo",            ITmdo,           xbit RecursiveDoBit),
729 730 731
             -- See Note [Lexing type pseudo-keywords]
         ( "family",         ITfamily,        0 ),
         ( "role",           ITrole,          0 ),
732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753
         ( "pattern",        ITpattern,       xbit PatternSynonymsBit),
         ( "group",          ITgroup,         xbit TransformComprehensionsBit),
         ( "by",             ITby,            xbit TransformComprehensionsBit),
         ( "using",          ITusing,         xbit TransformComprehensionsBit),

         ( "foreign",        ITforeign,       xbit FfiBit),
         ( "export",         ITexport,        xbit FfiBit),
         ( "label",          ITlabel,         xbit FfiBit),
         ( "dynamic",        ITdynamic,       xbit FfiBit),
         ( "safe",           ITsafe,          xbit FfiBit .|.
                                              xbit SafeHaskellBit),
         ( "interruptible",  ITinterruptible, xbit InterruptibleFfiBit),
         ( "unsafe",         ITunsafe,        xbit FfiBit),
         ( "stdcall",        ITstdcallconv,   xbit FfiBit),
         ( "ccall",          ITccallconv,     xbit FfiBit),
         ( "capi",           ITcapiconv,      xbit CApiFfiBit),
         ( "prim",           ITprimcallconv,  xbit FfiBit),
         ( "javascript",     ITjavascriptcallconv, xbit FfiBit),

         ( "rec",            ITrec,           xbit ArrowsBit .|.
                                              xbit RecursiveDoBit),
         ( "proc",           ITproc,          xbit ArrowsBit)
754 755
     ]

756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771
{-----------------------------------
Note [Lexing type pseudo-keywords]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

One might think that we wish to treat 'family' and 'role' as regular old
varids whenever -XTypeFamilies and -XRoleAnnotations are off, respectively.
But, there is no need to do so. These pseudo-keywords are not stolen syntax:
they are only used after the keyword 'type' at the top-level, where varids are
not allowed. Furthermore, checks further downstream (TcTyClsDecls) ensure that
type families and role annotations are never declared without their extensions
on. In fact, by unconditionally lexing these pseudo-keywords as special, we
can get better error messages.

Also, note that these are included in the `varid` production in the parser --
a key detail to make all this work.
-------------------------------------}
772

773
reservedSymsFM :: UniqFM (Token, ExtsBitmap -> Bool)
774
reservedSymsFM = listToUFM $
Ian Lynagh's avatar
Ian Lynagh committed
775 776 777 778 779 780 781 782 783 784 785 786
    map (\ (x,y,z) -> (mkFastString x,(y,z)))
      [ ("..",  ITdotdot,   always)
        -- (:) is a reserved op, meaning only list cons
       ,(":",   ITcolon,    always)
       ,("::",  ITdcolon,   always)
       ,("=",   ITequal,    always)
       ,("\\",  ITlam,      always)
       ,("|",   ITvbar,     always)
       ,("<-",  ITlarrow,   always)
       ,("->",  ITrarrow,   always)
       ,("@",   ITat,       always)
       ,("~",   ITtilde,    always)
787
       ,("~#",  ITtildehsh, magicHashEnabled)
Ian Lynagh's avatar
Ian Lynagh committed
788 789 790 791 792
       ,("=>",  ITdarrow,   always)
       ,("-",   ITminus,    always)
       ,("!",   ITbang,     always)

        -- For data T (a::*) = MkT
793
       ,("*", ITstar, always) -- \i -> kindSigsEnabled i || tyFamEnabled i)
Ian Lynagh's avatar
Ian Lynagh committed
794
        -- For 'forall a . t'
795
       ,(".", ITdot,  always) -- \i -> explicitForallEnabled i || inRulePrag i)
Ian Lynagh's avatar
Ian Lynagh committed
796 797 798 799 800

       ,("-<",  ITlarrowtail, arrowsEnabled)
       ,(">-",  ITrarrowtail, arrowsEnabled)
       ,("-<<", ITLarrowtail, arrowsEnabled)
       ,(">>-", ITRarrowtail, arrowsEnabled)
801

Ian Lynagh's avatar
Ian Lynagh committed
802 803
       ,("∷",   ITdcolon, unicodeSyntaxEnabled)
       ,("⇒",   ITdarrow, unicodeSyntaxEnabled)
804
       ,("∀",   ITforall, unicodeSyntaxEnabled)
Ian Lynagh's avatar
Ian Lynagh committed
805 806
       ,("→",   ITrarrow, unicodeSyntaxEnabled)
       ,("←",   ITlarrow, unicodeSyntaxEnabled)
807 808 809 810 811 812 813 814

       ,("⤙",   ITlarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤚",   ITrarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤛",   ITLarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤜",   ITRarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)

       ,("★", ITstar, unicodeSyntaxEnabled)

Simon Marlow's avatar
Simon Marlow committed
815 816 817
        -- ToDo: ideally, → and ∷ should be "specials", so that they cannot
        -- form part of a large operator.  This would let us have a better
        -- syntax for kinds: ɑ∷*→* would be a legal kind signature. (maybe).
818 819 820 821 822
       ]

-- -----------------------------------------------------------------------------
-- Lexer actions

Ian Lynagh's avatar
Ian Lynagh committed
823
type Action = RealSrcSpan -> StringBuffer -> Int -> P (RealLocated Token)
824

825
special :: Token -> Action
twanvl's avatar
twanvl committed
826
special tok span _buf _len = return (L span tok)
827

828
token, layout_token :: Token -> Action
twanvl's avatar
twanvl committed
829 830
token t span _buf _len = return (L span t)
layout_token t span _buf _len = pushLexState layout >> return (L span t)
831

832 833
idtoken :: (StringBuffer -> Int -> Token) -> Action
idtoken f span buf len = return (L span $! (f buf len))
834

835
skip_one_varid :: (FastString -> Token) -> Action
Ian Lynagh's avatar
Ian Lynagh committed
836
skip_one_varid f span buf len
837
  = return (L span $! f (lexemeToFastString (stepOn buf) (len-1)))
838

839 840 841 842
skip_two_varid :: (FastString -> Token) -> Action
skip_two_varid f span buf len
  = return (L span $! f (lexemeToFastString (stepOn (stepOn buf)) (len-2)))

843
strtoken :: (String -> Token) -> Action
Ian Lynagh's avatar
Ian Lynagh committed
844
strtoken f span buf len =
845
  return (L span $! (f $! lexemeToString buf len))
846

847
init_strtoken :: Int -> (String -> Token) -> Action
848
-- like strtoken, but drops the last N character(s)
Ian Lynagh's avatar
Ian Lynagh committed
849
init_strtoken drop f span buf len =
850
  return (L span $! (f $! lexemeToString buf (len-drop)))
851 852

begin :: Int -> Action
853
begin code _span _str _len = do pushLexState code; lexToken
854 855

pop :: Action
Ian Lynagh's avatar
Ian Lynagh committed
856 857
pop _span _buf _len = do _ <- popLexState
                         lexToken
858

859 860 861 862 863 864 865 866 867 868 869
hopefully_open_brace :: Action
hopefully_open_brace span buf len
 = do relaxed <- extension relaxedLayout
      ctx <- getContext
      (AI l _) <- getInput
      let offset = srcLocCol l
          isOK = relaxed ||
                 case ctx of
                 Layout prev_off : _ -> prev_off < offset
                 _                   -> True
      if isOK then pop_and open_brace span buf len
Ian Lynagh's avatar
Ian Lynagh committed
870
              else failSpanMsgP (RealSrcSpan span) (text "Missing block")
871

872
pop_and :: Action -> Action
Ian Lynagh's avatar
Ian Lynagh committed
873 874
pop_and act span buf len = do _ <- popLexState
                              act span buf len
875

876
{-# INLINE nextCharIs #-}
Ian Lynagh's avatar
Ian Lynagh committed
877
nextCharIs :: StringBuffer -> (Char -> Bool) -> Bool
878 879
nextCharIs buf p = not (atEnd buf) && p (currentChar buf)

880 881 882 883
{-# INLINE nextCharIsNot #-}
nextCharIsNot :: StringBuffer -> (Char -> Bool) -> Bool
nextCharIsNot buf p = not (nextCharIs buf p)

884
notFollowedBy :: Char -> AlexAccPred ExtsBitmap
Ian Lynagh's avatar
Ian Lynagh committed
885
notFollowedBy char _ _ _ (AI _ buf)
886
  = nextCharIsNot buf (== char)
887

888
notFollowedBySymbol :: AlexAccPred ExtsBitmap
889
notFollowedBySymbol _ _ _ (AI _ buf)
890
  = nextCharIsNot buf (`elem` "!#$%&*+./<=>?@\\^|-~")
ross's avatar
ross committed
891

892 893 894 895 896
-- We must reject doc comments as being ordinary comments everywhere.
-- In some cases the doc comment will be selected as the lexeme due to
-- maximal munch, but not always, because the nested comment rule is
-- valid in all states, but the doc-comment rules are only valid in
-- the non-layout states.
897
isNormalComment :: AlexAccPred ExtsBitmap
898
isNormalComment bits _ _ (AI _ buf)
899
  | haddockEnabled bits = notFollowedByDocOrPragma
900
  | otherwise           = nextCharIsNot buf (== '#')
901 902
  where
    notFollowedByDocOrPragma
903
       = afterOptionalSpace buf (\b -> nextCharIsNot b (`elem` "|^*$#"))
904

905 906 907 908 909
afterOptionalSpace :: StringBuffer -> (StringBuffer -> Bool) -> Bool
afterOptionalSpace buf p
    = if nextCharIs buf (== ' ')
      then p (snd (nextChar buf))
      else p buf
910

911
atEOL :: AlexAccPred ExtsBitmap
912
atEOL _ _ _ (AI _ buf) = atEnd buf || currentChar buf == '\n'
913

914
ifExtension :: (ExtsBitmap -> Bool) -> AlexAccPred ExtsBitmap
915 916
ifExtension pred bits _ _ _ = pred bits

917 918 919
multiline_doc_comment :: Action
multiline_doc_comment span buf _len = withLexedDocType (worker "")
  where
920
    worker commentAcc input docType oneLine = case alexGetChar' input of
Ian Lynagh's avatar
Ian Lynagh committed
921
      Just ('\n', input')
922 923 924 925 926 927
        | oneLine -> docCommentEnd input commentAcc docType buf span
        | otherwise -> case checkIfCommentLine input' of
          Just input -> worker ('\n':commentAcc) input docType False
          Nothing -> docCommentEnd input commentAcc docType buf span
      Just (c, input) -> worker (c:commentAcc) input docType oneLine
      Nothing -> docCommentEnd input commentAcc docType buf span
Ian Lynagh's avatar
Ian Lynagh committed
928

929 930
    checkIfCommentLine input = check (dropNonNewlineSpace input)
      where
931 932 933
        check input = case alexGetChar' input of
          Just ('-', input) -> case alexGetChar' input of
            Just ('-', input) -> case alexGetChar' input of
934 935 936 937 938
              Just (c, _) | c /= '-' -> Just input
              _ -> Nothing
            _ -> Nothing
          _ -> Nothing

939
        dropNonNewlineSpace input = case alexGetChar' input of
Ian Lynagh's avatar
Ian Lynagh committed
940
          Just (c, input')
941 942 943 944
            | isSpace c && c /= '\n' -> dropNonNewlineSpace input'
            | otherwise -> input
          Nothing -> input

Jedai's avatar
Jedai committed
945 946 947 948 949
lineCommentToken :: Action
lineCommentToken span buf len = do
  b <- extension rawTokenStreamEnabled
  if b then strtoken ITlineComment span buf len else lexToken

950 951 952 953
{-
  nested comments require traversing by hand, they can't be parsed
  using regular expressions.
-}
Ian Lynagh's avatar
Ian Lynagh committed
954
nested_comment :: P (RealLocated Token) -> Action
955
nested_comment cont span _str _len = do
956
  input <- getInput
Jedai's avatar
Jedai committed
957
  go "" (1::Int) input
958
  where
Jedai's avatar
Jedai committed
959 960 961 962 963
    go commentAcc 0 input = do setInput input
                               b <- extension rawTokenStreamEnabled
                               if b
                                 then docCommentEnd input commentAcc ITblockComment _str span
                                 else cont
964
    go commentAcc n input = case alexGetChar' input of
965
      Nothing -> errBrace input span
966
      Just ('-',input) -> case alexGetChar' input of
967
        Nothing  -> errBrace input span
Jedai's avatar
Jedai committed
968 969
        Just ('\125',input) -> go commentAcc (n-1) input
        Just (_,_)          -> go ('-':commentAcc) n input
970
      Just ('\123',input) -> case alexGetChar' input of
971
        Nothing  -> errBrace input span
Jedai's avatar
Jedai committed
972 973 974
        Just ('-',input) -> go ('-':'\123':commentAcc) (n+1) input
        Just (_,_)       -> go ('\123':commentAcc) n input
      Just (c,input) -> go (c:commentAcc) n input
975 976 977 978

nested_doc_comment :: Action
nested_doc_comment span buf _len = withLexedDocType (go "")
  where
979
    go commentAcc input docType _ = case alexGetChar' input of
980
      Nothing -> errBrace input span
981
      Just ('-',input) -> case alexGetChar' input of
982
        Nothing -> errBrace input span
twanvl's avatar
twanvl committed
983
        Just ('\125',input) ->
984
          docCommentEnd input commentAcc docType buf span
twanvl's avatar
twanvl committed
985
        Just (_,_) -> go ('-':commentAcc) input docType False
986
      Just ('\123', input) -> case alexGetChar' input of
987 988 989 990 991
        Nothing  -> errBrace input span
        Just ('-',input) -> do
          setInput input
          let cont = do input <- getInput; go commentAcc input docType False
          nested_comment cont span buf _len
twanvl's avatar
twanvl committed
992
        Just (_,_) -> go ('\123':commentAcc) input docType False
993 994
      Just (c,input) -> go (c:commentAcc) input docType False

Ian Lynagh's avatar
Ian Lynagh committed
995 996
withLexedDocType :: (AlexInput -> (String -> Token) -> Bool -> P (RealLocated Token))
                 -> P (RealLocated Token)
997
withLexedDocType lexDocComment = do
998
  input@(AI _ buf) <- getInput
999 1000 1001 1002
  case prevChar buf ' ' of
    '|' -> lexDocComment input ITdocCommentNext False
    '^' -> lexDocComment input ITdocCommentPrev False
    '$' -> lexDocComment input ITdocCommentNamed False
David Waern's avatar
David Waern committed
1003 1004
    '*' -> lexDocSection 1 input
    '#' -> lexDocComment input ITdocOptionsOld False
Ian Lynagh's avatar
Ian Lynagh committed
1005
    _ -> panic "withLexedDocType: Bad doc type"
Ian Lynagh's avatar
Ian Lynagh committed
1006
 where
1007
    lexDocSection n input = case alexGetChar' input of
1008
      Just ('*', input) -> lexDocSection (n+1) input
twanvl's avatar
twanvl committed
1009
      Just (_,   _)     -> lexDocComment input (ITdocSection n) True
1010 1011
      Nothing -> do setInput input; lexToken -- eof reached, lex it normally

1012 1013 1014
-- RULES pragmas turn on the forall and '.' keywords, and we turn them
-- off again at the end of the pragma.
rulePrag :: Action
1015
rulePrag span _buf _len = do
1016
  setExts (.|. xbit InRulePragBit)
1017 1018 1019
  return (L span ITrules_prag)

endPrag :: Action
1020
endPrag span _buf _len = do
1021
  setExts (.&. complement (xbit InRulePragBit))
1022 1023
  return (L span ITclose_prag)

1024 1025 1026