Lexer.x 135 KB
Newer Older
1
-----------------------------------------------------------------------------
2
-- (c) The University of Glasgow, 2006
3
--
4
-- GHC's lexer for Haskell 2010 [1].
5
--
6 7
-- This is a combination of an Alex-generated lexer [2] from a regex
-- definition, with some hand-coded bits. [3]
8 9
--
-- Completely accurate information about token-spans within the source
Ian Lynagh's avatar
Ian Lynagh committed
10 11
-- file is maintained.  Every token has a start and end RealSrcLoc
-- attached to it.
12
--
13 14 15
-- References:
-- [1] https://www.haskell.org/onlinereport/haskell2010/haskellch2.html
-- [2] http://www.haskell.org/alex/
16
-- [3] https://gitlab.haskell.org/ghc/ghc/wikis/commentary/compiler/parser
17
--
18 19 20 21 22 23 24 25 26 27
-----------------------------------------------------------------------------

--   ToDo / known bugs:
--    - parsing integers is a bit slow
--    - readRational is a bit slow
--
--   Known bugs, that were also in the previous version:
--    - M... should be 3 tokens, not 1.
--    - pragma-end should be only valid in a pragma

28
--   qualified operator NOTES.
Ian Lynagh's avatar
Ian Lynagh committed
29
--
30 31 32 33 34 35 36 37 38
--   - If M.(+) is a single lexeme, then..
--     - Probably (+) should be a single lexeme too, for consistency.
--       Otherwise ( + ) would be a prefix operator, but M.( + ) would not be.
--     - But we have to rule out reserved operators, otherwise (..) becomes
--       a different lexeme.
--     - Should we therefore also rule out reserved operators in the qualified
--       form?  This is quite difficult to achieve.  We don't do it for
--       qualified varids.

39 40 41 42

-- -----------------------------------------------------------------------------
-- Alex "Haskell code fragment top"

43
{
44
{-# LANGUAGE BangPatterns #-}
45
{-# LANGUAGE LambdaCase #-}
46
{-# LANGUAGE MultiWayIf #-}
47

48
{-# OPTIONS_GHC -funbox-strict-fields #-}
49
{-# OPTIONS_GHC -Wno-incomplete-uni-patterns #-}
50

Sylvain Henry's avatar
Sylvain Henry committed
51
module GHC.Parser.Lexer (
52
   Token(..), lexer, lexerDbg, pragState, mkPState, mkPStatePure, PState(..),
Vladislav Zavialov's avatar
Vladislav Zavialov committed
53 54 55 56
   P(..), ParseResult(..), mkParserFlags, mkParserFlags', ParserFlags(..),
   appendWarning,
   appendError,
   allocateComments,
57
   MonadP(..),
Sylvain Henry's avatar
Sylvain Henry committed
58
   getRealSrcLoc, getPState, withHomeUnitId,
59
   failMsgP, failLocMsgP, srcParseFail,
60
   getErrorMessages, getMessages,
61
   popContext, pushModuleContext, setLastToken, setSrcLoc,
vivian's avatar
vivian committed
62
   activeContext, nextIsEOF,
simonpj@microsoft.com's avatar
simonpj@microsoft.com committed
63
   getLexState, popLexState, pushLexState,
64
   ExtBits(..),
Vladislav Zavialov's avatar
Vladislav Zavialov committed
65
   xtest,
Alan Zimmerman's avatar
Alan Zimmerman committed
66
   lexTokenStream,
Vladislav Zavialov's avatar
Vladislav Zavialov committed
67 68
   AddAnn(..),mkParensApiAnn,
   addAnnsAt,
69 70
   commentToAnnotation,
   HdkComment(..),
71 72
  ) where

73
import GHC.Prelude
74

rodlogic's avatar
rodlogic committed
75 76 77
-- base
import Control.Monad
import Data.Bits
78
import Data.Char
rodlogic's avatar
rodlogic committed
79 80 81 82
import Data.List
import Data.Maybe
import Data.Word

83
import GHC.Data.EnumSet as EnumSet
84

85 86 87
-- ghc-boot
import qualified GHC.LanguageExtensions as LangExt

rodlogic's avatar
rodlogic committed
88 89 90 91 92 93 94
-- bytestring
import Data.ByteString (ByteString)

-- containers
import Data.Map (Map)
import qualified Data.Map as Map

95
-- compiler
96 97
import GHC.Data.Bag
import GHC.Utils.Outputable
98
import GHC.Utils.Panic
99 100
import GHC.Data.StringBuffer
import GHC.Data.FastString
Sylvain Henry's avatar
Sylvain Henry committed
101
import GHC.Types.Unique.FM
102 103
import GHC.Data.Maybe
import GHC.Data.OrdList
104 105
import GHC.Utils.Misc ( readRational, readHexRational )
import GHC.Utils.Error
Sylvain Henry's avatar
Sylvain Henry committed
106
import GHC.Driver.Session as DynFlags
rodlogic's avatar
rodlogic committed
107

Sylvain Henry's avatar
Sylvain Henry committed
108
import GHC.Types.SrcLoc
Sylvain Henry's avatar
Sylvain Henry committed
109
import GHC.Unit
Sylvain Henry's avatar
Sylvain Henry committed
110 111 112
import GHC.Types.Basic ( InlineSpec(..), RuleMatchInfo(..),
                         IntegralLit(..), FractionalLit(..),
                         SourceText(..) )
113
import GHC.Hs.Doc
114

Sylvain Henry's avatar
Sylvain Henry committed
115
import GHC.Parser.CharClass
Alan Zimmerman's avatar
Alan Zimmerman committed
116

Sylvain Henry's avatar
Sylvain Henry committed
117
import GHC.Parser.Annotation
118 119
}

120 121 122
-- -----------------------------------------------------------------------------
-- Alex "Character set macros"

123
-- NB: The logic behind these definitions is also reflected in "GHC.Utils.Lexeme"
124
-- Any changes here should likely be reflected there.
125
$unispace    = \x05 -- Trick Alex into handling Unicode. See [Unicode in Alex].
126 127 128
$nl          = [\n\r\f]
$whitechar   = [$nl\v\ $unispace]
$white_no_nl = $whitechar # \n -- TODO #8424
129
$tab         = \t
130 131

$ascdigit  = 0-9
132
$unidigit  = \x03 -- Trick Alex into handling Unicode. See [Unicode in Alex].
133
$decdigit  = $ascdigit -- for now, should really be $digit (ToDo)
134 135 136
$digit     = [$ascdigit $unidigit]

$special   = [\(\)\,\;\[\]\`\{\}]
137
$ascsymbol = [\!\#\$\%\&\*\+\.\/\<\=\>\?\@\\\^\|\-\~\:]
138
$unisymbol = \x04 -- Trick Alex into handling Unicode. See [Unicode in Alex].
139
$symbol    = [$ascsymbol $unisymbol] # [$special \_\"\']
140

141
$unilarge  = \x01 -- Trick Alex into handling Unicode. See [Unicode in Alex].
142
$asclarge  = [A-Z]
143 144
$large     = [$asclarge $unilarge]

145
$unismall  = \x02 -- Trick Alex into handling Unicode. See [Unicode in Alex].
146
$ascsmall  = [a-z]
147 148
$small     = [$ascsmall $unismall \_]

149
$unigraphic = \x06 -- Trick Alex into handling Unicode. See [Unicode in Alex].
150
$graphic   = [$small $large $symbol $digit $special $unigraphic \"\']
151

152
$binit     = 0-1
Ian Lynagh's avatar
Ian Lynagh committed
153
$octit     = 0-7
154
$hexit     = [$decdigit A-F a-f]
155

156
$uniidchar = \x07 -- Trick Alex into handling Unicode. See [Unicode in Alex].
157
$idchar    = [$small $large $digit $uniidchar \']
158

159 160
$pragmachar = [$small $large $digit]

161 162
$docsym    = [\| \^ \* \$]

163

164 165 166 167 168 169 170 171
-- -----------------------------------------------------------------------------
-- Alex "Regular expression macros"

@varid     = $small $idchar*          -- variable identifiers
@conid     = $large $idchar*          -- constructor identifiers

@varsym    = ($symbol # \:) $symbol*  -- variable (operator) symbol
@consym    = \: $symbol*              -- constructor (operator) symbol
172

173 174 175 176 177 178 179 180
-- See Note [Lexing NumericUnderscores extension] and #14473
@numspc       = _*                   -- numeric spacer (#14473)
@decimal      = $decdigit(@numspc $decdigit)*
@binary       = $binit(@numspc $binit)*
@octal        = $octit(@numspc $octit)*
@hexadecimal  = $hexit(@numspc $hexit)*
@exponent     = @numspc [eE] [\-\+]? @decimal
@bin_exponent = @numspc [pP] [\-\+]? @decimal
181 182

@qual = (@conid \.)+
183 184 185 186
@qvarid = @qual @varid
@qconid = @qual @conid
@qvarsym = @qual @varsym
@qconsym = @qual @consym
187

188 189 190 191 192
-- QualifiedDo needs to parse "M.do" not as a variable, so as to keep the
-- layout rules.
@qdo    = @qual "do"
@qmdo   = @qual "mdo"

193 194
@floating_point = @numspc @decimal \. @decimal @exponent? | @numspc @decimal @exponent
@hex_floating_point = @numspc @hexadecimal \. @hexadecimal @bin_exponent? | @numspc @hexadecimal @bin_exponent
195

196 197 198 199
-- normal signed numerical literals can only be explicitly negative,
-- not explicitly positive (contrast @exponent)
@negative = \-

200 201 202 203

-- -----------------------------------------------------------------------------
-- Alex "Identifier"

204 205
haskell :-

206 207 208 209 210

-- -----------------------------------------------------------------------------
-- Alex "Rules"

-- everywhere: skip whitespace
Ian Lynagh's avatar
Ian Lynagh committed
211
$white_no_nl+ ;
212
$tab          { warnTab }
213 214 215 216 217

-- Everywhere: deal with nested comments.  We explicitly rule out
-- pragmas, "{-#", so that we don't accidentally treat them as comments.
-- (this can happen even though pragmas will normally take precedence due to
-- longest-match, because pragmas aren't valid in every state, but comments
218 219 220 221
-- are). We also rule out nested Haddock comments, if the -haddock flag is
-- set.

"{-" / { isNormalComment } { nested_comment lexToken }
222 223 224 225

-- Single-line comments are a bit tricky.  Haskell 98 says that two or
-- more dashes followed by a symbol should be parsed as a varsym, so we
-- have to exclude those.
226 227

-- Since Haddock comments aren't valid in every state, we need to rule them
Ian Lynagh's avatar
Ian Lynagh committed
228
-- out here.
229 230 231 232 233 234 235

-- The following two rules match comments that begin with two dashes, but
-- continue with a different character. The rules test that this character
-- is not a symbol (in which case we'd have a varsym), and that it's not a
-- space followed by a Haddock comment symbol (docsym) (in which case we'd
-- have a Haddock comment). The rules then munch the rest of the line.

236
"-- " ~$docsym .* { lineCommentToken }
237
"--" [^$symbol \ ] .* { lineCommentToken }
238 239 240

-- Next, match Haddock comments if no -haddock flag

241
"-- " $docsym .* / { alexNotPred (ifExtension HaddockBit) } { lineCommentToken }
242 243 244 245 246 247 248

-- Now, when we've matched comments that begin with 2 dashes and continue
-- with a different character, we need to match comments that begin with three
-- or more dashes (which clearly can't be Haddock comments). We only need to
-- make sure that the first non-dash character isn't a symbol, and munch the
-- rest of the line.

249
"---"\-* ~$symbol .* { lineCommentToken }
250 251 252 253

-- Since the previous rules all match dashes followed by at least one
-- character, we also need to match a whole line filled with just dashes.

Jedai's avatar
Jedai committed
254
"--"\-* / { atEOL } { lineCommentToken }
255 256 257 258

-- We need this rule since none of the other single line comment rules
-- actually match this case.

Jedai's avatar
Jedai committed
259
"-- " / { atEOL } { lineCommentToken }
260 261 262 263 264 265 266 267 268 269 270

-- 'bol' state: beginning of a line.  Slurp up all the whitespace (including
-- blank lines) until we find a non-whitespace character, then do layout
-- processing.
--
-- One slight wibble here: what if the line begins with {-#? In
-- theory, we have to lex the pragma to see if it's one we recognise,
-- and if it is, then we backtrack and do_bol, otherwise we treat it
-- as a nested comment.  We don't bother with this: if the line begins
-- with {-#, then we'll assume it's a pragma we know about and go for do_bol.
<bol> {
Ian Lynagh's avatar
Ian Lynagh committed
271
  \n                                    ;
Adam Gundry's avatar
Adam Gundry committed
272 273
  ^\# line                              { begin line_prag1 }
  ^\# / { followedByDigit }             { begin line_prag1 }
Ian Lynagh's avatar
Ian Lynagh committed
274 275 276
  ^\# pragma .* \n                      ; -- GCC 3.3 CPP generated, apparently
  ^\# \! .* \n                          ; -- #!, for scripts
  ()                                    { do_bol }
277 278 279 280 281
}

-- after a layout keyword (let, where, do, of), we begin a new layout
-- context if the curly brace is missing.
-- Careful! This stuff is quite delicate.
282
<layout, layout_do, layout_if> {
Ian Lynagh's avatar
Ian Lynagh committed
283 284 285 286
  \{ / { notFollowedBy '-' }            { hopefully_open_brace }
        -- we might encounter {-# here, but {- has been handled already
  \n                                    ;
  ^\# (line)?                           { begin line_prag1 }
287 288
}

289 290
-- after an 'if', a vertical bar starts a layout context for MultiWayIf
<layout_if> {
291
  \| / { notFollowedBySymbol }          { new_layout_context True dontGenerateSemic ITvbar }
292 293 294
  ()                                    { pop }
}

295
-- do is treated in a subtly different way, see new_layout_context
296 297
<layout>    ()                          { new_layout_context True  generateSemic ITvocurly }
<layout_do> ()                          { new_layout_context False generateSemic ITvocurly }
298 299 300 301

-- after a new layout context which was found to be to the left of the
-- previous context, we have generated a '{' token, and we now need to
-- generate a matching '}' token.
Ian Lynagh's avatar
Ian Lynagh committed
302
<layout_left>  ()                       { do_layout_left }
303

Ian Lynagh's avatar
Ian Lynagh committed
304
<0,option_prags> \n                     { begin bol }
305

306 307
"{-#" $whitechar* $pragmachar+ / { known_pragma linePrags }
                                { dispatch_pragmas linePrags }
308 309 310

-- single-line line pragmas, of the form
--    # <line> "<file>" <extra-stuff> \n
311 312 313 314 315
<line_prag1> {
  @decimal $white_no_nl+ \" [$graphic \ ]* \"  { setLineAndFile line_prag1a }
  ()                                           { failLinePrag1 }
}
<line_prag1a> .*                               { popLinePrag1 }
316 317 318

-- Haskell-style line pragmas, of the form
--    {-# LINE <line> "<file>" #-}
319 320 321 322
<line_prag2> {
  @decimal $white_no_nl+ \" [$graphic \ ]* \"  { setLineAndFile line_prag2a }
}
<line_prag2a> "#-}"|"-}"                       { pop }
323 324
   -- NOTE: accept -} at the end of a LINE pragma, for compatibility
   -- with older versions of GHC which generated these.
325

Rufflewind's avatar
Rufflewind committed
326 327 328 329
-- Haskell-style column pragmas, of the form
--    {-# COLUMN <column> #-}
<column_prag> @decimal $whitechar* "#-}" { setColumn }

330
<0,option_prags> {
Ian Lynagh's avatar
Ian Lynagh committed
331
  "{-#" $whitechar* $pragmachar+
332 333 334 335 336
        $whitechar+ $pragmachar+ / { known_pragma twoWordPrags }
                                 { dispatch_pragmas twoWordPrags }

  "{-#" $whitechar* $pragmachar+ / { known_pragma oneWordPrags }
                                 { dispatch_pragmas oneWordPrags }
337

338
  -- We ignore all these pragmas, but don't generate a warning for them
339 340
  "{-#" $whitechar* $pragmachar+ / { known_pragma ignoredPrags }
                                 { dispatch_pragmas ignoredPrags }
341 342

  -- ToDo: should only be valid inside a pragma:
Ian Lynagh's avatar
Ian Lynagh committed
343
  "#-}"                          { endPrag }
344 345
}

346
<option_prags> {
347 348
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
                                   { dispatch_pragmas fileHeaderPrags }
David Waern's avatar
David Waern committed
349 350
}

351 352
<0> {
  -- In the "0" mode we ignore these pragmas
353
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
354 355 356
                     { nested_comment lexToken }
}

357
<0,option_prags> {
358 359
  "{-#"  { warnThen Opt_WarnUnrecognisedPragmas (text "Unrecognised pragma")
                    (nested_comment lexToken) }
360 361
}

362 363
-- '0' state: ordinary lexemes

364 365
-- Haddock comments

366 367
"-- " $docsym      / { ifExtension HaddockBit } { multiline_doc_comment }
"{-" \ ? $docsym   / { ifExtension HaddockBit } { nested_doc_comment }
368

369 370
-- "special" symbols

371
<0> {
372 373 374 375 376 377 378 379 380

  -- Don't check ThQuotesBit here as the renamer can produce a better
  -- error message than the lexer (see the thQuotesEnabled check in rnBracket).
  "[|"  { token (ITopenExpQuote NoE NormalSyntax) }
  "[||" { token (ITopenTExpQuote NoE) }
  "|]"  { token (ITcloseQuote NormalSyntax) }
  "||]" { token ITcloseTExpQuote }

  -- Check ThQuotesBit here as to not steal syntax.
381 382 383 384 385 386 387
  "[e|"       / { ifExtension ThQuotesBit } { token (ITopenExpQuote HasE NormalSyntax) }
  "[e||"      / { ifExtension ThQuotesBit } { token (ITopenTExpQuote HasE) }
  "[p|"       / { ifExtension ThQuotesBit } { token ITopenPatQuote }
  "[d|"       / { ifExtension ThQuotesBit } { layout_token ITopenDecQuote }
  "[t|"       / { ifExtension ThQuotesBit } { token ITopenTypQuote }

  "[" @varid "|"  / { ifExtension QqBit }   { lex_quasiquote_tok }
388 389

  -- qualified quasi-quote (#5555)
390
  "[" @qvarid "|"  / { ifExtension QqBit }  { lex_qquasiquote_tok }
391 392 393

  $unigraphic -- ⟦
    / { ifCurrentChar '⟦' `alexAndPred`
394 395
        ifExtension UnicodeSyntaxBit `alexAndPred`
        ifExtension ThQuotesBit }
396 397 398
    { token (ITopenExpQuote NoE UnicodeSyntax) }
  $unigraphic -- ⟧
    / { ifCurrentChar '⟧' `alexAndPred`
399 400
        ifExtension UnicodeSyntaxBit `alexAndPred`
        ifExtension ThQuotesBit }
401
    { token (ITcloseQuote UnicodeSyntax) }
402 403
}

404
<0> {
405 406 407 408 409 410 411
  "(|"
    / { ifExtension ArrowsBit `alexAndPred`
        notFollowedBySymbol }
    { special (IToparenbar NormalSyntax) }
  "|)"
    / { ifExtension ArrowsBit }
    { special (ITcparenbar NormalSyntax) }
412 413 414

  $unigraphic -- ⦇
    / { ifCurrentChar '⦇' `alexAndPred`
415 416
        ifExtension UnicodeSyntaxBit `alexAndPred`
        ifExtension ArrowsBit }
417 418 419
    { special (IToparenbar UnicodeSyntax) }
  $unigraphic -- ⦈
    / { ifCurrentChar '⦈' `alexAndPred`
420 421
        ifExtension UnicodeSyntaxBit `alexAndPred`
        ifExtension ArrowsBit }
422
    { special (ITcparenbar UnicodeSyntax) }
423 424
}

425
<0> {
426
  \? @varid / { ifExtension IpBit } { skip_one_varid ITdupipvarid }
427 428
}

Adam Gundry's avatar
Adam Gundry committed
429
<0> {
430
  "#" @varid / { ifExtension OverloadedLabelsBit } { skip_one_varid ITlabelvarid }
Adam Gundry's avatar
Adam Gundry committed
431 432
}

433
<0> {
434 435
  "(#" / { ifExtension UnboxedTuplesBit `alexOrPred`
           ifExtension UnboxedSumsBit }
Ian Lynagh's avatar
Ian Lynagh committed
436
         { token IToubxparen }
437 438
  "#)" / { ifExtension UnboxedTuplesBit `alexOrPred`
           ifExtension UnboxedSumsBit }
Ian Lynagh's avatar
Ian Lynagh committed
439 440 441
         { token ITcubxparen }
}

442
<0,option_prags> {
Ian Lynagh's avatar
Ian Lynagh committed
443 444 445 446 447 448 449 450 451 452
  \(                                    { special IToparen }
  \)                                    { special ITcparen }
  \[                                    { special ITobrack }
  \]                                    { special ITcbrack }
  \,                                    { special ITcomma }
  \;                                    { special ITsemi }
  \`                                    { special ITbackquote }

  \{                                    { open_brace }
  \}                                    { close_brace }
453 454
}

455
<0,option_prags> {
456 457
  @qdo                                      { qdo_token ITdo }
  @qmdo    / { ifExtension RecursiveDoBit } { qdo_token ITmdo }
458 459
  @qvarid                       { idtoken qvarid }
  @qconid                       { idtoken qconid }
Ian Lynagh's avatar
Ian Lynagh committed
460
  @varid                        { varid }
461
  @conid                        { idtoken conid }
462 463
}

464
<0> {
465 466 467 468
  @qvarid "#"+      / { ifExtension MagicHashBit } { idtoken qvarid }
  @qconid "#"+      / { ifExtension MagicHashBit } { idtoken qconid }
  @varid "#"+       / { ifExtension MagicHashBit } { varid }
  @conid "#"+       / { ifExtension MagicHashBit } { idtoken conid }
469 470
}

471 472 473 474 475 476 477 478 479
-- Operators classified into prefix, suffix, tight infix, and loose infix.
-- See Note [Whitespace-sensitive operator parsing]
<0> {
  @varsym / { precededByClosingToken `alexAndPred` followedByOpeningToken } { varsym_tight_infix }
  @varsym / { followedByOpeningToken }  { varsym_prefix }
  @varsym / { precededByClosingToken }  { varsym_suffix }
  @varsym                               { varsym_loose_infix }
}

480 481
-- ToDo: - move `var` and (sym) into lexical syntax?
--       - remove backquote from $special?
482
<0> {
483 484
  @qvarsym                                         { idtoken qvarsym }
  @qconsym                                         { idtoken qconsym }
485
  @consym                                          { consym }
486 487
}

488 489
-- For the normal boxed literals we need to be careful
-- when trying to be close to Haskell98
490 491 492 493 494 495 496 497 498 499

-- Note [Lexing NumericUnderscores extension] (#14473)
--
-- NumericUnderscores extension allows underscores in numeric literals.
-- Multiple underscores are represented with @numspc macro.
-- To be simpler, we have only the definitions with underscores.
-- And then we have a separate function (tok_integral and tok_frac)
-- that validates the literals.
-- If extensions are not enabled, check that there are no underscores.
--
500
<0> {
501
  -- Normal integral literals (:: Num a => a, from Integer)
502 503 504 505
  @decimal                                                                   { tok_num positive 0 0 decimal }
  0[bB] @numspc @binary                / { ifExtension BinaryLiteralsBit }   { tok_num positive 2 2 binary }
  0[oO] @numspc @octal                                                       { tok_num positive 2 2 octal }
  0[xX] @numspc @hexadecimal                                                 { tok_num positive 2 2 hexadecimal }
506 507
  @negative @decimal                   / { negLitPred }                      { tok_num negative 1 1 decimal }
  @negative 0[bB] @numspc @binary      / { negLitPred `alexAndPred`
508
                                           ifExtension BinaryLiteralsBit }   { tok_num negative 3 3 binary }
509 510
  @negative 0[oO] @numspc @octal       / { negLitPred }                      { tok_num negative 3 3 octal }
  @negative 0[xX] @numspc @hexadecimal / { negLitPred }                      { tok_num negative 3 3 hexadecimal }
511 512

  -- Normal rational literals (:: Fractional a => a, from Rational)
513
  @floating_point                                                            { tok_frac 0 tok_float }
514
  @negative @floating_point            / { negLitPred }                      { tok_frac 0 tok_float }
515 516 517
  0[xX] @numspc @hex_floating_point    / { ifExtension HexFloatLiteralsBit } { tok_frac 0 tok_hex_float }
  @negative 0[xX] @numspc @hex_floating_point
                                       / { ifExtension HexFloatLiteralsBit `alexAndPred`
518
                                           negLitPred }                      { tok_frac 0 tok_hex_float }
519 520
}

521
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
522
  -- Unboxed ints (:: Int#) and words (:: Word#)
523 524
  -- It's simpler (and faster?) to give separate cases to the negatives,
  -- especially considering octal/hexadecimal prefixes.
525 526 527 528 529
  @decimal                          \# / { ifExtension MagicHashBit }        { tok_primint positive 0 1 decimal }
  0[bB] @numspc @binary             \# / { ifExtension MagicHashBit `alexAndPred`
                                           ifExtension BinaryLiteralsBit }   { tok_primint positive 2 3 binary }
  0[oO] @numspc @octal              \# / { ifExtension MagicHashBit }        { tok_primint positive 2 3 octal }
  0[xX] @numspc @hexadecimal        \# / { ifExtension MagicHashBit }        { tok_primint positive 2 3 hexadecimal }
530 531
  @negative @decimal                \# / { negHashLitPred }                  { tok_primint negative 1 2 decimal }
  @negative 0[bB] @numspc @binary   \# / { negHashLitPred `alexAndPred`
532
                                           ifExtension BinaryLiteralsBit }   { tok_primint negative 3 4 binary }
533
  @negative 0[oO] @numspc @octal    \# / { negHashLitPred }                  { tok_primint negative 3 4 octal }
534
  @negative 0[xX] @numspc @hexadecimal \#
535
                                       / { negHashLitPred }                  { tok_primint negative 3 4 hexadecimal }
536 537 538 539 540 541

  @decimal                       \# \# / { ifExtension MagicHashBit }        { tok_primword 0 2 decimal }
  0[bB] @numspc @binary          \# \# / { ifExtension MagicHashBit `alexAndPred`
                                           ifExtension BinaryLiteralsBit }   { tok_primword 2 4 binary }
  0[oO] @numspc @octal           \# \# / { ifExtension MagicHashBit }        { tok_primword 2 4 octal }
  0[xX] @numspc @hexadecimal     \# \# / { ifExtension MagicHashBit }        { tok_primword 2 4 hexadecimal }
Ian Lynagh's avatar
Ian Lynagh committed
542

543 544
  -- Unboxed floats and doubles (:: Float#, :: Double#)
  -- prim_{float,double} work with signed literals
545 546 547 548 549
  @floating_point                  \# / { ifExtension MagicHashBit }        { tok_frac 1 tok_primfloat }
  @floating_point               \# \# / { ifExtension MagicHashBit }        { tok_frac 2 tok_primdouble }

  @negative @floating_point        \# / { negHashLitPred }                  { tok_frac 1 tok_primfloat }
  @negative @floating_point     \# \# / { negHashLitPred }                  { tok_frac 2 tok_primdouble }
550 551 552 553 554 555
}

-- Strings and chars are lexed by hand-written code.  The reason is
-- that even if we recognise the string or char here in the regex
-- lexer, we would still have to parse the string afterward in order
-- to convert it to a String.
556
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
557 558
  \'                            { lex_char_tok }
  \"                            { lex_string_tok }
559 560
}

561 562 563 564 565 566 567 568 569 570 571
-- Note [Whitespace-sensitive operator parsing]
-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
-- In accord with GHC Proposal #229 https://github.com/ghc-proposals/ghc-proposals/blob/master/proposals/0229-whitespace-bang-patterns.rst
-- we classify operator occurrences into four categories:
--
--     a ! b   -- a loose infix occurrence
--     a!b     -- a tight infix occurrence
--     a !b    -- a prefix occurrence
--     a! b    -- a suffix occurrence
--
-- The rules are a bit more elaborate than simply checking for whitespace, in
Brian Wignall's avatar
Brian Wignall committed
572
-- order to accommodate the following use cases:
573 574 575 576 577 578 579
--
--     f (!a) = ...    -- prefix occurrence
--     g (a !)         -- loose infix occurrence
--     g (! a)         -- loose infix occurrence
--
-- The precise rules are as follows:
--
580 581 582
--  * Identifiers, literals, and opening brackets (, (#, (|, [, [|, [||, [p|,
--    [e|, [t|, {, ⟦, ⦇, are considered "opening tokens". The function
--    followedByOpeningToken tests whether the next token is an opening token.
583
--
584
--  * Identifiers, literals, and closing brackets ), #), |), ], |], }, ⟧, ⦈,
585 586
--    are considered "closing tokens". The function precededByClosingToken tests
--    whether the previous token is a closing token.
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
587
--
588 589
--  * Whitespace, comments, separators, and other tokens, are considered
--    neither opening nor closing.
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
590
--
591 592
--  * Any unqualified operator occurrence is classified as prefix, suffix, or
--    tight/loose infix, based on preceding and following tokens:
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
593
--
594 595 596 597 598 599 600
--       precededByClosingToken | followedByOpeningToken | Occurrence
--      ------------------------+------------------------+------------
--       False                  | True                   | prefix
--       True                   | False                  | suffix
--       True                   | True                   | tight infix
--       False                  | False                  | loose infix
--      ------------------------+------------------------+------------
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
601
--
602 603
-- A loose infix occurrence is always considered an operator. Other types of
-- occurrences may be assigned a special per-operator meaning override:
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
604
--
605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637
--   Operator |  Occurrence   | Token returned
--  ----------+---------------+------------------------------------------
--    !       |  prefix       | ITbang
--            |               |   strictness annotation or bang pattern,
--            |               |   e.g.  f !x = rhs, data T = MkT !a
--            |  not prefix   | ITvarsym "!"
--            |               |   ordinary operator or type operator,
--            |               |   e.g.  xs ! 3, (! x), Int ! Bool
--  ----------+---------------+------------------------------------------
--    ~       |  prefix       | ITtilde
--            |               |   laziness annotation or lazy pattern,
--            |               |   e.g.  f ~x = rhs, data T = MkT ~a
--            |  not prefix   | ITvarsym "~"
--            |               |   ordinary operator or type operator,
--            |               |   e.g.  xs ~ 3, (~ x), Int ~ Bool
--  ----------+---------------+------------------------------------------
--    $  $$   |  prefix       | ITdollar, ITdollardollar
--            |               |   untyped or typed Template Haskell splice,
--            |               |   e.g.  $(f x), $$(f x), $$"str"
--            |  not prefix   | ITvarsym "$", ITvarsym "$$"
--            |               |   ordinary operator or type operator,
--            |               |   e.g.  f $ g x, a $$ b
--  ----------+---------------+------------------------------------------
--    @       |  prefix       | ITtypeApp
--            |               |   type application, e.g.  fmap @Maybe
--            |  tight infix  | ITat
--            |               |   as-pattern, e.g.  f p@(a,b) = rhs
--            |  suffix       | parse error
--            |               |   e.g. f p@ x = rhs
--            |  loose infix  | ITvarsym "@"
--            |               |   ordinary operator or type operator,
--            |               |   e.g.  f @ g, (f @)
--  ----------+---------------+------------------------------------------
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
638
--
639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668
-- Also, some of these overrides are guarded behind language extensions.
-- According to the specification, we must determine the occurrence based on
-- surrounding *tokens* (see the proposal for the exact rules). However, in
-- the implementation we cheat a little and do the classification based on
-- characters, for reasons of both simplicity and efficiency (see
-- 'followedByOpeningToken' and 'precededByClosingToken')
--
-- When an operator is subject to a meaning override, it is mapped to special
-- token: ITbang, ITtilde, ITat, ITdollar, ITdollardollar. Otherwise, it is
-- returned as ITvarsym.
--
-- For example, this is how we process the (!):
--
--    precededByClosingToken | followedByOpeningToken | Token
--   ------------------------+------------------------+-------------
--    False                  | True                   | ITbang
--    True                   | False                  | ITvarsym "!"
--    True                   | True                   | ITvarsym "!"
--    False                  | False                  | ITvarsym "!"
--   ------------------------+------------------------+-------------
--
-- And this is how we process the (@):
--
--    precededByClosingToken | followedByOpeningToken | Token
--   ------------------------+------------------------+-------------
--    False                  | True                   | ITtypeApp
--    True                   | False                  | parse error
--    True                   | True                   | ITat
--    False                  | False                  | ITvarsym "@"
--   ------------------------+------------------------+-------------
669 670 671 672

-- -----------------------------------------------------------------------------
-- Alex "Haskell code fragment bottom"

673
{
674

675 676 677
-- -----------------------------------------------------------------------------
-- The token type

678
data Token
Ian Lynagh's avatar
Ian Lynagh committed
679
  = ITas                        -- Haskell keywords
680 681 682 683 684
  | ITcase
  | ITclass
  | ITdata
  | ITdefault
  | ITderiving
685
  | ITdo (Maybe FastString)
686 687
  | ITelse
  | IThiding
688
  | ITforeign
689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704
  | ITif
  | ITimport
  | ITin
  | ITinfix
  | ITinfixl
  | ITinfixr
  | ITinstance
  | ITlet
  | ITmodule
  | ITnewtype
  | ITof
  | ITqualified
  | ITthen
  | ITtype
  | ITwhere

705
  | ITforall            IsUnicodeSyntax -- GHC extension keywords
706 707 708 709
  | ITexport
  | ITlabel
  | ITdynamic
  | ITsafe
710
  | ITinterruptible
711 712 713
  | ITunsafe
  | ITstdcallconv
  | ITccallconv
714
  | ITcapiconv
715
  | ITprimcallconv
thoughtpolice's avatar
thoughtpolice committed
716
  | ITjavascriptcallconv
717
  | ITmdo (Maybe FastString)
718
  | ITfamily
719
  | ITrole
720 721 722
  | ITgroup
  | ITby
  | ITusing
Gergő Érdi's avatar
Gergő Érdi committed
723
  | ITpattern
Facundo Domínguez's avatar
Facundo Domínguez committed
724
  | ITstatic
Ryan Scott's avatar
Ryan Scott committed
725 726
  | ITstock
  | ITanyclass
Ryan Scott's avatar
Ryan Scott committed
727
  | ITvia
728

Edward Z. Yang's avatar
Edward Z. Yang committed
729 730 731 732 733 734
  -- Backpack tokens
  | ITunit
  | ITsignature
  | ITdependency
  | ITrequires

735
  -- Pragmas, see  note [Pragma source text] in "GHC.Types.Basic"
Alan Zimmerman's avatar
Alan Zimmerman committed
736 737 738 739 740 741 742
  | ITinline_prag       SourceText InlineSpec RuleMatchInfo
  | ITspec_prag         SourceText                -- SPECIALISE
  | ITspec_inline_prag  SourceText Bool    -- SPECIALISE INLINE (or NOINLINE)
  | ITsource_prag       SourceText
  | ITrules_prag        SourceText
  | ITwarning_prag      SourceText
  | ITdeprecated_prag   SourceText
743 744
  | ITline_prag         SourceText  -- not usually produced, see 'UsePosPragsBit'
  | ITcolumn_prag       SourceText  -- not usually produced, see 'UsePosPragsBit'
Alan Zimmerman's avatar
Alan Zimmerman committed
745 746 747 748
  | ITscc_prag          SourceText
  | ITunpack_prag       SourceText
  | ITnounpack_prag     SourceText
  | ITann_prag          SourceText
749
  | ITcomplete_prag     SourceText
750
  | ITclose_prag
751 752 753
  | IToptions_prag String
  | ITinclude_prag String
  | ITlanguage_prag
Alan Zimmerman's avatar
Alan Zimmerman committed
754 755 756 757 758 759
  | ITminimal_prag      SourceText
  | IToverlappable_prag SourceText  -- instance overlap mode
  | IToverlapping_prag  SourceText  -- instance overlap mode
  | IToverlaps_prag     SourceText  -- instance overlap mode
  | ITincoherent_prag   SourceText  -- instance overlap mode
  | ITctype             SourceText
760
  | ITcomment_line_prag         -- See Note [Nested comment line pragmas]
761

Ian Lynagh's avatar
Ian Lynagh committed
762
  | ITdotdot                    -- reserved symbols
763
  | ITcolon
764
  | ITdcolon            IsUnicodeSyntax
765 766
  | ITequal
  | ITlam
767
  | ITlcase
768
  | ITvbar
769 770
  | ITlarrow            IsUnicodeSyntax
  | ITrarrow            IsUnicodeSyntax
Krzysztof Gogolewski's avatar
Krzysztof Gogolewski committed
771
  | ITlolly             IsUnicodeSyntax
772
  | ITdarrow            IsUnicodeSyntax
773 774
  | ITminus       -- See Note [Minus tokens]
  | ITprefixminus -- See Note [Minus tokens]
775 776 777 778
  | ITbang     -- Prefix (!) only, e.g. f !x = rhs
  | ITtilde    -- Prefix (~) only, e.g. f ~x = rhs
  | ITat       -- Tight infix (@) only, e.g. f x@pat = rhs
  | ITtypeApp  -- Prefix (@) only, e.g. f @t
779
  | ITstar              IsUnicodeSyntax
780 781
  | ITdot

Ian Lynagh's avatar
Ian Lynagh committed
782
  | ITbiglam                    -- GHC-extension symbols
783

Ian Lynagh's avatar
Ian Lynagh committed
784
  | ITocurly                    -- special symbols
785 786 787 788
  | ITccurly
  | ITvocurly
  | ITvccurly
  | ITobrack
Ian Lynagh's avatar
Ian Lynagh committed
789 790
  | ITopabrack                  -- [:, for parallel arrays with -XParallelArrays
  | ITcpabrack                  -- :], for parallel arrays with -XParallelArrays
791 792 793 794 795 796 797 798 799
  | ITcbrack
  | IToparen
  | ITcparen
  | IToubxparen
  | ITcubxparen
  | ITsemi
  | ITcomma
  | ITunderscore
  | ITbackquote
dreixel's avatar
dreixel committed
800
  | ITsimpleQuote               --  '
801

Ian Lynagh's avatar
Ian Lynagh committed
802
  | ITvarid   FastString        -- identifiers
803 804 805 806 807 808 809 810
  | ITconid   FastString
  | ITvarsym  FastString
  | ITconsym  FastString
  | ITqvarid  (FastString,FastString)
  | ITqconid  (FastString,FastString)
  | ITqvarsym (FastString,FastString)
  | ITqconsym (FastString,FastString)

Ian Lynagh's avatar
Ian Lynagh committed
811
  | ITdupipvarid   FastString   -- GHC extension: implicit param: ?x
Adam Gundry's avatar
Adam Gundry committed
812
  | ITlabelvarid   FastString   -- Overloaded label: #x
813

814 815 816
  | ITchar     SourceText Char       -- Note [Literal source text] in "GHC.Types.Basic"
  | ITstring   SourceText FastString -- Note [Literal source text] in "GHC.Types.Basic"
  | ITinteger  IntegralLit           -- Note [Literal source text] in "GHC.Types.Basic"
Alan Zimmerman's avatar
Alan Zimmerman committed
817
  | ITrational FractionalLit
818

819 820 821 822
  | ITprimchar   SourceText Char     -- Note [Literal source text] in "GHC.Types.Basic"
  | ITprimstring SourceText ByteString -- Note [Literal source text] in "GHC.Types.Basic"
  | ITprimint    SourceText Integer  -- Note [Literal source text] in "GHC.Types.Basic"
  | ITprimword   SourceText Integer  -- Note [Literal source text] in "GHC.Types.Basic"
823 824
  | ITprimfloat  FractionalLit
  | ITprimdouble FractionalLit
825

826
  -- Template Haskell extension tokens
827 828 829 830 831 832 833
  | ITopenExpQuote HasE IsUnicodeSyntax --  [| or [e|
  | ITopenPatQuote                      --  [p|
  | ITopenDecQuote                      --  [d|
  | ITopenTypQuote                      --  [t|
  | ITcloseQuote IsUnicodeSyntax        --  |]
  | ITopenTExpQuote HasE                --  [|| or [e||
  | ITcloseTExpQuote                    --  ||]
834 835
  | ITdollar                            --  prefix $
  | ITdollardollar                      --  prefix $$
836
  | ITtyQuote                           --  ''
837
  | ITquasiQuote (FastString,FastString,PsSpan)
838 839 840
    -- ITquasiQuote(quoter, quote, loc)
    -- represents a quasi-quote of the form
    -- [quoter| quote |]
841
  | ITqQuasiQuote (FastString,FastString,FastString,PsSpan)
842 843 844
    -- ITqQuasiQuote(Qual, quoter, quote, loc)
    -- represents a qualified quasi-quote of the form
    -- [Qual.quoter| quote |]
845 846 847 848

  -- Arrow notation extension
  | ITproc
  | ITrec
849 850 851 852 853 854 855 856 857
  | IToparenbar  IsUnicodeSyntax -- ^ @(|@
  | ITcparenbar  IsUnicodeSyntax -- ^ @|)@
  | ITlarrowtail IsUnicodeSyntax -- ^ @-<@
  | ITrarrowtail IsUnicodeSyntax -- ^ @>-@
  | ITLarrowtail IsUnicodeSyntax -- ^ @-<<@
  | ITRarrowtail IsUnicodeSyntax -- ^ @>>-@

  | ITunknown String             -- ^ Used when the lexer can't make sense of it
  | ITeof                        -- ^ end of file token
858 859

  -- Documentation annotations
860 861 862 863 864 865 866
  | ITdocCommentNext  String     -- ^ something beginning @-- |@
  | ITdocCommentPrev  String     -- ^ something beginning @-- ^@
  | ITdocCommentNamed String     -- ^ something beginning @-- $@
  | ITdocSection      Int String -- ^ a section heading
  | ITdocOptions      String     -- ^ doc options (prune, ignore-exports, etc)
  | ITlineComment     String     -- ^ comment starting by "--"
  | ITblockComment    String     -- ^ comment in {- -}
867

868
  deriving Show
869

Alan Zimmerman's avatar
Alan Zimmerman committed
870 871 872
instance Outputable Token where
  ppr x = text (show x)

Alan Zimmerman's avatar
Alan Zimmerman committed
873

874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904
{- Note [Minus tokens]
~~~~~~~~~~~~~~~~~~~~~~
A minus sign can be used in prefix form (-x) and infix form (a - b).

When LexicalNegation is on:
  * ITprefixminus  represents the prefix form
  * ITvarsym "-"   represents the infix form
  * ITminus        is not used

When LexicalNegation is off:
  * ITminus        represents all forms
  * ITprefixminus  is not used
  * ITvarsym "-"   is not used
-}

{- Note [Why not LexicalNegationBit]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
One might wonder why we define NoLexicalNegationBit instead of
LexicalNegationBit. The problem lies in the following line in reservedSymsFM:

    ,("-", ITminus, NormalSyntax, xbit NoLexicalNegationBit)

We want to generate ITminus only when LexicalNegation is off. How would one
do it if we had LexicalNegationBit? I (int-index) tried to use bitwise
complement:

    ,("-", ITminus, NormalSyntax, complement (xbit LexicalNegationBit))

This did not work, so I opted for NoLexicalNegationBit instead.
-}

905

906 907 908 909 910 911 912
-- the bitmap provided as the third component indicates whether the
-- corresponding extension keyword is valid under the extension options
-- provided to the compiler; if the extension corresponding to *any* of the
-- bits set in the bitmap is enabled, the keyword is valid (this setup
-- facilitates using a keyword in two different extensions that can be
-- activated independently)
--
913
reservedWordsFM :: UniqFM FastString (Token, ExtsBitmap)
914
reservedWordsFM = listToUFM $
Ian Lynagh's avatar
Ian Lynagh committed
915 916 917 918 919 920 921 922
    map (\(x, y, z) -> (mkFastString x, (y, z)))
        [( "_",              ITunderscore,    0 ),
         ( "as",             ITas,            0 ),
         ( "case",           ITcase,          0 ),
         ( "class",          ITclass,         0 ),
         ( "data",           ITdata,          0 ),
         ( "default",        ITdefault,       0 ),
         ( "deriving",       ITderiving,      0 ),
923
         ( "do",             ITdo Nothing,    0 ),
Ian Lynagh's avatar
Ian Lynagh committed
924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941
         ( "else",           ITelse,          0 ),
         ( "hiding",         IThiding,        0 ),
         ( "if",             ITif,            0 ),
         ( "import",         ITimport,        0 ),
         ( "in",             ITin,            0 ),
         ( "infix",          ITinfix,         0 ),
         ( "infixl",         ITinfixl,        0 ),
         ( "infixr",         ITinfixr,        0 ),
         ( "instance",       ITinstance,      0 ),
         ( "let",            ITlet,           0 ),
         ( "module",         ITmodule,        0 ),
         ( "newtype",        ITnewtype,       0 ),
         ( "of",             ITof,            0 ),
         ( "qualified",      ITqualified,     0 ),
         ( "then",           ITthen,          0 ),
         ( "type",           ITtype,          0 ),
         ( "where",          ITwhere,         0 ),

942
         ( "forall",         ITforall NormalSyntax, 0),
943
         ( "mdo",            ITmdo Nothing,   xbit RecursiveDoBit),
944 945 946
             -- See Note [Lexing type pseudo-keywords]
         ( "family",         ITfamily,        0 ),
         ( "role",           ITrole,          0 ),
947
         ( "pattern",        ITpattern,       xbit PatternSynonymsBit),
948
         ( "static",         ITstatic,        xbit StaticPointersBit ),
Ryan Scott's avatar
Ryan Scott committed
949 950
         ( "stock",          ITstock,         0 ),
         ( "anyclass",       ITanyclass,      0 ),
Ryan Scott's avatar
Ryan Scott committed
951
         ( "via",            ITvia,           0 ),
952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969
         ( "group",          ITgroup,         xbit TransformComprehensionsBit),
         ( "by",             ITby,            xbit TransformComprehensionsBit),
         ( "using",          ITusing,         xbit TransformComprehensionsBit),

         ( "foreign",        ITforeign,       xbit FfiBit),
         ( "export",         ITexport,        xbit FfiBit),
         ( "label",          ITlabel,         xbit FfiBit),
         ( "dynamic",        ITdynamic,       xbit FfiBit),
         ( "safe",           ITsafe,          xbit FfiBit .|.
                                              xbit SafeHaskellBit),
         ( "interruptible",  ITinterruptible, xbit InterruptibleFfiBit),
         ( "unsafe",         ITunsafe,        xbit FfiBit),
         ( "stdcall",        ITstdcallconv,   xbit FfiBit),
         ( "ccall",          ITccallconv,     xbit FfiBit),
         ( "capi",           ITcapiconv,      xbit CApiFfiBit),
         ( "prim",           ITprimcallconv,  xbit FfiBit),
         ( "javascript",     ITjavascriptcallconv, xbit FfiBit),

Edward Z. Yang's avatar
Edward Z. Yang committed
970 971 972 973
         ( "unit",           ITunit,          0 ),
         ( "dependency",     ITdependency,       0 ),
         ( "signature",      ITsignature,     0 ),

974 975 976
         ( "rec",            ITrec,           xbit ArrowsBit .|.
                                              xbit RecursiveDoBit),
         ( "proc",           ITproc,          xbit ArrowsBit)
977 978
     ]

979 980 981 982 983 984 985 986
{-----------------------------------
Note [Lexing type pseudo-keywords]
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

One might think that we wish to treat 'family' and 'role' as regular old
varids whenever -XTypeFamilies and -XRoleAnnotations are off, respectively.
But, there is no need to do so. These pseudo-keywords are not stolen syntax:
they are only used after the keyword 'type' at the top-level, where varids are
Sylvain Henry's avatar
Sylvain Henry committed
987
not allowed. Furthermore, checks further downstream (GHC.Tc.TyCl) ensure that
988 989 990 991 992 993 994
type families and role annotations are never declared without their extensions
on. In fact, by unconditionally lexing these pseudo-keywords as special, we
can get better error messages.

Also, note that these are included in the `varid` production in the parser --
a key detail to make all this work.
-------------------------------------}
995

996
reservedSymsFM :: UniqFM FastString (Token, IsUnicodeSyntax, ExtsBitmap)
997
reservedSymsFM = listToUFM $
998 999
    map (\ (x,w,y,z) -> (mkFastString x,(w,y,z)))
      [ ("..",  ITdotdot,                   NormalSyntax,  0 )
Ian Lynagh's avatar
Ian Lynagh committed
1000
        -- (:) is a reserved op, meaning only list cons
1001 1002 1003 1004 1005 1006 1007 1008
       ,(":",   ITcolon,                    NormalSyntax,  0 )
       ,("::",  ITdcolon NormalSyntax,      NormalSyntax,  0 )
       ,("=",   ITequal,                    NormalSyntax,  0 )
       ,("\\",  ITlam,                      NormalSyntax,  0 )
       ,("|",   ITvbar,                     NormalSyntax,  0 )
       ,("<-",  ITlarrow NormalSyntax,      NormalSyntax,  0 )
       ,("->",  ITrarrow NormalSyntax,      NormalSyntax,  0 )
       ,("=>",  ITdarrow NormalSyntax,      NormalSyntax,  0 )
1009
       ,("-",   ITminus,                    NormalSyntax,  xbit NoLexicalNegationBit)
1010 1011

       ,("*",   ITstar NormalSyntax,        NormalSyntax,  xbit StarIsTypeBit)
1012

Ian Lynagh's avatar
Ian Lynagh committed
1013
        -- For 'forall a . t'
1014 1015 1016 1017 1018 1019 1020