aclocal.m4 35.1 KB
Newer Older
1 2 3 4
# Extra autoconf macros for the Glasgow fptools
#
# To be a good autoconf citizen, names of local macros have prefixed with FP_ to
# ensure we don't clash with any pre-supplied autoconf ones.
sof's avatar
sof committed
5

6

7
# FP_EVAL_STDERR(COMMAND)
8
# -----------------------
9 10 11 12 13 14 15 16 17 18 19 20
# Eval COMMAND, save its stderr (without lines resulting from shell tracing)
# into the file conftest.err and the exit status in the variable fp_status.
AC_DEFUN([FP_EVAL_STDERR],
[{ (eval $1) 2>conftest.er1
  fp_status=$?
  grep -v '^ *+' conftest.er1 >conftest.err
  rm -f conftest.er1
  (exit $fp_status); }[]dnl
])# FP_EVAL_STDERR


# FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
21
# ---------------------------------------------------------------------
22 23 24 25 26 27 28 29
# Check to see whether the compiler for the current language supports a
# particular option.
#
# Implementation note: When given an unkown option, GCC issues an warning on
# stderr only, but returns an exit value of 0 nevertheless. Consequently we have
# to check stderr *and* the exit value.
#
# Used by ghc.
30
AC_DEFUN([FP_CHECK_FLAG],
31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51
[AC_LANG_COMPILER_REQUIRE()dnl
AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
             [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
             [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
[AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
fp_save_flags="$fp_Flags"
fp_Flags="$fp_Flags $1"
fp_Cache=no
if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
  test -s conftest.err || fp_Cache=yes
fi
fp_Flags="$fp_save_flags"
rm -f conftest.err conftest.$ac_ext])
AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
m4_popdef([fp_Cache])[]dnl
m4_popdef([fp_Flags])[]dnl
])# FP_CHECK_FLAG


52 53 54
# FP_PROG_CONTEXT_DIFF
# --------------------
# Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
55 56 57 58
#
# Note: NeXTStep thinks diff'ing a file against itself is "trouble".
#
# Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77
AC_DEFUN([FP_PROG_CONTEXT_DIFF],
[AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
[echo foo > conftest1
echo foo > conftest2
fp_cv_context_diff=no
for fp_var in '-C 1' '-c1'
do
  if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
    fp_cv_context_diff="diff $fp_var"
    break
  fi
done])
if test x"$fp_cv_context_diff" = xno; then
   AC_MSG_ERROR([cannot figure out how to do context diffs])
fi
AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
])# FP_PROG_CONTEXT_DIFF


78
# FP_DECL_ALTZONE
79
# ---------------
80
# Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
81
#
82
# Used by base package.
83
AC_DEFUN([FP_DECL_ALTZONE],
84 85 86
[AC_REQUIRE([AC_HEADER_TIME])dnl
AC_CHECK_HEADERS([sys/time.h])
AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
sof's avatar
sof committed
87 88 89 90 91 92 93 94
# include <sys/time.h>
# include <time.h>
#else
# if HAVE_SYS_TIME_H
#  include <sys/time.h>
# else
#  include <time.h>
# endif
95
#endif])
96
])# FP_DECL_ALTZONE
97

sof's avatar
sof committed
98

99
# FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
100
# --------------------------------------------------------
101 102 103
# Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
# compilation. Execute IF-FAILS when unable to determine the value. Works for
# cross-compilation, too.
104 105 106 107
#
# Implementation note: We are lazy and use an internal autoconf macro, but it
# is supported in autoconf versions 2.50 up to the actual 2.57, so there is
# little risk.
108 109 110 111 112 113 114 115 116 117 118
AC_DEFUN([FP_COMPUTE_INT],
[_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
])# FP_COMPUTE_INT


# FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
# ------------------------------------------------------------------
# A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
# given type. Defines ALIGNMENT_TYPE.
AC_DEFUN([FP_CHECK_ALIGNMENT],
[AS_LITERAL_IF([$1], [],
119
               [AC_FATAL([$0: requires literal arguments])])[]dnl
120 121 122
AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
AC_CACHE_CHECK([alignment of $1], [fp_Cache],
123 124
[if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
  FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
125
                 [fp_Cache],
126
                 [AC_INCLUDES_DEFAULT([$3])],
127 128
                 [AC_MSG_ERROR([cannot compute alignment ($1)
See `config.log' for more details.], [77])])
129
else
130 131 132 133
  fp_Cache=0
fi])[]dnl
AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
m4_popdef([fp_Cache])[]dnl
134 135 136
])# FP_CHECK_ALIGNMENT


137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155
# FP_LEADING_UNDERSCORE
# ---------------------
# Test for determining whether symbol names have a leading underscore. We assume
# that they _haven't_ if anything goes wrong. Sets the output variable
# LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
#
# Some nlist implementations seem to try to be compatible by ignoring a leading
# underscore sometimes (eg. FreeBSD). We therefore have to work around this by
# checking for *no* leading underscore first. Sigh.  --SDM
#
# Similarly on OpenBSD, but this test doesn't help. -- dons
AC_DEFUN([FP_LEADING_UNDERSCORE],
[AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
# Hack!: nlist() under Digital UNIX insist on there being an _,
# but symbol table listings shows none. What is going on here?!?
#
# Another hack: cygwin doesn't come with nlist.h , so we hardwire
# the underscoredness of that "platform"
156
case $HostPlatform in
dons's avatar
dons committed
157
*openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
158 159 160 161 162 163 164
  case $build in
    i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
    *) fptools_cv_leading_underscore=no ;;
  esac ;;
alpha-dec-osf*) fptools_cv_leading_underscore=no;;
*cygwin32) fptools_cv_leading_underscore=yes;;
*mingw32) fptools_cv_leading_underscore=yes;;
165
*) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
sof's avatar
sof committed
166
#include <nlist.h>
167 168
struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
sof's avatar
sof committed
169 170
#endif

171 172 173
int main(argc, argv)
int argc;
char **argv;
sof's avatar
sof committed
174 175
{
#ifdef HAVE_NLIST_H
176 177 178
    if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
        exit(1);
    if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
179
        exit(0);
sof's avatar
sof committed
180 181
#endif
    exit(1);
182
}]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
183
;;
184 185 186 187 188
esac]);
AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
if test x"$fptools_cv_leading_underscore" = xyes; then
   AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
fi])# FP_LEADING_UNDERSCORE
sof's avatar
sof committed
189

190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217

# FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
# ----------------------------------------------------------------------------------
# Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
# to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
AC_DEFUN([FP_COMPARE_VERSIONS],
[fp_version1=$1; fp_version2=$3
fp_save_IFS=$IFS; IFS='.'
while test x"$fp_version1" != x || test x"$fp_version2" != x
do

  set dummy $fp_version1; shift
  fp_num1=""
  test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
  test x"$fp_num1" = x && fp_num1="0"
  fp_version1="[$]*"

  set dummy $fp_version2; shift
  fp_num2=""
  test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
  test x"$fp_num2" = x && fp_num2="0"
  fp_version2="[$]*"

  test "$fp_num1" = "$fp_num2" || break;
done
IFS=$fp_save_IFS
AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
])# FP_COMPARE_VERSIONS
218 219


reid's avatar
reid committed
220
dnl
221
dnl Check for GreenCard and version.
reid's avatar
reid committed
222
dnl
223
AC_DEFUN([FPTOOLS_GREENCARD],
reid's avatar
reid committed
224
[
225
AC_PATH_PROG(GreenCardCmd,greencard)
reid's avatar
reid committed
226
AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
reid's avatar
reid committed
227
changequote(, )dnl
228 229
[if test x"$GreenCardCmd" != x; then
   fptools_cv_greencard_version="`$GreenCardCmd --version |
reid's avatar
reid committed
230
			  grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
reid's avatar
reid committed
231 232 233 234 235
else
   fptools_cv_greencard_version=""
fi
changequote([, ])dnl
])
236 237
FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
  [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
238 239
GreenCardVersion=$fptools_cv_greencard_version
AC_SUBST(GreenCardVersion)
reid's avatar
reid committed
240 241
])

sof's avatar
sof committed
242
dnl
243
dnl Check for Happy and version.  If we're building GHC, then we need
244
dnl at least Happy version 1.14.  If there's no installed Happy, we look
245 246
dnl for a happy source tree and point the build system at that instead.
dnl
247
AC_DEFUN([FPTOOLS_HAPPY],
248 249 250
[
if test -d $srcdir/happy; then
   SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
251 252
else
   SrcTreeHappyCmd=""
253
fi
sof's avatar
sof committed
254
if test x"$UseSrcTreeHappy" = xYES; then
255 256 257 258 259
  if test x"$SrcTreeHappyCmd" != x; then
     HappyCmd=$SrcTreeHappyCmd
  else
     AC_MSG_ERROR([--enable-src-tree-happy given, but happy not found in source tree])
  fi
sof's avatar
sof committed
260 261 262
else
  AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
fi
sof's avatar
sof committed
263
AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
sof's avatar
sof committed
264
changequote(, )dnl
265
[if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
sof's avatar
sof committed
266
   fptools_cv_happy_version=`grep '^ProjectVersion[ 	]*=' $srcdir/happy/mk/version.mk | sed 's/[^0-9]*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
267 268 269
elif test x"$HappyCmd" != x; then
   fptools_cv_happy_version="`$HappyCmd -v |
			  grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
sof's avatar
sof committed
270
else
sof's avatar
sof committed
271
   fptools_cv_happy_version="";
sof's avatar
sof committed
272
fi;
273
changequote([, ])dnl
274
])
275
if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
276 277
  FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.15],
  [AC_MSG_ERROR([Happy version 1.15 or later is required to compile GHC.])])[]dnl
278
fi
279
HappyVersion=$fptools_cv_happy_version;
sof's avatar
sof committed
280 281 282
AC_SUBST(HappyVersion)
])

283 284 285 286
dnl
dnl Check for Haddock and version.  If there's no installed Haddock, we look
dnl for a haddock source tree and point the build system at that instead.
dnl
287
AC_DEFUN([FPTOOLS_HADDOCK],
288 289 290
[
if test -d $srcdir/haddock; then
   SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
291 292
else
   SrcTreeHaddockCmd=""
293 294
fi
if test x"$UseSrcTreeHaddock" = xYES; then
295 296 297 298 299
  if test x"$SrcTreeHaddockCmd" != x; then
     HaddockCmd=$SrcTreeHaddockCmd
  else
     AC_MSG_ERROR([--enable-src-tree-haddock given, but haddock not found in source tree])
  fi
300 301 302 303 304 305 306 307 308
else
  AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
fi
dnl Darn, I forgot to make Haddock print out its version number when
dnl invoked with -v.  We could try generating some HTML and grepping
dnl through that to find the version number, but I think we'll make
dnl do without it for now.
])

309 310 311 312 313
dnl
dnl Check for Alex and version.  If we're building GHC, then we need
dnl at least Alex version 2.0.  If there's no installed Alex, we look
dnl for a alex source tree and point the build system at that instead.
dnl
314
AC_DEFUN([FPTOOLS_ALEX],
315 316 317
[
if test -d $srcdir/alex; then
   SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
318 319
else
   SrcTreeAlexCmd=""
320 321
fi
if test x"$UseSrcTreeAlex" = xYES; then
322 323 324 325 326
  if test x"$SrcTreeAlexCmd" != x; then
     AlexCmd=$SrcTreeAlexCmd
  else
     AC_MSG_ERROR([--enable-src-tree-alex given, but alex not found in source tree])
  fi
327 328 329 330 331 332
else
  AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
fi
AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
changequote(, )dnl
[if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
sof's avatar
sof committed
333
   fptools_cv_alex_version=`grep '^ProjectVersion[ 	]*=' $srcdir/alex/mk/version.mk | sed 's/[^0-9]*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
334 335
elif test x"$AlexCmd" != x; then
   fptools_cv_alex_version="`$AlexCmd -v |
336
			  grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
337 338 339 340 341
else
   fptools_cv_alex_version="";
fi;
changequote([, ])dnl
])
342 343 344 345
if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
  FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
  [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
fi
346 347 348 349
AlexVersion=$fptools_cv_alex_version;
AC_SUBST(AlexVersion)
])

sof's avatar
sof committed
350

351 352 353 354 355 356 357 358 359 360 361 362 363 364 365
# FP_PROG_LD
# ----------
# Sets the output variable LdCmd to the (non-Cygwin version of the) full path
# of ld. Exits if no ld can be found
AC_DEFUN([FP_PROG_LD],
[AC_PATH_PROG([fp_prog_ld_raw], [ld])
if test -z "$fp_prog_ld_raw"; then
  AC_MSG_ERROR([cannot find ld in your PATH, no idea how to link])
fi
LdCmd=$fp_prog_ld_raw
case $HostPlatform in
  *mingw32) if test x${OSTYPE} != xmsys; then
 	      LdCmd="`cygpath -w ${fp_prog_ld_raw} | sed -e 's@\\\\@/@g'`"
              AC_MSG_NOTICE([normalized ld command to $LdCmd])
            fi
sof's avatar
sof committed
366 367 368 369 370 371
	    # Insist on >= ld-2.15.x, since earlier versions doesn't handle
	    # the generation of relocatable object files with large amounts
	    # of relocations correctly. (cf. HSbase.o splittage-hack)
	    fp_prog_ld_version=`${LdCmd} --version | sed -n '/GNU ld/p' | tr -cd 0-9 | cut -b1-3`
	    FP_COMPARE_VERSIONS([$fp_prog_ld_version],[-lt],[214],
                                [AC_MSG_ERROR([GNU ld version later than 2.14 required to compile GHC on Windows.])])[]dnl
372 373 374 375 376 377 378 379 380 381 382 383 384 385
            ;;
esac
AC_SUBST([LdCmd])
])# FP_PROG_LD


# FP_PROG_LD_X
# ------------
# Sets the output variable LdXFlag to -x if ld supports this flag, otherwise the
# variable's value is empty.
AC_DEFUN([FP_PROG_LD_X],
[AC_REQUIRE([FP_PROG_LD])
AC_CACHE_CHECK([whether ld understands -x], [fp_cv_ld_x],
[echo 'foo() {}' > conftest.c
386
${CC-cc} -c conftest.c
387
if ${LdCmd} -r -x -o conftest2.o conftest.o > /dev/null 2>&1; then
388
   fp_cv_ld_x=yes
389
else
390
   fp_cv_ld_x=no
391
fi
392 393 394
rm -rf conftest*])
if test "$fp_cv_ld_x" = yes; then
  LdXFlag=-x
395
else
396
  LdXFlag=
397
fi
398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415
AC_SUBST([LdXFlag])
])# FP_PROG_LD_X


# FP_PROG_LD_IS_GNU
# -----------------
# Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
# GNU ld or not.
AC_DEFUN([FP_PROG_LD_IS_GNU],
[AC_REQUIRE([FP_PROG_LD])
AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
[if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
  fp_cv_gnu_ld=yes
else
  fp_cv_gnu_ld=no
fi])
AC_SUBST([LdIsGNULd], [`echo $fp_cv_gnu_ld | sed 'y/yesno/YESNO/'`])
])# FP_PROG_LD_IS_GNU
416

sof's avatar
sof committed
417

418 419 420 421 422 423 424 425
# FP_PROG_AR
# ----------
# Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
# version of it. Exits if no ar can be found
AC_DEFUN([FP_PROG_AR],
[AC_PATH_PROG([fp_prog_ar_raw], [ar])
if test -z "$fp_prog_ar_raw"; then
  AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
sof's avatar
sof committed
426
fi
427
fp_prog_ar=$fp_prog_ar_raw
sof's avatar
sof committed
428
case $HostPlatform in
429 430 431 432 433
  *mingw32) if test x${OSTYPE} != xmsys; then
 	      fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
              AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
            fi
            ;;
sof's avatar
sof committed
434
esac
435 436 437 438 439 440 441 442 443
])# FP_PROG_AR


# FP_PROG_AR_IS_GNU
# -----------------
# Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
AC_DEFUN([FP_PROG_AR_IS_GNU],
[AC_REQUIRE([FP_PROG_AR])
AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
444
[if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492
  fp_cv_prog_ar_is_gnu=yes
else
  fp_cv_prog_ar_is_gnu=no
fi])
fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
])# FP_PROG_AR_IS_GNU


# FP_PROG_AR_ARGS
# ---------------
# Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
# to a non-Cygwin invocation of ar including these arguments.
AC_DEFUN([FP_PROG_AR_ARGS],
[AC_REQUIRE([FP_PROG_AR_IS_GNU])
AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
[
# GNU ar needs special treatment: it appears to have problems with
# object files with the same name if you use the 's' modifier, but
# simple 'ar q' works fine, and doesn't need a separate ranlib.
if test $fp_prog_ar_is_gnu = yes; then
  fp_cv_prog_ar_args="q"
else
  touch conftest.dummy
  for fp_var in clqsZ clqs cqs clq cq ; do
     rm -f conftest.a
     if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
        fp_cv_prog_ar_args=$fp_var
        break
     fi
  done
  rm -f conftest*
  if test -z "$fp_cv_prog_ar_args"; then
    AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
  fi
fi])
fp_prog_ar_args=$fp_cv_prog_ar_args
AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])

])# FP_PROG_AR_ARGS


# FP_PROG_AR_NEEDS_RANLIB
# -----------------------
# Sets the output variable RANLIB to "ranlib" if it is needed and found,
# to ":" otherwise.
AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
[AC_REQUIRE([FP_PROG_AR_IS_GNU])
AC_REQUIRE([FP_PROG_AR_ARGS])
493
AC_REQUIRE([AC_PROG_CC])
494 495 496
AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
[if test $fp_prog_ar_is_gnu = yes; then
  fp_cv_prog_ar_needs_ranlib=no
497
elif echo $TargetPlatform | grep "^.*-apple-darwin$"  > /dev/null 2> /dev/null; then
498 499 500
  # It's quite tedious to check for Apple's crazy timestamps in .a files,
  # so we hardcode it.
  fp_cv_prog_ar_needs_ranlib=yes
501 502 503 504 505 506 507
elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
  fp_cv_prog_ar_needs_ranlib=no
else
  fp_cv_prog_ar_needs_ranlib=yes
fi])
if test $fp_cv_prog_ar_needs_ranlib = yes; then
   AC_PROG_RANLIB
ken's avatar
ken committed
508
else
509 510
  RANLIB=":"
  AC_SUBST([RANLIB])
ken's avatar
ken committed
511
fi
512 513 514 515 516 517 518 519 520 521 522 523 524 525 526
])# FP_PROG_AR_NEEDS_RANLIB


# FP_PROG_AR_SUPPORTS_INPUT
# -------------------------
# Sets the output variable ArSupportsInput to "-input" or "", depending on
# whether ar supports -input flag is supported or not.
AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
[AC_REQUIRE([FP_PROG_AR_IS_GNU])
AC_REQUIRE([FP_PROG_AR_ARGS])
AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
[fp_cv_prog_ar_supports_input=no
if test $fp_prog_ar_is_gnu = no; then
  rm -f conftest*
  touch conftest.lst
527 528
  if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
    test -s conftest.err || fp_cv_prog_ar_supports_input=yes
529 530 531 532 533
  fi
  rm -f conftest*
fi])
if test $fp_cv_prog_ar_supports_input = yes; then
    ArSupportsInput="-input"
sof's avatar
sof committed
534
else
535
    ArSupportsInput=""
sof's avatar
sof committed
536
fi
537 538 539
AC_SUBST([ArSupportsInput])
])# FP_PROG_AR_SUPPORTS_INPUT

sof's avatar
sof committed
540

sof's avatar
sof committed
541
dnl
sof's avatar
sof committed
542
dnl AC_SHEBANG_PERL - can we she-bang perl?
sof's avatar
sof committed
543
dnl
544
AC_DEFUN([FPTOOLS_SHEBANG_PERL],
sof's avatar
sof committed
545
[AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
sof's avatar
sof committed
546 547 548 549 550 551
[echo "#!$PerlCmd"'
exit $1;
' > conftest
chmod u+x conftest
(SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
if test $? -ne 69; then
sof's avatar
sof committed
552
   fptools_cv_shebang_perl=yes
sof's avatar
sof committed
553
else
sof's avatar
sof committed
554
   fptools_cv_shebang_perl=no
sof's avatar
sof committed
555 556 557 558
fi
rm -f conftest
])])

559 560 561 562 563 564 565

# FP_HAVE_GCC
# -----------
# Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
# output variables HaveGcc and GccVersion.
AC_DEFUN([FP_HAVE_GCC],
[AC_REQUIRE([AC_PROG_CC])
566 567
if test -z "$GCC"; then
   fp_have_gcc=NO
sof's avatar
sof committed
568
else
569 570 571 572 573 574 575
   fp_have_gcc=YES
fi
if test "$fp_have_gcc" = "NO" -a -d $srcdir/ghc; then
  AC_MSG_ERROR([gcc is required])
fi
AC_CACHE_CHECK([version of gcc], [fp_gcc_version],
[if test "$fp_have_gcc" = "YES"; then
576
   fp_gcc_version="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/g'`"
577 578 579 580 581 582 583 584
   FP_COMPARE_VERSIONS([$fp_gcc_version], [-lt], [2.0],
     [AC_MSG_ERROR([Need at least gcc version 2.0 (3.4+ recommended)])])
 else
   fp_gcc_version="not-installed"
 fi
])
AC_SUBST([HaveGcc], [$fp_have_gcc])
AC_SUBST([GccVersion], [$fp_gcc_version])
585
])# FP_HAVE_GCC
586

587 588 589 590 591 592 593 594 595 596 597 598 599
AC_DEFUN([FP_MINGW_GCC],
[
  case $HostOS_CPP in
    mingw*)  AC_MSG_CHECKING([whether $CC is a mingw gcc])
	     if $CC -v 2>&1 | grep mingw >/dev/null; then
		AC_MSG_RESULT([yes])
	     else
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([Please use --with-gcc to specify a mingw gcc])
	     fi;;
    *) ;;	
  esac
])
600

sof's avatar
sof committed
601 602 603
dnl Small feature test for perl version. Assumes PerlCmd
dnl contains path to perl binary
dnl
604
AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
sof's avatar
sof committed
605
[$PerlCmd -v >conftest.out 2>&1
dons's avatar
dons committed
606 607 608 609 610 611 612 613 614
   if grep "v5.6" conftest.out >/dev/null 2>&1; then
      :
   else
      if grep "v5.8" conftest.out >/dev/null 2>&1; then
         :
      else
         if grep "version 6" conftest.out >/dev/null 2>&1; then
            :
         else
615 616
            AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
         fi
dons's avatar
dons committed
617 618
      fi
   fi
sof's avatar
sof committed
619 620
rm -fr conftest*
])
reid's avatar
reid committed
621

622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642

# FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
#               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
# -----------------------------------------------------
# HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
# of PROG-TO-CHECK-FOR when found.
AC_DEFUN([FP_CHECK_PROG],
[AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
)# FP_CHECK_PROC


# FP_PROG_FIND
# ------------
# Find a non-WinDoze version of the "find" utility.
AC_DEFUN([FP_PROG_FIND],
[AC_PATH_PROG([fp_prog_find], [find])
echo foo > conftest.txt
$fp_prog_find conftest.txt -print > conftest.out 2>&1
if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
  # OK, looks like a real "find".
  FindCmd="$fp_prog_find"
sof's avatar
sof committed
643
else
644 645 646
  # Found a poor WinDoze version of "find", ignore it.
  AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
  FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
sof's avatar
sof committed
647
fi
648 649 650 651
rm -f conftest.txt conftest.out
AC_SUBST([FindCmd])[]dnl
])# FP_PROG_FIND

sof's avatar
sof committed
652

sof's avatar
sof committed
653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671
# FP_PROG_SORT
# ------------
# Find a Unix-like sort
AC_DEFUN([FP_PROG_SORT],
[AC_PATH_PROG([fp_prog_sort], [sort])
echo conwip > conftest.txt
$fp_prog_sort -f conftest.txt > conftest.out 2>&1
if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
  # The goods
  SortCmd="$fp_prog_sort"
else
  # Summink else..pick next one.
  AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
  FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
fi
rm -f conftest.txt conftest.out
AC_SUBST([SortCmd])[]dnl
])# FP_PROG_SORT

672 673 674 675 676 677 678
dnl
dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
dnl values of the second argument to the result of running
dnl the commands given by the third. It does not cache its
dnl result, so it is suitable for checks which should be
dnl run every time.
dnl
679
AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
680 681 682 683 684
[AC_MSG_CHECKING([$1])
 $3
 AC_MSG_RESULT([$][$2])
])

685 686 687
dnl
dnl FPTOOLS_GHC_VERSION(version)
dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
688
dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
689 690
dnl
dnl Test for version of installed ghc.  Uses $GHC.
691
dnl [original version pinched from c2hs]
692
dnl
693
AC_DEFUN([FPTOOLS_GHC_VERSION],
694
[FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
695
["${WithGhc-ghc}" --version > conftestghc 2>&1
696
  cat conftestghc >&AS_MESSAGE_LOG_FD
697 698
#Useless Use Of cat award...
  fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
699
  rm -fr conftest*
700
  if test "[$]fptools_version_of_ghc" = ""
701
  then
702 703 704 705 706 707 708
    fptools_version_of_ghc='unknown'
  fi
fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
#
if test "[$]fptools_version_of_ghc[_pl]" = ""
709
then
710 711
  fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
  fptools_version_of_ghc[_pl]="0"
712
else
713
  fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
714
fi
715
#
716
ifelse($#, [1], [dnl
717
[$1]="[$]fptools_version_of_ghc[_all]"
718
], $#, [2], [dnl
719 720
[$1]="[$]fptools_version_of_ghc[_major]"
[$2]="[$]fptools_version_of_ghc[_minor]"
721
], $#, [3], [dnl
722 723 724
[$1]="[$]fptools_version_of_ghc[_major]"
[$2]="[$]fptools_version_of_ghc[_minor]"
[$3]="[$]fptools_version_of_ghc[_pl]"
725
], $#, [4], [dnl
726 727 728 729 730 731
[$1]="[$]fptools_version_of_ghc[_all]"
[$2]="[$]fptools_version_of_ghc[_major]"
[$3]="[$]fptools_version_of_ghc[_minor]"
[$4]="[$]fptools_version_of_ghc[_pl]"
])
])
732
])dnl
733 734


735 736 737
dnl ** Map an arithmetic C type to a Haskell type.
dnl    Based on autconf's AC_CHECK_SIZEOF.

738
dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
739
AC_DEFUN([FPTOOLS_CHECK_HTYPE],
740 741 742 743 744
[changequote(<<, >>)dnl
dnl The name to #define.
define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
dnl The cache variable name.
define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
sof's avatar
sof committed
745
define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
746 747 748
changequote([, ])dnl
AC_MSG_CHECKING(Haskell type for $1)
AC_CACHE_VAL(AC_CV_NAME,
749 750 751
[AC_CV_NAME_supported=yes
fp_check_htype_save_cppflags="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
752
AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
753
#include <stddef.h>
sof's avatar
sof committed
754

755
#if HAVE_SYS_TYPES_H
sof's avatar
sof committed
756 757 758
# include <sys/types.h>
#endif

759
#if HAVE_UNISTD_H
sof's avatar
sof committed
760 761 762
# include <unistd.h>
#endif

763
#if HAVE_SYS_STAT_H
sof's avatar
sof committed
764 765 766
# include <sys/stat.h>
#endif

767
#if HAVE_FCNTL_H
sof's avatar
sof committed
768 769 770
# include <fcntl.h>
#endif

771
#if HAVE_SIGNAL_H
sof's avatar
sof committed
772
# include <signal.h>
773
#endif
sof's avatar
sof committed
774

775
#if HAVE_TIME_H
sof's avatar
sof committed
776 777 778
# include <time.h>
#endif

779
#if HAVE_TERMIOS_H
sof's avatar
sof committed
780 781 782
# include <termios.h>
#endif

783
#if HAVE_STRING_H
sof's avatar
sof committed
784
# include <string.h>
785
#endif
sof's avatar
sof committed
786

787
#if HAVE_CTYPE_H
sof's avatar
sof committed
788 789 790
# include <ctype.h>
#endif

791
#if defined(HAVE_GL_GL_H)
sof's avatar
sof committed
792
# include <GL/gl.h>
793 794
#elif defined(HAVE_OPENGL_GL_H)
# include <OpenGL/gl.h>
795
#endif
796

797 798 799 800 801 802
#if defined(HAVE_AL_AL_H)
# include <AL/al.h>
#elif defined(HAVE_OPENAL_AL_H)
# include <OpenAL/al.h>
#endif

803 804 805 806
#if defined(HAVE_AL_ALC_H)
# include <AL/alc.h>
#elif defined(HAVE_OPENAL_ALC_H)
# include <OpenAL/alc.h>
807 808
#endif

809
#if HAVE_SYS_RESOURCE_H
810 811 812
# include <sys/resource.h>
#endif

813 814 815
typedef $1 testing;

main() {
sof's avatar
sof committed
816
  FILE *f=fopen("conftestval", "w");
817 818 819 820 821 822 823 824 825 826 827 828
  if (!f) exit(1);
  if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
    fprintf(f, "%s%d\n",
           ((testing)(-1) < (testing)0) ? "Int" : "Word",
           sizeof(testing)*8);
  } else {
    fprintf(f,"%s\n",
           (sizeof(testing) >  sizeof(double)) ? "LDouble" :
           (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
  }
  fclose(f);
  exit(0);
829 830
}]])],[AC_CV_NAME=`cat conftestval`],
[ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
sof's avatar
sof committed
831 832
[ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])
CPPFLAGS="$fp_check_htype_save_cppflags"]) dnl
sof's avatar
sof committed
833
if test "$AC_CV_NAME_supported" = yes; then
sof's avatar
sof committed
834
  AC_MSG_RESULT($AC_CV_NAME)
sof's avatar
sof committed
835
  AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
sof's avatar
sof committed
836 837 838
else
  AC_MSG_RESULT([not supported])
fi
839 840
undefine([AC_TYPE_NAME])dnl
undefine([AC_CV_NAME])dnl
sof's avatar
sof committed
841
undefine([AC_CV_NAME_supported])dnl
842 843
])

844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862

# FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
# ---------------------------------------------------------------------------------
# A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
# additional flexibility of specifying the PROLOGUE and BODY.
AC_DEFUN([FP_CHECK_FUNC],
[AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
AC_CACHE_CHECK([for $1], fp_func,
[AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
                [AS_VAR_SET(fp_func, yes)],
                [AS_VAR_SET(fp_func, no)])])
AS_IF([test AS_VAR_GET(fp_func) = yes],
      [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
                [Define to 1 if you have the `]$1[' function.]) $4],
      [$5])dnl
AS_VAR_POPDEF([fp_func])dnl
])# FP_CHECK_FUNC


863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958
# FP_GEN_DOCBOOK_XML
# ------------------
# Generates a DocBook XML V4.2 document in conftest.xml.
AC_DEFUN([FP_GEN_DOCBOOK_XML],
[rm -f conftest.xml
cat > conftest.xml << EOF
<?xml version="1.0" encoding="iso-8859-1"?>
<!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
   "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
<book id="test">
  <title>A DocBook Test Document</title>
  <chapter id="id-one">
    <title>A Chapter Title</title>
    <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
  </chapter>
  <chapter id="id-two">
    <title>Another Chapter Title</title>
    <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
  </chapter>
</book>
EOF
]) # FP_GEN_DOCBOOK_XML


# FP_PROG_XSLTPROC
# ----------------
# Sets the output variable XsltprocCmd to the full path of the XSLT processor
# xsltproc. XsltprocCmd is empty if xsltproc could not be found.
AC_DEFUN([FP_PROG_XSLTPROC],
[AC_PATH_PROG([XsltprocCmd], [xsltproc])
if test -z "$XsltprocCmd"; then
  AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
fi
])# FP_PROG_XSLTPROC


# FP_DIR_DOCBOOK_XSL(XSL-DIRS)
# ----------------------------
# Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
# output variable DIR_DOCBOOK_XSL will contain the first usable directory or
# will be empty if none could be found.
AC_DEFUN([FP_DIR_DOCBOOK_XSL],
[AC_REQUIRE([FP_PROG_XSLTPROC])dnl
if test -n "$XsltprocCmd"; then
  AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
  [FP_GEN_DOCBOOK_XML
  fp_cv_dir_docbook_xsl=no
  for fp_var in $1; do
     if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
        fp_cv_dir_docbook_xsl=$fp_var
        break
     fi
  done
  rm -rf conftest*])
fi
if test x"$fp_cv_dir_docbook_xsl" = xno; then
  AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
  DIR_DOCBOOK_XSL=
else
  DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
fi
AC_SUBST([DIR_DOCBOOK_XSL])
])# FP_DIR_DOCBOOK_XSL


# FP_PROG_XMLLINT
# ----------------
# Sets the output variable XmllintCmd to the full path of the XSLT processor
# xmllint. XmllintCmd is empty if xmllint could not be found.
AC_DEFUN([FP_PROG_XMLLINT],
[AC_PATH_PROG([XmllintCmd], [xmllint])
if test -z "$XmllintCmd"; then
  AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
fi
])# FP_PROG_XMLLINT


# FP_CHECK_DOCBOOK_DTD
# --------------------
AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
[AC_REQUIRE([FP_PROG_XMLLINT])dnl
if test -n "$XmllintCmd"; then
  AC_MSG_CHECKING([for DocBook DTD])
  FP_GEN_DOCBOOK_XML
  if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
    AC_MSG_RESULT([ok])
  else
    AC_MSG_RESULT([failed])
    AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
    AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
  fi
  rm -rf conftest*
fi
])# FP_CHECK_DOCBOOK_DTD


959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011
# FP_GEN_FO
# ------------------
# Generates a formatting objects document in conftest.fo.
AC_DEFUN([FP_GEN_FO],
[rm -f conftest.fo
cat > conftest.fo << EOF
<?xml version="1.0"?>
<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <fo:layout-master-set>
    <fo:simple-page-master master-name="blank">
      <fo:region-body/>
    </fo:simple-page-master>
  </fo:layout-master-set>
  <fo:page-sequence master-reference="blank">
    <fo:flow flow-name="xsl-region-body">
      <fo:block>
        Test!
      </fo:block>
    </fo:flow>
  </fo:page-sequence>
</fo:root>
EOF
]) # FP_GEN_FO


# FP_PROG_FOP
# -----------
# Set the output variable 'FopCmd' to the first working 'fop' in the current
# 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
# /usr/share/fop/fop.sh in that case (or no 'fop'), too.
AC_DEFUN([FP_PROG_FOP],
[AC_PATH_PROGS([FopCmd1], [fop])
if test -n "$FopCmd1"; then
  AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
    [FP_GEN_FO
    if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
      fp_cv_fop_usability=yes
    else
      fp_cv_fop_usability=no
    fi
    rm -rf conftest*])
  if test x"$fp_cv_fop_usability" = xyes; then
     FopCmd=$FopCmd1
  fi
fi
if test -z "$FopCmd"; then
  AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
  FopCmd=$FopCmd2
fi
AC_SUBST([FopCmd])
])# FP_PROG_FOP


1012 1013 1014
# FP_PROG_FO_PROCESSOR
# --------------------
# Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
1015 1016
# try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
# PdfxmltexCmd.
1017
AC_DEFUN([FP_PROG_FO_PROCESSOR],
1018
[AC_REQUIRE([FP_PROG_FOP])
1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038
AC_PATH_PROG([XmltexCmd], [xmltex])
AC_PATH_PROG([DvipsCmd], [dvips])
if test -z "$FopCmd"; then
  if test -z "$XmltexCmd"; then
    AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
  else
    if test -z "$DvipsCmd"; then
      AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
    fi
  fi
  AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
  if test -z "$PdfxmltexCmd"; then
    AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
  fi
elif test -z "$XmltexCmd"; then
  AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
fi
])# FP_PROG_FO_PROCESSOR


1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057
# FP_PROG_GHC_PKG
# ----------------
# Try to find a ghc-pkg matching the ghc mentioned in the environment variable
# WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
# find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
AC_DEFUN([FP_PROG_GHC_PKG],
[AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
[fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
  fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
else
  fp_cv_matching_ghc_pkg=no
fi])
if test x"$fp_cv_matching_ghc_pkg" = xno; then
  AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
else
  GhcPkgCmd=$fp_cv_matching_ghc_pkg
fi])# FP_PROG_GHC_PKG

1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116

# FP_GHC_HAS_READLINE
# -------------------
AC_DEFUN([FP_GHC_HAS_READLINE],
[AC_REQUIRE([FP_PROG_GHC_PKG])
AC_CACHE_CHECK([whether ghc has readline package], [fp_cv_ghc_has_readline],
[if "${GhcPkgCmd-ghc-pkg}" --show-package readline >/dev/null 2>&1; then
  fp_cv_ghc_has_readline=yes
else
  fp_cv_ghc_has_readline=no
 fi])
AC_SUBST([GhcHasReadline], [`echo $fp_cv_ghc_has_readline | sed 'y/yesno/YESNO/'`])
])# FP_GHC_HAS_READLINE


# FP_GCC_NEEDS_NO_OMIT_LFPTR
# --------------------------
# Some OSs (Mandrake Linux, in particular) configure GCC with
# -momit-leaf-frame-pointer on by default. If this is the case, we need to turn
# it off for mangling to work. The test is currently a bit crude, using only the
# version number of gcc. Defines HAVE_GCC_MNO_OMIT_LFPTR.
AC_DEFUN([FP_GCC_NEEDS_NO_OMIT_LFPTR],
[AC_REQUIRE([FP_HAVE_GCC])
AC_CACHE_CHECK([whether gcc needs -mno-omit-leaf-frame-pointer], [fp_cv_gcc_needs_no_omit_lfptr],
[FP_COMPARE_VERSIONS([$gcc_version_str], [-ge], [3.2],
  [fp_cv_gcc_needs_no_omit_lfptr=yes],
  [fp_cv_gcc_needs_no_omit_lfptr=no])])
if test "$fp_cv_gcc_needs_no_omit_lfptr" = "yes"; then
   AC_DEFINE([HAVE_GCC_MNO_OMIT_LFPTR], [1], [Define to 1 if gcc supports -mno-omit-leaf-frame-pointer.])
fi])# FP_GCC_NEEDS_NO_OMIT_LFPTR


# FP_SETUP_PROJECT_VERSION
# ---------------------
AC_DEFUN([FP_SETUP_PROJECT_VERSION],
[# Some renamings
AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])

# Split PACKAGE_VERSION into (possibly empty) parts
VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`

# Calculate project version as an integer, using 2 digits for minor version
case $VERSION_MINOR in
  ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
  ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
  *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
esac
AC_SUBST([ProjectVersionInt])

# The project patchlevel is zero unless stated otherwise
test -z "$ProjectPatchLevel" && ProjectPatchLevel=0

# Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`

AC_SUBST([ProjectPatchLevel])
1117
])# FP_SETUP_PROJECT_VERSION
1118

reid's avatar
reid committed
1119
# LocalWords:  fi