Lexer.x 80.3 KB
Newer Older
1
-----------------------------------------------------------------------------
2
-- (c) The University of Glasgow, 2006
3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
--
-- GHC's lexer.
--
-- This is a combination of an Alex-generated lexer from a regex
-- definition, with some hand-coded bits.
--
-- Completely accurate information about token-spans within the source
-- file is maintained.  Every token has a start and end SrcLoc attached to it.
--
-----------------------------------------------------------------------------

--   ToDo / known bugs:
--    - parsing integers is a bit slow
--    - readRational is a bit slow
--
--   Known bugs, that were also in the previous version:
--    - M... should be 3 tokens, not 1.
--    - pragma-end should be only valid in a pragma

22 23 24 25 26 27 28 29 30 31 32
--   qualified operator NOTES.
--   
--   - If M.(+) is a single lexeme, then..
--     - Probably (+) should be a single lexeme too, for consistency.
--       Otherwise ( + ) would be a prefix operator, but M.( + ) would not be.
--     - But we have to rule out reserved operators, otherwise (..) becomes
--       a different lexeme.
--     - Should we therefore also rule out reserved operators in the qualified
--       form?  This is quite difficult to achieve.  We don't do it for
--       qualified varids.

33
{
34
-- XXX The above flags turn off warnings in the generated code:
35
{-# LANGUAGE BangPatterns #-}
36 37 38 39 40 41 42 43
{-# OPTIONS_GHC -fno-warn-unused-matches #-}
{-# OPTIONS_GHC -fno-warn-unused-binds #-}
{-# OPTIONS_GHC -fno-warn-unused-imports #-}
{-# OPTIONS_GHC -fno-warn-missing-signatures #-}
-- But alex still generates some code that causes the "lazy unlifted bindings"
-- warning, and old compilers don't know about it so we can't easily turn
-- it off, so for now we use the sledge hammer:
{-# OPTIONS_GHC -w #-}
44

45 46
{-# OPTIONS_GHC -funbox-strict-fields #-}

47
module Lexer (
48
   Token(..), lexer, pragState, mkPState, PState(..),
49
   P(..), ParseResult(..), getSrcLoc, 
50
   getPState, getDynFlags, withThisPackage,
51
   failLocMsgP, failSpanMsgP, srcParseFail,
52
   getMessages, 
53
   popContext, pushCurrentContext, setLastToken, setSrcLoc,
vivian's avatar
vivian committed
54
   activeContext, nextIsEOF,
simonpj@microsoft.com's avatar
simonpj@microsoft.com committed
55
   getLexState, popLexState, pushLexState,
56
   extension, bangPatEnabled, datatypeContextsEnabled,
Jedai's avatar
Jedai committed
57 58
   addWarning,
   lexTokenStream
59 60
  ) where

61 62
import Bag
import ErrUtils
63 64 65 66 67
import Outputable
import StringBuffer
import FastString
import SrcLoc
import UniqFM
68
import DynFlags
69
import Module
70
import Ctype
71
import BasicTypes	( InlineSpec(..), RuleMatchInfo(..) )
72
import Util		( readRational )
73

74
import Control.Monad
Simon Marlow's avatar
Simon Marlow committed
75
import Data.Bits
76
import Data.Char
77
import Data.List
Ian Lynagh's avatar
Ian Lynagh committed
78
import Data.Maybe
79 80
import Data.Map (Map)
import qualified Data.Map as Map
Simon Marlow's avatar
Simon Marlow committed
81
import Data.Ratio
82 83
}

84
$unispace    = \x05 -- Trick Alex into handling Unicode. See alexGetChar.
85
$whitechar   = [\ \n\r\f\v $unispace]
86
$white_no_nl = $whitechar # \n
87
$tab         = \t
88 89

$ascdigit  = 0-9
90
$unidigit  = \x03 -- Trick Alex into handling Unicode. See alexGetChar.
91
$decdigit  = $ascdigit -- for now, should really be $digit (ToDo)
92 93 94
$digit     = [$ascdigit $unidigit]

$special   = [\(\)\,\;\[\]\`\{\}]
95
$ascsymbol = [\!\#\$\%\&\*\+\.\/\<\=\>\?\@\\\^\|\-\~]
96
$unisymbol = \x04 -- Trick Alex into handling Unicode. See alexGetChar.
97 98
$symbol    = [$ascsymbol $unisymbol] # [$special \_\:\"\']

99
$unilarge  = \x01 -- Trick Alex into handling Unicode. See alexGetChar.
100
$asclarge  = [A-Z]
101 102
$large     = [$asclarge $unilarge]

103
$unismall  = \x02 -- Trick Alex into handling Unicode. See alexGetChar.
104
$ascsmall  = [a-z]
105 106
$small     = [$ascsmall $unismall \_]

107
$unigraphic = \x06 -- Trick Alex into handling Unicode. See alexGetChar.
108
$graphic   = [$small $large $symbol $digit $special $unigraphic \:\"\']
109 110

$octit	   = 0-7
111
$hexit     = [$decdigit A-F a-f]
112 113 114 115
$symchar   = [$symbol \:]
$nl        = [\n\r]
$idchar    = [$small $large $digit \']

116 117
$pragmachar = [$small $large $digit]

118 119
$docsym    = [\| \^ \* \$]

120 121 122 123 124 125
@varid     = $small $idchar*
@conid     = $large $idchar*

@varsym    = $symbol $symchar*
@consym    = \: $symchar*

126
@decimal     = $decdigit+
127 128 129 130 131 132 133 134 135
@octal       = $octit+
@hexadecimal = $hexit+
@exponent    = [eE] [\-\+]? @decimal

-- we support the hierarchical module name extension:
@qual = (@conid \.)+

@floating_point = @decimal \. @decimal @exponent? | @decimal @exponent

136 137 138 139 140
-- normal signed numerical literals can only be explicitly negative,
-- not explicitly positive (contrast @exponent)
@negative = \-
@signed = @negative ?

141 142 143 144
haskell :-

-- everywhere: skip whitespace and comments
$white_no_nl+ 				;
145
$tab+         { warn Opt_WarnTabs (text "Warning: Tab character") }
146 147 148 149 150

-- Everywhere: deal with nested comments.  We explicitly rule out
-- pragmas, "{-#", so that we don't accidentally treat them as comments.
-- (this can happen even though pragmas will normally take precedence due to
-- longest-match, because pragmas aren't valid in every state, but comments
151 152 153 154
-- are). We also rule out nested Haddock comments, if the -haddock flag is
-- set.

"{-" / { isNormalComment } { nested_comment lexToken }
155 156 157 158

-- Single-line comments are a bit tricky.  Haskell 98 says that two or
-- more dashes followed by a symbol should be parsed as a varsym, so we
-- have to exclude those.
159 160 161 162 163 164 165 166 167 168

-- Since Haddock comments aren't valid in every state, we need to rule them
-- out here.  

-- The following two rules match comments that begin with two dashes, but
-- continue with a different character. The rules test that this character
-- is not a symbol (in which case we'd have a varsym), and that it's not a
-- space followed by a Haddock comment symbol (docsym) (in which case we'd
-- have a Haddock comment). The rules then munch the rest of the line.

Jedai's avatar
Jedai committed
169 170
"-- " ~[$docsym \#] .* { lineCommentToken }
"--" [^$symbol : \ ] .* { lineCommentToken }
171 172 173

-- Next, match Haddock comments if no -haddock flag

Jedai's avatar
Jedai committed
174
"-- " [$docsym \#] .* / { ifExtension (not . haddockEnabled) } { lineCommentToken }
175 176 177 178 179 180 181

-- Now, when we've matched comments that begin with 2 dashes and continue
-- with a different character, we need to match comments that begin with three
-- or more dashes (which clearly can't be Haddock comments). We only need to
-- make sure that the first non-dash character isn't a symbol, and munch the
-- rest of the line.

Jedai's avatar
Jedai committed
182
"---"\-* [^$symbol :] .* { lineCommentToken }
183 184 185 186

-- Since the previous rules all match dashes followed by at least one
-- character, we also need to match a whole line filled with just dashes.

Jedai's avatar
Jedai committed
187
"--"\-* / { atEOL } { lineCommentToken }
188 189 190 191

-- We need this rule since none of the other single line comment rules
-- actually match this case.

Jedai's avatar
Jedai committed
192
"-- " / { atEOL } { lineCommentToken }
193 194 195 196 197 198 199 200 201 202 203 204 205

-- 'bol' state: beginning of a line.  Slurp up all the whitespace (including
-- blank lines) until we find a non-whitespace character, then do layout
-- processing.
--
-- One slight wibble here: what if the line begins with {-#? In
-- theory, we have to lex the pragma to see if it's one we recognise,
-- and if it is, then we backtrack and do_bol, otherwise we treat it
-- as a nested comment.  We don't bother with this: if the line begins
-- with {-#, then we'll assume it's a pragma we know about and go for do_bol.
<bol> {
  \n					;
  ^\# (line)?				{ begin line_prag1 }
206
  ^\# pragma .* \n			; -- GCC 3.3 CPP generated, apparently
207
  ^\# \! .* \n				; -- #!, for scripts
208 209 210 211 212 213 214
  ()					{ do_bol }
}

-- after a layout keyword (let, where, do, of), we begin a new layout
-- context if the curly brace is missing.
-- Careful! This stuff is quite delicate.
<layout, layout_do> {
215
  \{ / { notFollowedBy '-' }		{ hopefully_open_brace }
216 217 218 219 220 221 222 223 224 225 226 227 228 229
	-- we might encounter {-# here, but {- has been handled already
  \n					;
  ^\# (line)?				{ begin line_prag1 }
}

-- do is treated in a subtly different way, see new_layout_context
<layout>    ()				{ new_layout_context True }
<layout_do> ()				{ new_layout_context False }

-- after a new layout context which was found to be to the left of the
-- previous context, we have generated a '{' token, and we now need to
-- generate a matching '}' token.
<layout_left>  ()			{ do_layout_left }

230
<0,option_prags> \n				{ begin bol }
231

232 233
"{-#" $whitechar* $pragmachar+ / { known_pragma linePrags }
                                { dispatch_pragmas linePrags }
234 235 236

-- single-line line pragmas, of the form
--    # <line> "<file>" <extra-stuff> \n
237
<line_prag1> $decdigit+			{ setLine line_prag1a }
238
<line_prag1a> \" [$graphic \ ]* \"	{ setFile line_prag1b }
239 240 241 242
<line_prag1b> .*			{ pop }

-- Haskell-style line pragmas, of the form
--    {-# LINE <line> "<file>" #-}
243
<line_prag2> $decdigit+			{ setLine line_prag2a }
244
<line_prag2a> \" [$graphic \ ]* \"	{ setFile line_prag2b }
245 246 247
<line_prag2b> "#-}"|"-}"		{ pop }
   -- NOTE: accept -} at the end of a LINE pragma, for compatibility
   -- with older versions of GHC which generated these.
248

249
<0,option_prags> {
250 251 252 253 254 255
  "{-#" $whitechar* $pragmachar+ 
        $whitechar+ $pragmachar+ / { known_pragma twoWordPrags }
                                 { dispatch_pragmas twoWordPrags }

  "{-#" $whitechar* $pragmachar+ / { known_pragma oneWordPrags }
                                 { dispatch_pragmas oneWordPrags }
256

257
  -- We ignore all these pragmas, but don't generate a warning for them
258 259
  "{-#" $whitechar* $pragmachar+ / { known_pragma ignoredPrags }
                                 { dispatch_pragmas ignoredPrags }
260 261

  -- ToDo: should only be valid inside a pragma:
262
  "#-}" 				{ endPrag }
263 264
}

265
<option_prags> {
266 267 268
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
                                   { dispatch_pragmas fileHeaderPrags }

David Waern's avatar
David Waern committed
269 270 271
  "-- #"                                 { multiline_doc_comment }
}

272 273
<0> {
  -- In the "0" mode we ignore these pragmas
274
  "{-#"  $whitechar* $pragmachar+ / { known_pragma fileHeaderPrags }
275 276 277
                     { nested_comment lexToken }
}

David Waern's avatar
David Waern committed
278
<0> {
Jedai's avatar
Jedai committed
279
  "-- #" .* { lineCommentToken }
280
}
281

282
<0,option_prags> {
283 284
  "{-#"  { warnThen Opt_WarnUnrecognisedPragmas (text "Unrecognised pragma")
                    (nested_comment lexToken) }
285 286
}

287 288
-- '0' state: ordinary lexemes

289 290
-- Haddock comments

291
<0,option_prags> {
David Waern's avatar
David Waern committed
292 293
  "-- " $docsym      / { ifExtension haddockEnabled } { multiline_doc_comment }
  "{-" \ ? $docsym   / { ifExtension haddockEnabled } { nested_doc_comment }
294 295
}

296 297
-- "special" symbols

298
<0> {
299 300 301 302
  "[:" / { ifExtension parrEnabled }	{ token ITopabrack }
  ":]" / { ifExtension parrEnabled }	{ token ITcpabrack }
}
  
303
<0> {
304 305 306 307 308 309 310 311
  "[|"	    / { ifExtension thEnabled }	{ token ITopenExpQuote }
  "[e|"	    / { ifExtension thEnabled }	{ token ITopenExpQuote }
  "[p|"	    / { ifExtension thEnabled }	{ token ITopenPatQuote }
  "[d|"	    / { ifExtension thEnabled }	{ layout_token ITopenDecQuote }
  "[t|"	    / { ifExtension thEnabled }	{ token ITopenTypQuote }
  "|]"	    / { ifExtension thEnabled }	{ token ITcloseQuote }
  \$ @varid / { ifExtension thEnabled }	{ skip_one_varid ITidEscape }
  "$("	    / { ifExtension thEnabled }	{ token ITparenEscape }
312

313 314 315 316
-- For backward compatibility, accept the old dollar syntax
  "[$" @varid "|"  / { ifExtension qqEnabled }
                     { lex_quasiquote_tok }

317
  "[" @varid "|"  / { ifExtension qqEnabled }
318
                     { lex_quasiquote_tok }
319 320
}

321
<0> {
ross's avatar
ross committed
322 323
  "(|" / { ifExtension arrowsEnabled `alexAndPred` notFollowedBySymbol }
					{ special IToparenbar }
324 325 326
  "|)" / { ifExtension arrowsEnabled }  { special ITcparenbar }
}

327
<0> {
328 329 330
  \? @varid / { ifExtension ipEnabled }	{ skip_one_varid ITdupipvarid }
}

331
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
332 333 334 335 336 337
  "(#" / { ifExtension unboxedTuplesEnabled `alexAndPred` notFollowedBySymbol }
         { token IToubxparen }
  "#)" / { ifExtension unboxedTuplesEnabled }
         { token ITcubxparen }
}

338
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
339 340
  "{|" / { ifExtension genericsEnabled } { token ITocurlybar }
  "|}" / { ifExtension genericsEnabled } { token ITccurlybar }
341 342
}

343
<0,option_prags> {
344 345 346 347 348 349 350 351 352 353 354 355
  \(					{ special IToparen }
  \)					{ special ITcparen }
  \[					{ special ITobrack }
  \]					{ special ITcbrack }
  \,					{ special ITcomma }
  \;					{ special ITsemi }
  \`					{ special ITbackquote }
 				
  \{					{ open_brace }
  \}					{ close_brace }
}

356
<0,option_prags> {
357
  @qual @varid			{ idtoken qvarid }
358 359 360 361 362
  @qual @conid			{ idtoken qconid }
  @varid			{ varid }
  @conid			{ idtoken conid }
}

363
<0> {
364 365 366 367
  @qual @varid "#"+ / { ifExtension magicHashEnabled } { idtoken qvarid }
  @qual @conid "#"+ / { ifExtension magicHashEnabled } { idtoken qconid }
  @varid "#"+       / { ifExtension magicHashEnabled } { varid }
  @conid "#"+       / { ifExtension magicHashEnabled } { idtoken conid }
368 369
}

370 371
-- ToDo: - move `var` and (sym) into lexical syntax?
--       - remove backquote from $special?
372
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
373 374
  @qual @varsym                                    { idtoken qvarsym }
  @qual @consym                                    { idtoken qconsym }
375 376
  @varsym                                          { varsym }
  @consym                                          { consym }
377 378
}

379 380
-- For the normal boxed literals we need to be careful
-- when trying to be close to Haskell98
381
<0> {
382
  -- Normal integral literals (:: Num a => a, from Integer)
Ian Lynagh's avatar
Ian Lynagh committed
383 384 385
  @decimal           { tok_num positive 0 0 decimal }
  0[oO] @octal       { tok_num positive 2 2 octal }
  0[xX] @hexadecimal { tok_num positive 2 2 hexadecimal }
386 387

  -- Normal rational literals (:: Fractional a => a, from Rational)
Ian Lynagh's avatar
Ian Lynagh committed
388
  @floating_point    { strtoken tok_float }
389 390
}

391
<0> {
Ian Lynagh's avatar
Ian Lynagh committed
392
  -- Unboxed ints (:: Int#) and words (:: Word#)
393 394
  -- It's simpler (and faster?) to give separate cases to the negatives,
  -- especially considering octal/hexadecimal prefixes.
Ian Lynagh's avatar
Ian Lynagh committed
395 396 397 398 399
  @decimal                     \# / { ifExtension magicHashEnabled } { tok_primint positive 0 1 decimal }
  0[oO] @octal                 \# / { ifExtension magicHashEnabled } { tok_primint positive 2 3 octal }
  0[xX] @hexadecimal           \# / { ifExtension magicHashEnabled } { tok_primint positive 2 3 hexadecimal }
  @negative @decimal           \# / { ifExtension magicHashEnabled } { tok_primint negative 1 2 decimal }
  @negative 0[oO] @octal       \# / { ifExtension magicHashEnabled } { tok_primint negative 3 4 octal }
400
  @negative 0[xX] @hexadecimal \# / { ifExtension magicHashEnabled } { tok_primint negative 3 4 hexadecimal }
401

Ian Lynagh's avatar
Ian Lynagh committed
402 403 404 405
  @decimal                     \# \# / { ifExtension magicHashEnabled } { tok_primword 0 2 decimal }
  0[oO] @octal                 \# \# / { ifExtension magicHashEnabled } { tok_primword 2 4 octal }
  0[xX] @hexadecimal           \# \# / { ifExtension magicHashEnabled } { tok_primword 2 4 hexadecimal }

406 407
  -- Unboxed floats and doubles (:: Float#, :: Double#)
  -- prim_{float,double} work with signed literals
408 409
  @signed @floating_point \# / { ifExtension magicHashEnabled } { init_strtoken 1 tok_primfloat }
  @signed @floating_point \# \# / { ifExtension magicHashEnabled } { init_strtoken 2 tok_primdouble }
410 411 412 413 414 415
}

-- Strings and chars are lexed by hand-written code.  The reason is
-- that even if we recognise the string or char here in the regex
-- lexer, we would still have to parse the string afterward in order
-- to convert it to a String.
416
<0> {
417 418 419 420 421 422 423 424
  \'				{ lex_char_tok }
  \" 				{ lex_string_tok }
}

{
-- -----------------------------------------------------------------------------
-- The token type

425
data Token
426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458
  = ITas  			-- Haskell keywords
  | ITcase
  | ITclass
  | ITdata
  | ITdefault
  | ITderiving
  | ITdo
  | ITelse
  | IThiding
  | ITif
  | ITimport
  | ITin
  | ITinfix
  | ITinfixl
  | ITinfixr
  | ITinstance
  | ITlet
  | ITmodule
  | ITnewtype
  | ITof
  | ITqualified
  | ITthen
  | ITtype
  | ITwhere
  | ITscc			-- ToDo: remove (we use {-# SCC "..." #-} now)

  | ITforall			-- GHC extension keywords
  | ITforeign
  | ITexport
  | ITlabel
  | ITdynamic
  | ITsafe
  | ITthreadsafe
459
  | ITinterruptible
460 461 462
  | ITunsafe
  | ITstdcallconv
  | ITccallconv
463
  | ITprimcallconv
464
  | ITmdo
465
  | ITfamily
466 467 468
  | ITgroup
  | ITby
  | ITusing
469

470
	-- Pragmas
471
  | ITinline_prag InlineSpec RuleMatchInfo
472 473
  | ITspec_prag			-- SPECIALISE	
  | ITspec_inline_prag Bool	-- SPECIALISE INLINE (or NOINLINE)
474 475
  | ITsource_prag
  | ITrules_prag
Ian Lynagh's avatar
Ian Lynagh committed
476
  | ITwarning_prag
477 478 479
  | ITdeprecated_prag
  | ITline_prag
  | ITscc_prag
andy@galois.com's avatar
andy@galois.com committed
480
  | ITgenerated_prag
481
  | ITcore_prag                 -- hdaume: core annotations
482
  | ITunpack_prag
483
  | ITann_prag
484
  | ITclose_prag
485 486 487
  | IToptions_prag String
  | ITinclude_prag String
  | ITlanguage_prag
488 489
  | ITvect_prag
  | ITvect_scalar_prag
490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515

  | ITdotdot  			-- reserved symbols
  | ITcolon
  | ITdcolon
  | ITequal
  | ITlam
  | ITvbar
  | ITlarrow
  | ITrarrow
  | ITat
  | ITtilde
  | ITdarrow
  | ITminus
  | ITbang
  | ITstar
  | ITdot

  | ITbiglam			-- GHC-extension symbols

  | ITocurly  			-- special symbols
  | ITccurly
  | ITocurlybar                 -- {|, for type applications
  | ITccurlybar                 -- |}, for type applications
  | ITvocurly
  | ITvccurly
  | ITobrack
benl's avatar
benl committed
516 517
  | ITopabrack			-- [:, for parallel arrays with -XParallelArrays
  | ITcpabrack			-- :], for parallel arrays with -XParallelArrays
518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535
  | ITcbrack
  | IToparen
  | ITcparen
  | IToubxparen
  | ITcubxparen
  | ITsemi
  | ITcomma
  | ITunderscore
  | ITbackquote

  | ITvarid   FastString	-- identifiers
  | ITconid   FastString
  | ITvarsym  FastString
  | ITconsym  FastString
  | ITqvarid  (FastString,FastString)
  | ITqconid  (FastString,FastString)
  | ITqvarsym (FastString,FastString)
  | ITqconsym (FastString,FastString)
536 537
  | ITprefixqvarsym (FastString,FastString)
  | ITprefixqconsym (FastString,FastString)
538 539 540 541 542 543 544 545 546 547 548

  | ITdupipvarid   FastString	-- GHC extension: implicit param: ?x

  | ITchar       Char
  | ITstring     FastString
  | ITinteger    Integer
  | ITrational   Rational

  | ITprimchar   Char
  | ITprimstring FastString
  | ITprimint    Integer
Ian Lynagh's avatar
Ian Lynagh committed
549
  | ITprimword   Integer
550 551 552
  | ITprimfloat  Rational
  | ITprimdouble Rational

553
  -- Template Haskell extension tokens
554 555 556 557 558 559 560 561 562
  | ITopenExpQuote  		--  [| or [e|
  | ITopenPatQuote		--  [p|
  | ITopenDecQuote		--  [d|
  | ITopenTypQuote		--  [t|         
  | ITcloseQuote		--  |]
  | ITidEscape   FastString	--  $x
  | ITparenEscape		--  $( 
  | ITvarQuote			--  '
  | ITtyQuote			--  ''
563
  | ITquasiQuote (FastString,FastString,SrcSpan) --  [:...|...|]
564 565 566 567

  -- Arrow notation extension
  | ITproc
  | ITrec
568 569 570 571 572 573
  | IToparenbar			--  (|
  | ITcparenbar			--  |)
  | ITlarrowtail		--  -<
  | ITrarrowtail		--  >-
  | ITLarrowtail		--  -<<
  | ITRarrowtail		--  >>-
574 575 576

  | ITunknown String		-- Used when the lexer can't make sense of it
  | ITeof			-- end of file token
577 578 579 580 581 582 583

  -- Documentation annotations
  | ITdocCommentNext  String     -- something beginning '-- |'
  | ITdocCommentPrev  String     -- something beginning '-- ^'
  | ITdocCommentNamed String     -- something beginning '-- $'
  | ITdocSection      Int String -- a section heading
  | ITdocOptions      String     -- doc options (prune, ignore-exports, etc)
David Waern's avatar
David Waern committed
584
  | ITdocOptionsOld   String     -- doc options declared "-- # ..."-style
Jedai's avatar
Jedai committed
585 586
  | ITlineComment     String     -- comment starting by "--"
  | ITblockComment    String     -- comment in {- -}
587

588 589 590 591
#ifdef DEBUG
  deriving Show -- debugging
#endif

twanvl's avatar
twanvl committed
592
{-
593
isSpecial :: Token -> Bool
594 595 596 597 598 599 600 601 602 603 604 605
-- If we see M.x, where x is a keyword, but
-- is special, we treat is as just plain M.x, 
-- not as a keyword.
isSpecial ITas        	= True
isSpecial IThiding    	= True
isSpecial ITqualified 	= True
isSpecial ITforall    	= True
isSpecial ITexport    	= True
isSpecial ITlabel     	= True
isSpecial ITdynamic   	= True
isSpecial ITsafe    	= True
isSpecial ITthreadsafe 	= True
606
isSpecial ITinterruptible = True
607 608 609
isSpecial ITunsafe    	= True
isSpecial ITccallconv   = True
isSpecial ITstdcallconv = True
610
isSpecial ITprimcallconv = True
611
isSpecial ITmdo		= True
612
isSpecial ITfamily	= True
613 614 615
isSpecial ITgroup   = True
isSpecial ITby      = True
isSpecial ITusing   = True
616
isSpecial _             = False
twanvl's avatar
twanvl committed
617
-}
618 619 620 621 622 623 624 625

-- the bitmap provided as the third component indicates whether the
-- corresponding extension keyword is valid under the extension options
-- provided to the compiler; if the extension corresponding to *any* of the
-- bits set in the bitmap is enabled, the keyword is valid (this setup
-- facilitates using a keyword in two different extensions that can be
-- activated independently)
--
Ian Lynagh's avatar
Ian Lynagh committed
626
reservedWordsFM :: UniqFM (Token, Int)
627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655
reservedWordsFM = listToUFM $
	map (\(x, y, z) -> (mkFastString x, (y, z)))
       [( "_",		ITunderscore, 	0 ),
	( "as",		ITas, 		0 ),
	( "case",	ITcase, 	0 ),     
	( "class",	ITclass, 	0 ),    
	( "data",	ITdata, 	0 ),     
	( "default",	ITdefault, 	0 ),  
	( "deriving",	ITderiving, 	0 ), 
	( "do",		ITdo, 		0 ),       
	( "else",	ITelse, 	0 ),     
	( "hiding",	IThiding, 	0 ),
	( "if",		ITif, 		0 ),       
	( "import",	ITimport, 	0 ),   
	( "in",		ITin, 		0 ),       
	( "infix",	ITinfix, 	0 ),    
	( "infixl",	ITinfixl, 	0 ),   
	( "infixr",	ITinfixr, 	0 ),   
	( "instance",	ITinstance, 	0 ), 
	( "let",	ITlet, 		0 ),      
	( "module",	ITmodule, 	0 ),   
	( "newtype",	ITnewtype, 	0 ),  
	( "of",		ITof, 		0 ),       
	( "qualified",	ITqualified, 	0 ),
	( "then",	ITthen, 	0 ),     
	( "type",	ITtype, 	0 ),     
	( "where",	ITwhere, 	0 ),
	( "_scc_",	ITscc, 		0 ),		-- ToDo: remove

656
    ( "forall",	ITforall,	 bit explicitForallBit .|. bit inRulePragBit),
Ian Lynagh's avatar
Ian Lynagh committed
657
	( "mdo",	ITmdo,		 bit recursiveDoBit),
658
	( "family",	ITfamily,	 bit tyFamBit),
659 660 661
    ( "group",  ITgroup,     bit transformComprehensionsBit),
    ( "by",     ITby,        bit transformComprehensionsBit),
    ( "using",  ITusing,     bit transformComprehensionsBit),
662 663 664 665 666 667

	( "foreign",	ITforeign,	 bit ffiBit),
	( "export",	ITexport,	 bit ffiBit),
	( "label",	ITlabel,	 bit ffiBit),
	( "dynamic",	ITdynamic,	 bit ffiBit),
	( "safe",	ITsafe,		 bit ffiBit),
668
	( "threadsafe",	ITthreadsafe,	 bit ffiBit),  -- ToDo: remove
669
	( "interruptible", ITinterruptible, bit ffiBit),
670 671 672
	( "unsafe",	ITunsafe,	 bit ffiBit),
	( "stdcall",    ITstdcallconv,	 bit ffiBit),
	( "ccall",      ITccallconv,	 bit ffiBit),
673
	( "prim",       ITprimcallconv,	 bit ffiBit),
674

675
	( "rec",	ITrec,		 bit recBit),
676
	( "proc",	ITproc,		 bit arrowsBit)
677 678
     ]

Ian Lynagh's avatar
Ian Lynagh committed
679
reservedSymsFM :: UniqFM (Token, Int -> Bool)
680
reservedSymsFM = listToUFM $
Ian Lynagh's avatar
Ian Lynagh committed
681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697
    map (\ (x,y,z) -> (mkFastString x,(y,z)))
      [ ("..",  ITdotdot,   always)
        -- (:) is a reserved op, meaning only list cons
       ,(":",   ITcolon,    always)
       ,("::",  ITdcolon,   always)
       ,("=",   ITequal,    always)
       ,("\\",  ITlam,      always)
       ,("|",   ITvbar,     always)
       ,("<-",  ITlarrow,   always)
       ,("->",  ITrarrow,   always)
       ,("@",   ITat,       always)
       ,("~",   ITtilde,    always)
       ,("=>",  ITdarrow,   always)
       ,("-",   ITminus,    always)
       ,("!",   ITbang,     always)

        -- For data T (a::*) = MkT
698
       ,("*", ITstar, always) -- \i -> kindSigsEnabled i || tyFamEnabled i)
Ian Lynagh's avatar
Ian Lynagh committed
699
        -- For 'forall a . t'
700
       ,(".", ITdot,  always) -- \i -> explicitForallEnabled i || inRulePrag i)
Ian Lynagh's avatar
Ian Lynagh committed
701 702 703 704 705

       ,("-<",  ITlarrowtail, arrowsEnabled)
       ,(">-",  ITrarrowtail, arrowsEnabled)
       ,("-<<", ITLarrowtail, arrowsEnabled)
       ,(">>-", ITRarrowtail, arrowsEnabled)
706

Ian Lynagh's avatar
Ian Lynagh committed
707 708
       ,("∷",   ITdcolon, unicodeSyntaxEnabled)
       ,("⇒",   ITdarrow, unicodeSyntaxEnabled)
Ian Lynagh's avatar
Ian Lynagh committed
709 710
       ,("∀",   ITforall, \i -> unicodeSyntaxEnabled i &&
                                explicitForallEnabled i)
Ian Lynagh's avatar
Ian Lynagh committed
711 712
       ,("→",   ITrarrow, unicodeSyntaxEnabled)
       ,("←",   ITlarrow, unicodeSyntaxEnabled)
713 714 715 716 717 718 719 720

       ,("⤙",   ITlarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤚",   ITrarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤛",   ITLarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)
       ,("⤜",   ITRarrowtail, \i -> unicodeSyntaxEnabled i && arrowsEnabled i)

       ,("★", ITstar, unicodeSyntaxEnabled)

Simon Marlow's avatar
Simon Marlow committed
721 722 723
        -- ToDo: ideally, → and ∷ should be "specials", so that they cannot
        -- form part of a large operator.  This would let us have a better
        -- syntax for kinds: ɑ∷*→* would be a legal kind signature. (maybe).
724 725 726 727 728
       ]

-- -----------------------------------------------------------------------------
-- Lexer actions

729
type Action = SrcSpan -> StringBuffer -> Int -> P (Located Token)
730

731
special :: Token -> Action
twanvl's avatar
twanvl committed
732
special tok span _buf _len = return (L span tok)
733

734
token, layout_token :: Token -> Action
twanvl's avatar
twanvl committed
735 736
token t span _buf _len = return (L span t)
layout_token t span _buf _len = pushLexState layout >> return (L span t)
737

738 739
idtoken :: (StringBuffer -> Int -> Token) -> Action
idtoken f span buf len = return (L span $! (f buf len))
740

741 742 743
skip_one_varid :: (FastString -> Token) -> Action
skip_one_varid f span buf len 
  = return (L span $! f (lexemeToFastString (stepOn buf) (len-1)))
744

745 746 747
strtoken :: (String -> Token) -> Action
strtoken f span buf len = 
  return (L span $! (f $! lexemeToString buf len))
748

749
init_strtoken :: Int -> (String -> Token) -> Action
750
-- like strtoken, but drops the last N character(s)
751 752
init_strtoken drop f span buf len = 
  return (L span $! (f $! lexemeToString buf (len-drop)))
753 754

begin :: Int -> Action
755
begin code _span _str _len = do pushLexState code; lexToken
756 757

pop :: Action
Ian Lynagh's avatar
Ian Lynagh committed
758 759
pop _span _buf _len = do _ <- popLexState
                         lexToken
760

761 762 763 764 765 766 767 768 769 770 771 772 773
hopefully_open_brace :: Action
hopefully_open_brace span buf len
 = do relaxed <- extension relaxedLayout
      ctx <- getContext
      (AI l _) <- getInput
      let offset = srcLocCol l
          isOK = relaxed ||
                 case ctx of
                 Layout prev_off : _ -> prev_off < offset
                 _                   -> True
      if isOK then pop_and open_brace span buf len
              else failSpanMsgP span (text "Missing block")

774
pop_and :: Action -> Action
Ian Lynagh's avatar
Ian Lynagh committed
775 776
pop_and act span buf len = do _ <- popLexState
                              act span buf len
777

778
{-# INLINE nextCharIs #-}
Ian Lynagh's avatar
Ian Lynagh committed
779
nextCharIs :: StringBuffer -> (Char -> Bool) -> Bool
780 781
nextCharIs buf p = not (atEnd buf) && p (currentChar buf)

Ian Lynagh's avatar
Ian Lynagh committed
782
notFollowedBy :: Char -> AlexAccPred Int
783
notFollowedBy char _ _ _ (AI _ buf) 
784
  = nextCharIs buf (/=char)
785

Ian Lynagh's avatar
Ian Lynagh committed
786
notFollowedBySymbol :: AlexAccPred Int
787
notFollowedBySymbol _ _ _ (AI _ buf)
788
  = nextCharIs buf (`notElem` "!#$%&*+./<=>?@\\^|-~")
ross's avatar
ross committed
789

790 791 792 793 794
-- We must reject doc comments as being ordinary comments everywhere.
-- In some cases the doc comment will be selected as the lexeme due to
-- maximal munch, but not always, because the nested comment rule is
-- valid in all states, but the doc-comment rules are only valid in
-- the non-layout states.
Ian Lynagh's avatar
Ian Lynagh committed
795
isNormalComment :: AlexAccPred Int
796
isNormalComment bits _ _ (AI _ buf)
797 798 799 800 801 802
  | haddockEnabled bits = notFollowedByDocOrPragma
  | otherwise           = nextCharIs buf (/='#')
  where
    notFollowedByDocOrPragma
       = not $ spaceAndP buf (`nextCharIs` (`elem` "|^*$#"))

Ian Lynagh's avatar
Ian Lynagh committed
803
spaceAndP :: StringBuffer -> (StringBuffer -> Bool) -> Bool
804
spaceAndP buf p = p buf || nextCharIs buf (==' ') && p (snd (nextChar buf))
805

twanvl's avatar
twanvl committed
806
{-
807
haddockDisabledAnd p bits _ _ (AI _ buf)
808
  = if haddockEnabled bits then False else (p buf)
twanvl's avatar
twanvl committed
809
-}
810

Ian Lynagh's avatar
Ian Lynagh committed
811
atEOL :: AlexAccPred Int
812
atEOL _ _ _ (AI _ buf) = atEnd buf || currentChar buf == '\n'
813

Ian Lynagh's avatar
Ian Lynagh committed
814
ifExtension :: (Int -> Bool) -> AlexAccPred Int
815 816
ifExtension pred bits _ _ _ = pred bits

817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844
multiline_doc_comment :: Action
multiline_doc_comment span buf _len = withLexedDocType (worker "")
  where
    worker commentAcc input docType oneLine = case alexGetChar input of
      Just ('\n', input') 
        | oneLine -> docCommentEnd input commentAcc docType buf span
        | otherwise -> case checkIfCommentLine input' of
          Just input -> worker ('\n':commentAcc) input docType False
          Nothing -> docCommentEnd input commentAcc docType buf span
      Just (c, input) -> worker (c:commentAcc) input docType oneLine
      Nothing -> docCommentEnd input commentAcc docType buf span
      
    checkIfCommentLine input = check (dropNonNewlineSpace input)
      where
        check input = case alexGetChar input of
          Just ('-', input) -> case alexGetChar input of
            Just ('-', input) -> case alexGetChar input of
              Just (c, _) | c /= '-' -> Just input
              _ -> Nothing
            _ -> Nothing
          _ -> Nothing

        dropNonNewlineSpace input = case alexGetChar input of
          Just (c, input') 
            | isSpace c && c /= '\n' -> dropNonNewlineSpace input'
            | otherwise -> input
          Nothing -> input

Jedai's avatar
Jedai committed
845 846 847 848 849
lineCommentToken :: Action
lineCommentToken span buf len = do
  b <- extension rawTokenStreamEnabled
  if b then strtoken ITlineComment span buf len else lexToken

850 851 852 853
{-
  nested comments require traversing by hand, they can't be parsed
  using regular expressions.
-}
854 855
nested_comment :: P (Located Token) -> Action
nested_comment cont span _str _len = do
856
  input <- getInput
Jedai's avatar
Jedai committed
857
  go "" (1::Int) input
858
  where
Jedai's avatar
Jedai committed
859 860 861 862 863 864
    go commentAcc 0 input = do setInput input
                               b <- extension rawTokenStreamEnabled
                               if b
                                 then docCommentEnd input commentAcc ITblockComment _str span
                                 else cont
    go commentAcc n input = case alexGetChar input of
865 866 867
      Nothing -> errBrace input span
      Just ('-',input) -> case alexGetChar input of
        Nothing  -> errBrace input span
Jedai's avatar
Jedai committed
868 869
        Just ('\125',input) -> go commentAcc (n-1) input
        Just (_,_)          -> go ('-':commentAcc) n input
870 871
      Just ('\123',input) -> case alexGetChar input of
        Nothing  -> errBrace input span
Jedai's avatar
Jedai committed
872 873 874
        Just ('-',input) -> go ('-':'\123':commentAcc) (n+1) input
        Just (_,_)       -> go ('\123':commentAcc) n input
      Just (c,input) -> go (c:commentAcc) n input
875 876 877 878 879 880 881 882

nested_doc_comment :: Action
nested_doc_comment span buf _len = withLexedDocType (go "")
  where
    go commentAcc input docType _ = case alexGetChar input of
      Nothing -> errBrace input span
      Just ('-',input) -> case alexGetChar input of
        Nothing -> errBrace input span
twanvl's avatar
twanvl committed
883
        Just ('\125',input) ->
884
          docCommentEnd input commentAcc docType buf span
twanvl's avatar
twanvl committed
885
        Just (_,_) -> go ('-':commentAcc) input docType False
886 887 888 889 890 891
      Just ('\123', input) -> case alexGetChar input of
        Nothing  -> errBrace input span
        Just ('-',input) -> do
          setInput input
          let cont = do input <- getInput; go commentAcc input docType False
          nested_comment cont span buf _len
twanvl's avatar
twanvl committed
892
        Just (_,_) -> go ('\123':commentAcc) input docType False
893 894
      Just (c,input) -> go (c:commentAcc) input docType False

Ian Lynagh's avatar
Ian Lynagh committed
895 896
withLexedDocType :: (AlexInput -> (String -> Token) -> Bool -> P (Located Token))
                 -> P (Located Token)
897
withLexedDocType lexDocComment = do
898
  input@(AI _ buf) <- getInput
899 900 901 902
  case prevChar buf ' ' of
    '|' -> lexDocComment input ITdocCommentNext False
    '^' -> lexDocComment input ITdocCommentPrev False
    '$' -> lexDocComment input ITdocCommentNamed False
David Waern's avatar
David Waern committed
903 904
    '*' -> lexDocSection 1 input
    '#' -> lexDocComment input ITdocOptionsOld False
Ian Lynagh's avatar
Ian Lynagh committed
905
    _ -> panic "withLexedDocType: Bad doc type"
906 907 908
 where 
    lexDocSection n input = case alexGetChar input of 
      Just ('*', input) -> lexDocSection (n+1) input
twanvl's avatar
twanvl committed
909
      Just (_,   _)     -> lexDocComment input (ITdocSection n) True
910 911
      Nothing -> do setInput input; lexToken -- eof reached, lex it normally

912 913 914
-- RULES pragmas turn on the forall and '.' keywords, and we turn them
-- off again at the end of the pragma.
rulePrag :: Action
915
rulePrag span _buf _len = do
916
  setExts (.|. bit inRulePragBit)
917 918 919
  return (L span ITrules_prag)

endPrag :: Action
920
endPrag span _buf _len = do
921 922 923
  setExts (.&. complement (bit inRulePragBit))
  return (L span ITclose_prag)

924 925 926 927 928 929 930 931 932 933 934 935
-- docCommentEnd
-------------------------------------------------------------------------------
-- This function is quite tricky. We can't just return a new token, we also
-- need to update the state of the parser. Why? Because the token is longer
-- than what was lexed by Alex, and the lexToken function doesn't know this, so 
-- it writes the wrong token length to the parser state. This function is
-- called afterwards, so it can just update the state. 

docCommentEnd :: AlexInput -> String -> (String -> Token) -> StringBuffer ->
                 SrcSpan -> P (Located Token) 
docCommentEnd input commentAcc docType buf span = do
  setInput input
936
  let (AI loc nextBuf) = input
937 938 939 940
      comment = reverse commentAcc
      span' = mkSrcSpan (srcSpanStart span) loc
      last_len = byteDiff buf nextBuf
      
941
  span `seq` setLastToken span' last_len
942 943
  return (L span' (docType comment))
 
Ian Lynagh's avatar
Ian Lynagh committed
944
errBrace :: AlexInput -> SrcSpan -> P a
945
errBrace (AI end _) span = failLocMsgP (srcSpanStart span) end "unterminated `{-'"
Ian Lynagh's avatar
Ian Lynagh committed
946

947
open_brace, close_brace :: Action
948
open_brace span _str _len = do 
949 950
  ctx <- getContext
  setContext (NoLayout:ctx)
951 952
  return (L span ITocurly)
close_brace span _str _len = do 
953
  popContext
954
  return (L span ITccurly)
955

Ian Lynagh's avatar
Ian Lynagh committed
956
qvarid, qconid :: StringBuffer -> Int -> Token
957 958
qvarid buf len = ITqvarid $! splitQualName buf len False
qconid buf len = ITqconid $! splitQualName buf len False
959

960
splitQualName :: StringBuffer -> Int -> Bool -> (FastString,FastString)
961 962 963
-- takes a StringBuffer and a length, and returns the module name
-- and identifier parts of a qualified name.  Splits at the *last* dot,
-- because of hierarchical module names.
964
splitQualName orig_buf len parens = split orig_buf orig_buf
965
  where
966 967 968 969 970 971
    split buf dot_buf
	| orig_buf `byteDiff` buf >= len  = done dot_buf
	| c == '.'                	  = found_dot buf'
	| otherwise               	  = split buf' dot_buf
      where
       (c,buf') = nextChar buf
972 973 974 975
  
    -- careful, we might get names like M....
    -- so, if the character after the dot is not upper-case, this is
    -- the end of the qualifier part.
976 977 978 979 980 981 982 983
    found_dot buf -- buf points after the '.'
	| isUpper c    = split buf' buf
	| otherwise    = done buf
      where
       (c,buf') = nextChar buf

    done dot_buf =
	(lexemeToFastString orig_buf (qual_size - 1),
984 985 986
	 if parens -- Prelude.(+)
            then lexemeToFastString (stepOn dot_buf) (len - qual_size - 2)
            else lexemeToFastString dot_buf (len - qual_size))
987 988
      where
	qual_size = orig_buf `byteDiff` dot_buf
989

Ian Lynagh's avatar
Ian Lynagh committed
990 991
varid :: Action
varid span buf len =
Ian Lynagh's avatar
Ian Lynagh committed
992
  fs `seq`
993 994 995
  case lookupUFM reservedWordsFM fs of
	Just (keyword,0)    -> do
		maybe_layout keyword
996
		return (L span keyword)
997 998 999
	Just (keyword,exts) -> do
		b <- extension (\i -> exts .&. i /= 0)
		if b then do maybe_layout keyword
1000 1001 1002
			     return (L span keyword)
		     else return (L span (ITvarid fs))
	_other -> return (L span (ITvarid fs))
1003 1004 1005
  where
	fs = lexemeToFastString buf len

Ian Lynagh's avatar
Ian Lynagh committed
1006
conid :: StringBuffer -> Int -> Token
1007 1008 1009
conid buf len = ITconid fs
  where fs = lexemeToFastString buf len

Ian Lynagh's avatar
Ian Lynagh committed
1010
qvarsym, qconsym, prefixqvarsym, prefixqconsym :: StringBuffer -> Int -> Token
1011 1012 1013 1014
qvarsym buf len = ITqvarsym $! splitQualName buf len False
qconsym buf len = ITqconsym $! splitQualName buf len False
prefixqvarsym buf len = ITprefixqvarsym $! splitQualName buf len True
prefixqconsym buf len = ITprefixqconsym $! splitQualName buf len True
1015

Ian Lynagh's avatar
Ian Lynagh committed
1016
varsym, consym :: Action
1017 1018 1019
varsym = sym ITvarsym
consym = sym ITconsym

Ian Lynagh's avatar
Ian Lynagh committed
1020 1021
sym :: (FastString -> Token) -> SrcSpan -> StringBuffer -> Int
    -> P (Located Token)
1022
sym con span buf len = 
1023 1024
  case lookupUFM reservedSymsFM fs of
	Just (keyword,exts) -> do
Ian Lynagh's avatar
Ian Lynagh committed
1025
		b <- extension exts
1026 1027 1028
		if b then return (L span keyword)
		     else return (L span $! con fs)
	_other -> return (L span $! con fs)
1029 1030 1031
  where
	fs = lexemeToFastString buf len

1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042
-- Variations on the integral numeric literal.
tok_integral :: (Integer -> Token)
     -> (Integer -> Integer)
 --    -> (StringBuffer -> StringBuffer) -> (Int -> Int)
     -> Int -> Int
     -> (Integer, (Char->Int)) -> Action
tok_integral itint transint transbuf translen (radix,char_to_int) span buf len =
  return $ L span $ itint $! transint $ parseUnsignedInteger
     (offsetBytes transbuf buf) (subtract translen len) radix char_to_int

-- some conveniences for use with tok_integral
Ian Lynagh's avatar
Ian Lynagh committed
1043 1044 1045
tok_num :: (Integer -> Integer)
        -> Int -> Int
        -> (Integer, (Char->Int)) -> Action
1046
tok_num = tok_integral ITinteger
Ian Lynagh's avatar
Ian Lynagh committed
1047 1048 1049
tok_primint :: (Integer -> Integer)
            -> Int -> Int
            -> (Integer, (Char->Int)) -> Action
1050
tok_primint = tok_integral ITprimint
Ian Lynagh's avatar
Ian Lynagh committed
1051 1052
tok_primword :: Int -> Int
             -> (Integer, (Char->Int)) -> Action
Ian Lynagh's avatar
Ian Lynagh committed
1053
tok_primword = tok_integral ITprimword positive
Ian Lynagh's avatar
Ian Lynagh committed
1054
positive, negative :: (Integer -> Integer)
1055 1056
positive = id
negative = negate
Ian Lynagh's avatar
Ian Lynagh committed
1057
decimal, octal, hexadecimal :: (Integer, Char -> Int)
1058 1059 1060 1061 1062
decimal = (10,octDecDigit)
octal = (8,octDecDigit)
hexadecimal = (16,hexDigit)

-- readRational can understand negative rationals, exponents, everything.
Ian Lynagh's avatar
Ian Lynagh committed
1063
tok_float, tok_primfloat, tok_primdouble :: String -> Token
1064
tok_float        str = ITrational   $! readRational str
1065 1066
tok_primfloat    str = ITprimfloat  $! readRational str
tok_primdouble   str = ITprimdouble $! readRational str
1067 1068 1069 1070 1071 1072

-- -----------------------------------------------------------------------------
-- Layout processing

-- we're at the first token on a line, insert layout tokens if necessary
do_bol :: Action
1073
do_bol span _str _len = do
1074
	pos <- getOffside
1075 1076 1077 1078 1079
	case pos of
	    LT -> do
                --trace "layout: inserting '}'" $ do
		popContext
		-- do NOT pop the lex state, we might have a ';' to insert
1080
		return (L span ITvccurly)
1081 1082
	    EQ -> do
                --trace "layout: inserting ';'" $ do
Ian Lynagh's avatar
Ian Lynagh committed
1083
		_ <- popLexState
1084
		return (L span ITsemi)
1085
	    GT -> do
Ian Lynagh's avatar
Ian Lynagh committed
1086
		_ <- popLexState
1087 1088 1089 1090
		lexToken

-- certain keywords put us in the "layout" state, where we might
-- add an opening curly brace.
Ian Lynagh's avatar
Ian Lynagh committed
1091
maybe_layout :: Token -> P ()
1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107
maybe_layout t = do -- If the alternative layout rule is enabled then
                    -- we never create an implicit layout context here.
                    -- Layout is handled XXX instead.
                    -- The code for closing implicit contexts, or
                    -- inserting implicit semi-colons, is therefore
                    -- irrelevant as it only applies in an implicit
                    -- context.
                    alr <- extension alternativeLayoutRule
                    unless alr $ f t
    where f ITdo    = pushLexState layout_do
          f ITmdo   = pushLexState layout_do
          f ITof    = pushLexState layout
          f ITlet   = pushLexState layout
          f ITwhere = pushLexState layout
          f ITrec   = pushLexState layout
          f _       = return ()
1108 1109 1110 1111 1112 1113 1114 1115 1116 1117

-- Pushing a new implicit layout context.  If the indentation of the
-- next token is not greater than the previous layout context, then
-- Haskell 98 says that the new layout context should be empty; that is
-- the lexer must generate {}.
--
-- We are slightly more lenient than this: when the new context is started
-- by a 'do', then we allow the new context to be at the same indentation as
-- the previous context.  This is what the 'strict' argument is for.
--
Ian Lynagh's avatar
Ian Lynagh committed
1118
new_layout_context :: Bool -> Action
1119
new_layout_context strict span _buf _len = do
Ian Lynagh's avatar
Ian Lynagh committed
1120
    _ <- popLexState
1121 1122
    (AI l _) <- getInput
    let offset = srcLocCol l
1123
    ctx <- getContext
1124 1125
    nondecreasing <- extension nondecreasingIndentation
    let strict' = strict || not nondecreasing
1126 1127
    case ctx of
	Layout prev_off : _  | 
1128 1129
	   (strict'     && prev_off >= offset  ||
	    not strict' && prev_off > offset) -> do
1130 1131 1132
		-- token is indented to the left of the previous context.
		-- we must generate a {} sequence now.
		pushLexState layout_left
1133
		return (L span ITvocurly)