DriverPipeline.hs 60.3 KB
Newer Older
1
2
3
4
-----------------------------------------------------------------------------
--
-- GHC Driver
--
5
-- (c) The University of Glasgow 2005
6
7
8
9
--
-----------------------------------------------------------------------------

module DriverPipeline (
10
11
	-- Run a series of compilation steps in a pipeline, for a
	-- collection of source files.
12
   oneShot, compileFile,
13

14
	-- Interfaces for the batch-mode driver
15
   linkBinary,
16

17
18
	-- Interfaces for the compilation manager (interpreted/batch-mode)
   preprocess, 
19
   compile,
20
   link, 
21

22
23
24
25
  ) where

#include "HsVersions.h"

26
import Packages
27
import HeaderInfo
28
import DriverPhases
29
import SysTools
30
import HscMain
31
import Finder
32
33
34
import HscTypes
import Outputable
import Module
Simon Marlow's avatar
Simon Marlow committed
35
import UniqFM		( eltsUFM )
36
import ErrUtils
37
import DynFlags
38
import StaticFlags	( v_Ld_inputs, opt_Static, WayName(..) )
39
import Config
40
import Panic
41
import Util
42
import StringBuffer	( hGetStringBuffer )
43
import BasicTypes	( SuccessFlag(..) )
44
import Maybes		( expectJust )
45
import ParserCoreUtils	( getCoreModuleName )
46
import SrcLoc		( unLoc )
47
import SrcLoc		( Located(..) )
48

Simon Marlow's avatar
Simon Marlow committed
49
50
51
52
import Control.Exception as Exception
import Data.IORef	( readIORef, writeIORef, IORef )
import GHC.Exts		( Int(..) )
import System.Directory
Ian Lynagh's avatar
Ian Lynagh committed
53
import System.FilePath
Simon Marlow's avatar
Simon Marlow committed
54
55
56
import System.IO
import SYSTEM_IO_ERROR as IO
import Control.Monad
57
import Data.List	( isSuffixOf )
Simon Marlow's avatar
Simon Marlow committed
58
59
60
import Data.Maybe
import System.Exit
import System.Environment
61

62
63
-- ---------------------------------------------------------------------------
-- Pre-process
64
65
66

-- Just preprocess a file, put the result in a temp. file (used by the
-- compilation manager during the summary phase).
67
68
69
--
-- We return the augmented DynFlags, because they contain the result
-- of slurping in the OPTIONS pragmas
70

71
72
73
preprocess :: DynFlags -> (FilePath, Maybe Phase) -> IO (DynFlags, FilePath)
preprocess dflags (filename, mb_phase) =
  ASSERT2(isJust mb_phase || isHaskellSrcFilename filename, text filename) 
Simon Marlow's avatar
Simon Marlow committed
74
75
  runPipeline anyHsc dflags (filename, mb_phase) 
        Nothing Temporary Nothing{-no ModLocation-}
76

77
78
-- ---------------------------------------------------------------------------
-- Compile
79
80
81
82
83
84
85
86
87
88

-- Compile a single module, under the control of the compilation manager.
--
-- This is the interface between the compilation manager and the
-- compiler proper (hsc), where we deal with tedious details like
-- reading the OPTIONS pragma from the source file, and passing the
-- output of hsc through the C compiler.

-- NB.  No old interface can also mean that the source has changed.

89
compile :: HscEnv
90
91
92
93
94
95
96
97
98
99
100
        -> ModSummary                   -- summary for module being compiled
        -> Int -> Int                   -- module N of M
        -> Maybe ModIface               -- old interface, if we have one
        -> Maybe Linkable               -- old linkable, if we have one
        -> IO (Maybe HomeModInfo)       -- the complete HomeModInfo, if successful

compile hsc_env summary mod_index nmods mb_old_iface maybe_old_linkable
 = do
   let dflags0     = ms_hspp_opts summary
       this_mod    = ms_mod summary
       src_flavour = ms_hsc_src summary
101
102
103
       location	   = ms_location summary
       input_fn    = expectJust "compile:hs" (ml_hs_file location) 
       input_fnpp  = ms_hspp_file summary
104

105
   debugTraceMsg dflags0 2 (text "compile: input file" <+> text input_fnpp)
106

Ian Lynagh's avatar
Ian Lynagh committed
107
   let basename = dropExtension input_fn
108

109
110
111
  -- We add the directory in which the .hs files resides) to the import path.
  -- This is needed when we try to compile the .hc file later, if it
  -- imports a _stub.h file that we created here.
Ian Lynagh's avatar
Ian Lynagh committed
112
113
114
   let current_dir = case takeDirectory basename of
                     "" -> "." -- XXX Hack
                     d -> d
115
116
       old_paths   = includePaths dflags0
       dflags      = dflags0 { includePaths = current_dir : old_paths }
117

118
   -- Figure out what lang we're generating
119
   let hsc_lang = hscMaybeAdjustTarget dflags StopLn src_flavour (hscTarget dflags)
120
   -- ... and what the next phase should be
121
   let next_phase = hscNextPhase dflags src_flavour hsc_lang
122
   -- ... and what file to generate the output into
123
124
   output_fn <- getOutputFilename next_phase 
			Temporary basename dflags next_phase (Just location)
125

126
   let dflags' = dflags { hscTarget = hsc_lang,
127
				hscOutName = output_fn,
128
129
130
				extCoreName = basename ++ ".hcr" }

   -- -no-recomp should also work with --make
131
132
   let force_recomp = dopt Opt_ForceRecomp dflags
       source_unchanged = isJust maybe_old_linkable && not force_recomp
133
       hsc_env' = hsc_env { hsc_dflags = dflags' }
134
       object_filename = ml_obj_file location
135

136
137
138
139
140
   let getStubLinkable False = return []
       getStubLinkable True
           = do stub_o <- compileStub dflags' this_mod location
                return [ DotO stub_o ]

141
       handleBatch HscNoRecomp
142
           = ASSERT (isJust maybe_old_linkable)
143
144
145
             return maybe_old_linkable

       handleBatch (HscRecomp hasStub)
146
           | isHsBoot src_flavour
147
148
               = do when (isObjectTarget hsc_lang) $ -- interpreted reaches here too
                       SysTools.touch dflags' "Touching object file"
149
                                   object_filename
150
151
                    return maybe_old_linkable

152
153
154
155
156
           | otherwise
               = do stub_unlinked <- getStubLinkable hasStub
                    (hs_unlinked, unlinked_time) <-
                        case hsc_lang of
                          HscNothing
157
                            -> return ([], ms_hs_date summary)
158
159
                          -- We're in --make mode: finish the compilation pipeline.
                          _other
Simon Marlow's avatar
Simon Marlow committed
160
161
162
                            -> do runPipeline StopLn dflags (output_fn,Nothing)
                                              (Just basename)
                                              Persistent
163
164
165
166
167
168
                                              (Just location)
                                  -- The object filename comes from the ModLocation
                                  o_time <- getModificationTime object_filename
                                  return ([DotO object_filename], o_time)
                    let linkable = LM unlinked_time this_mod
			           (hs_unlinked ++ stub_unlinked)
169
                    return (Just linkable)
170

171
       handleInterpreted InteractiveNoRecomp
172
           = ASSERT (isJust maybe_old_linkable)
173
174
             return maybe_old_linkable
       handleInterpreted (InteractiveRecomp hasStub comp_bc modBreaks)
175
           = do stub_unlinked <- getStubLinkable hasStub
176
                let hs_unlinked = [BCOs comp_bc modBreaks]
177
                    unlinked_time = ms_hs_date summary
178
179
180
181
182
183
184
185
                  -- Why do we use the timestamp of the source file here,
                  -- rather than the current time?  This works better in
                  -- the case where the local clock is out of sync
                  -- with the filesystem's clock.  It's just as accurate:
                  -- if the source is modified, then the linkable will
                  -- be out of date.
                let linkable = LM unlinked_time this_mod
                               (hs_unlinked ++ stub_unlinked)
186
                return (Just linkable)
187

188
189
190
191
   let -- runCompiler :: Compiler result -> (result -> Maybe Linkable)
       --            -> IO (Maybe HomeModInfo)
       runCompiler compiler handle
           = do mbResult <- compiler hsc_env' summary source_unchanged mb_old_iface
192
193
                                     (Just (mod_index, nmods))
                case mbResult of
194
195
196
197
198
199
                  Nothing -> return Nothing
                  Just (result, iface, details) -> do
                        linkable <- handle result
                        return (Just HomeModInfo{ hm_details  = details,
                                                  hm_iface    = iface,
                                                  hm_linkable = linkable })
200
   -- run the compiler
201
   case hsc_lang of
202
203
204
205
206
207
208
209
210
      HscInterpreted
        | isHsBoot src_flavour -> 
                runCompiler hscCompileNothing handleBatch
        | otherwise -> 
                runCompiler hscCompileInteractive handleInterpreted
      HscNothing -> 
                runCompiler hscCompileNothing handleBatch
      _other -> 
                runCompiler hscCompileBatch handleBatch
211

212
-----------------------------------------------------------------------------
213
214
-- stub .h and .c files (for foreign export support)

215
216
217
-- The _stub.c file is derived from the haskell source file, possibly taking
-- into account the -stubdir option.
--
218
219
220
221
222
223
224
225
226
227
228
229
230
-- Consequently, we derive the _stub.o filename from the haskell object
-- filename.  
--
-- This isn't necessarily the same as the object filename we
-- would get if we just compiled the _stub.c file using the pipeline.
-- For example:
--
--    ghc src/A.hs -odir obj
-- 
-- results in obj/A.o, and src/A_stub.c.  If we compile src/A_stub.c with
-- -odir obj, we would get obj/src/A_stub.o, which is wrong; we want
-- obj/A_stub.o.

231
232
compileStub :: DynFlags -> Module -> ModLocation -> IO FilePath
compileStub dflags mod location = do
Ian Lynagh's avatar
Ian Lynagh committed
233
234
	let (o_base, o_ext) = splitExtension (ml_obj_file location)
	    stub_o = (o_base ++ "_stub") <.> o_ext
235

236
	-- compile the _stub.c file w/ gcc
237
	let (stub_c,_,_) = mkStubPaths dflags (moduleName mod) location
Simon Marlow's avatar
Simon Marlow committed
238
	runPipeline StopLn dflags (stub_c,Nothing)  Nothing
239
240
241
		(SpecificFile stub_o) Nothing{-no ModLocation-}

	return stub_o
242
243


244
245
-- ---------------------------------------------------------------------------
-- Link
246

Ian Lynagh's avatar
Ian Lynagh committed
247
248
249
250
link :: GhcLink                 -- interactive or batch
     -> DynFlags                -- dynamic flags
     -> Bool                    -- attempt linking in batch mode?
     -> HomePackageTable        -- what to link
251
252
253
254
255
256
257
258
259
260
     -> IO SuccessFlag

-- For the moment, in the batch linker, we don't bother to tell doLink
-- which packages to link -- it just tries all that are available.
-- batch_attempt_linking should only be *looked at* in batch mode.  It
-- should only be True if the upsweep was successful and someone
-- exports main, i.e., we have good reason to believe that linking
-- will succeed.

#ifdef GHCI
261
link LinkInMemory _ _ _
262
    = do -- Not Linking...(demand linker will do the job)
Ian Lynagh's avatar
Ian Lynagh committed
263
         return Succeeded
264
265
#endif

266
link NoLink _ _ _
267
268
   = return Succeeded

269
link LinkBinary dflags batch_attempt_linking hpt
270
   | batch_attempt_linking
Ian Lynagh's avatar
Ian Lynagh committed
271
272
273
   = do
        let
            home_mod_infos = eltsUFM hpt
274

Ian Lynagh's avatar
Ian Lynagh committed
275
276
            -- the packages we depend on
            pkg_deps  = concatMap (dep_pkgs . mi_deps . hm_iface) home_mod_infos
277

Ian Lynagh's avatar
Ian Lynagh committed
278
279
            -- the linkables to link
            linkables = map (expectJust "link".hm_linkable) home_mod_infos
280

281
        debugTraceMsg dflags 3 (text "link: linkables are ..." $$ vcat (map ppr linkables))
282

Ian Lynagh's avatar
Ian Lynagh committed
283
284
285
286
287
        -- check for the -no-link flag
        if isNoLink (ghcLink dflags)
          then do debugTraceMsg dflags 3 (text "link(batch): linking omitted (-c flag given).")
                  return Succeeded
          else do
288

Ian Lynagh's avatar
Ian Lynagh committed
289
290
        let getOfiles (LM _ _ us) = map nameOfObject (filter isObject us)
            obj_files = concatMap getOfiles linkables
291

Ian Lynagh's avatar
Ian Lynagh committed
292
            exe_file = exeFileName dflags
293

Ian Lynagh's avatar
Ian Lynagh committed
294
295
296
297
        -- if the modification time on the executable is later than the
        -- modification times on all of the objects, then omit linking
        -- (unless the -no-recomp flag was given).
        e_exe_time <- IO.try $ getModificationTime exe_file
298
299
300
301
        extra_ld_inputs <- readIORef v_Ld_inputs
        extra_times <- mapM (IO.try . getModificationTime) extra_ld_inputs
        let other_times = map linkableTime linkables
                       ++ [ t' | Right t' <- extra_times ]
302
303
304
            linking_needed = case e_exe_time of
                               Left _  -> True
                               Right t -> any (t <) other_times
305

Ian Lynagh's avatar
Ian Lynagh committed
306
307
308
309
        if not (dopt Opt_ForceRecomp dflags) && not linking_needed
           then do debugTraceMsg dflags 2 (text exe_file <+> ptext SLIT("is up to date, linking not required."))
                   return Succeeded
           else do
310

Ian Lynagh's avatar
Ian Lynagh committed
311
312
        debugTraceMsg dflags 1 (ptext SLIT("Linking") <+> text exe_file
                                 <+> text "...")
313

Ian Lynagh's avatar
Ian Lynagh committed
314
315
316
317
        -- Don't showPass in Batch mode; doLink will do that for us.
        let link = case ghcLink dflags of
                LinkBinary  -> linkBinary
                LinkDynLib  -> linkDynLib
318
                other       -> panicBadLink other
Ian Lynagh's avatar
Ian Lynagh committed
319
        link dflags obj_files pkg_deps
320

321
        debugTraceMsg dflags 3 (text "link: done")
322

Ian Lynagh's avatar
Ian Lynagh committed
323
        -- linkBinary only returns if it succeeds
324
325
326
        return Succeeded

   | otherwise
327
328
   = do debugTraceMsg dflags 3 (text "link(batch): upsweep (partially) failed OR" $$
                                text "   Main.main not exported; not linking.")
329
        return Succeeded
Ian Lynagh's avatar
Ian Lynagh committed
330

331
332
333
334
335
336
-- warning suppression
link other _ _ _ = panicBadLink other

panicBadLink :: GhcLink -> a
panicBadLink other = panic ("link: GHC not built to link this way: " ++
                            show other)
337
338
339
-- -----------------------------------------------------------------------------
-- Compile files in one-shot mode.

340
oneShot :: DynFlags -> Phase -> [(String, Maybe Phase)] -> IO ()
341
342
343
344
oneShot dflags stop_phase srcs = do
  o_files <- mapM (compileFile dflags stop_phase) srcs
  doLink dflags stop_phase o_files

345
346
compileFile :: DynFlags -> Phase -> (FilePath, Maybe Phase) -> IO FilePath
compileFile dflags stop_phase (src, mb_phase) = do
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
   exists <- doesFileExist src
   when (not exists) $ 
   	throwDyn (CmdLineError ("does not exist: " ++ src))
   
   let
	split     = dopt Opt_SplitObjs dflags
	mb_o_file = outputFile dflags
	ghc_link  = ghcLink dflags	-- Set by -c or -no-link

	-- When linking, the -o argument refers to the linker's output.	
	-- otherwise, we use it as the name for the pipeline's output.
        output
	 | StopLn <- stop_phase, not (isNoLink ghc_link) = Persistent
		-- -o foo applies to linker
	 | Just o_file <- mb_o_file = SpecificFile o_file
		-- -o foo applies to the file we are compiling now
	 | otherwise = Persistent

        stop_phase' = case stop_phase of 
			As | split -> SplitAs
367
                        _          -> stop_phase
368
369

   (_, out_file) <- runPipeline stop_phase' dflags
Simon Marlow's avatar
Simon Marlow committed
370
371
			  (src, mb_phase) Nothing output 
                          Nothing{-no ModLocation-}
372
373
374
375
376
377
378
379
380
381
382
   return out_file


doLink :: DynFlags -> Phase -> [FilePath] -> IO ()
doLink dflags stop_phase o_files
  | not (isStopLn stop_phase)
  = return ()		-- We stopped before the linking phase

  | otherwise
  = case ghcLink dflags of
	NoLink     -> return ()
383
384
	LinkBinary -> linkBinary dflags o_files link_pkgs
	LinkDynLib -> linkDynLib dflags o_files []
385
        other      -> panicBadLink other
386
387
388
  where
   -- Always link in the haskell98 package for static linking.  Other
   -- packages have to be specified via the -package flag.
Simon Marlow's avatar
Simon Marlow committed
389
    link_pkgs = [haskell98PackageId]
390
391


392
393
-- ---------------------------------------------------------------------------
-- Run a compilation pipeline, consisting of multiple phases.
394

395
396
397
398
-- This is the interface to the compilation pipeline, which runs
-- a series of compilation steps on a single source file, specifying
-- at which stage to stop.

399
-- The DynFlags can be modified by phases in the pipeline (eg. by
400
401
402
403
404
405
406
407
408
409
410
411
412
-- GHC_OPTIONS pragmas), and the changes affect later phases in the
-- pipeline.

data PipelineOutput 
  = Temporary
	-- output should be to a temporary file: we're going to
	-- run more compilation steps on this output later
  | Persistent
	-- we want a persistent file, i.e. a file in the current directory
	-- derived from the input filename, but with the appropriate extension.
	-- eg. in "ghc -c Foo.hs" the output goes into ./Foo.o.
  | SpecificFile FilePath
	-- the output must go into the specified file.
413

414
runPipeline
415
416
417
  :: Phase		        -- When to stop
  -> DynFlags		        -- Dynamic flags
  -> (FilePath,Maybe Phase)     -- Input filename (and maybe -x suffix)
Simon Marlow's avatar
Simon Marlow committed
418
  -> Maybe FilePath             -- original basename (if different from ^^^)
419
420
  -> PipelineOutput	        -- Output filename
  -> Maybe ModLocation          -- A ModLocation, if this is a Haskell module
421
  -> IO (DynFlags, FilePath)	-- (final flags, output filename)
422

423
runPipeline stop_phase dflags0 (input_fn, mb_phase) mb_basename output maybe_loc
424
  = do
425
  let
Ian Lynagh's avatar
Ian Lynagh committed
426
427
      (input_basename, suffix) = splitExtension input_fn
      suffix' = drop 1 suffix -- strip off the .
Simon Marlow's avatar
Simon Marlow committed
428
429
      basename | Just b <- mb_basename = b
               | otherwise             = input_basename
430

431
432
433
      -- Decide where dump files should go based on the pipeline output
      dflags = dflags0 { dumpPrefix = Just (basename ++ ".") }

434
	-- If we were given a -x flag, then use that phase to start from
Ian Lynagh's avatar
Ian Lynagh committed
435
      start_phase = fromMaybe (startPhase suffix') mb_phase
436

437
438
439
440
441
442
  -- We want to catch cases of "you can't get there from here" before
  -- we start the pipeline, because otherwise it will just run off the
  -- end.
  --
  -- There is a partial ordering on phases, where A < B iff A occurs
  -- before B in a normal compilation pipeline.
443

444
445
  when (not (start_phase `happensBefore` stop_phase)) $
	throwDyn (UsageError 
446
447
		    ("cannot compile this file to desired target: "
		       ++ input_fn))
448

449
450
  -- this is a function which will be used to calculate output file names
  -- as we go along (we partially apply it to some of its inputs here)
451
  let get_output_fn = getOutputFilename stop_phase output basename
452

453
  -- Execute the pipeline...
454
455
  (dflags', output_fn, maybe_loc) <- 
	pipeLoop dflags start_phase stop_phase input_fn 
Ian Lynagh's avatar
Ian Lynagh committed
456
	  	 basename suffix' get_output_fn maybe_loc
457

458
  -- Sometimes, a compilation phase doesn't actually generate any output
459
460
  -- (eg. the CPP phase when -fcpp is not turned on).  If we end on this
  -- stage, but we wanted to keep the output, then we have to explicitly
461
462
  -- copy the file, remembering to prepend a {-# LINE #-} pragma so that
  -- further compilation stages can tell what the original filename was.
463
464
465
466
  case output of
    Temporary -> 
	return (dflags', output_fn)
    _other ->
467
	do final_fn <- get_output_fn dflags' stop_phase maybe_loc
468
469
470
471
	   when (final_fn /= output_fn) $ do
              let msg = ("Copying `" ++ output_fn ++"' to `" ++ final_fn ++ "'")
                  line_prag = Just ("{-# LINE 1 \"" ++ input_fn ++ "\" #-}\n")
	      copyWithHeader dflags msg line_prag output_fn final_fn
472
	   return (dflags', final_fn)
473

474
475


476
pipeLoop :: DynFlags -> Phase -> Phase 
477
	 -> FilePath  -> String -> Suffix
478
	 -> (DynFlags -> Phase -> Maybe ModLocation -> IO FilePath)
479
480
	 -> Maybe ModLocation
	 -> IO (DynFlags, FilePath, Maybe ModLocation)
481

482
pipeLoop dflags phase stop_phase 
483
484
	 input_fn orig_basename orig_suff 
	 orig_get_output_fn maybe_loc
485

486
487
  | phase `eqPhase` stop_phase		  -- All done
  = return (dflags, input_fn, maybe_loc)
488

489
  | not (phase `happensBefore` stop_phase)
490
491
492
493
	-- Something has gone wrong.  We'll try to cover all the cases when
	-- this could happen, so if we reach here it is a panic.
	-- eg. it might happen if the -C flag is used on a source file that
	-- has {-# OPTIONS -fasm #-}.
494
495
496
497
498
  = panic ("pipeLoop: at phase " ++ show phase ++ 
	   " but I wanted to stop at phase " ++ show stop_phase)

  | otherwise 
  = do	{ (next_phase, dflags', maybe_loc, output_fn)
499
		<- runPhase phase stop_phase dflags orig_basename 
500
			    orig_suff input_fn orig_get_output_fn maybe_loc
501
	; pipeLoop dflags' next_phase stop_phase output_fn
502
503
		   orig_basename orig_suff orig_get_output_fn maybe_loc }

504
getOutputFilename
505
506
507
  :: Phase -> PipelineOutput -> String
  -> DynFlags -> Phase{-next phase-} -> Maybe ModLocation -> IO FilePath
getOutputFilename stop_phase output basename
508
509
 = func
 where
510
	func dflags next_phase maybe_location
511
512
513
514
	   | is_last_phase, Persistent <- output     = persistent_fn
	   | is_last_phase, SpecificFile f <- output = return f
	   | keep_this_output	   		     = persistent_fn
     	   | otherwise        	   		     = newTempName dflags suffix
515
	   where
516
517
518
519
520
521
522
523
524
525
526
		hcsuf      = hcSuf dflags
		odir       = objectDir dflags
		osuf       = objectSuf dflags
		keep_hc    = dopt Opt_KeepHcFiles dflags
		keep_raw_s = dopt Opt_KeepRawSFiles dflags
		keep_s     = dopt Opt_KeepSFiles dflags

		myPhaseInputExt HCc    = hcsuf
		myPhaseInputExt StopLn = osuf
		myPhaseInputExt other  = phaseInputExt other

527
		is_last_phase = next_phase `eqPhase` stop_phase
528
529
530
531

		-- sometimes, we keep output from intermediate stages
		keep_this_output = 
     		     case next_phase of
532
     			     StopLn              -> True
533
534
535
536
537
     			     Mangle | keep_raw_s -> True
     			     As     | keep_s     -> True
     			     HCc    | keep_hc    -> True
     			     _other              -> False

538
		suffix = myPhaseInputExt next_phase
539
540
541

		-- persistent object files get put in odir
	        persistent_fn 
542
543
		   | StopLn <- next_phase = return odir_persistent
		   | otherwise            = return persistent
544

Ian Lynagh's avatar
Ian Lynagh committed
545
		persistent = basename <.> suffix
546

547
		odir_persistent
548
		   | Just loc <- maybe_location = ml_obj_file loc
Ian Lynagh's avatar
Ian Lynagh committed
549
		   | Just d <- odir = d </> persistent
550
551
		   | otherwise      = persistent

552

553
554
555
556
557
558
559
560
561
562
-- -----------------------------------------------------------------------------
-- Each phase in the pipeline returns the next phase to execute, and the
-- name of the file in which the output was placed.
--
-- We must do things dynamically this way, because we often don't know
-- what the rest of the phases will be until part-way through the
-- compilation: for example, an {-# OPTIONS -fasm #-} at the beginning
-- of a source file can change the latter stages of the pipeline from
-- taking the via-C route to using the native code generator.

563
564
runPhase :: Phase	-- Do this phase first
	 -> Phase	-- Stop just before this phase
565
566
567
568
	 -> DynFlags
	 -> String	-- basename of original input source
	 -> String	-- its extension
	 -> FilePath	-- name of file which contains the input to this phase.
569
	 -> (DynFlags -> Phase -> Maybe ModLocation -> IO FilePath)
570
			-- how to calculate the output filename
571
	 -> Maybe ModLocation		-- the ModLocation, if we have one
572
	 -> IO (Phase,	  		-- next phase
573
574
575
		DynFlags,		-- new dynamic flags
		Maybe ModLocation,	-- the ModLocation, if we have one
		FilePath)		-- output filename
576

577
578
579
580
	-- Invariant: the output filename always contains the output
	-- Interesting case: Hsc when there is no recompilation to do
	--		     Then the output filename is still a .o file 

581
582
583
-------------------------------------------------------------------------------
-- Unlit phase 

584
runPhase (Unlit sf) _stop dflags _basename _suff input_fn get_output_fn maybe_loc
585
  = do
586
       output_fn <- get_output_fn dflags (Cpp sf) maybe_loc
587

588
589
590
591
592
593
594
595
596
597
598
599
600
       let unlit_flags = getOpts dflags opt_L
           flags = map SysTools.Option unlit_flags ++
                   [ -- The -h option passes the file name for unlit to
                     -- put in a #line directive
                     SysTools.Option     "-h"
                     -- cpp interprets \b etc as escape sequences,
                     -- so we use / for filenames in pragmas
                   , SysTools.Option $ reslash Forwards $ normalise input_fn
                   , SysTools.FileOption "" input_fn
                   , SysTools.FileOption "" output_fn
                   ]

       SysTools.runUnlit dflags flags
601

602
       return (Cpp sf, dflags, maybe_loc, output_fn)
603
604

-------------------------------------------------------------------------------
605
606
-- Cpp phase : (a) gets OPTIONS out of file
--	       (b) runs cpp if necessary
607

608
runPhase (Cpp sf) _stop dflags0 basename suff input_fn get_output_fn maybe_loc
609
610
  = do src_opts <- getOptionsFromFile input_fn
       (dflags,unhandled_flags) <- parseDynamicFlags dflags0 (map unLoc src_opts)
Ian Lynagh's avatar
Ian Lynagh committed
611
       checkProcessArgsResult unhandled_flags (basename <.> suff)
612

613
       if not (dopt Opt_Cpp dflags) then
sof's avatar
sof committed
614
615
           -- no need to preprocess CPP, just pass input file along
	   -- to the next phase of the pipeline.
616
          return (HsPp sf, dflags, maybe_loc, input_fn)
sof's avatar
sof committed
617
	else do
618
	    output_fn <- get_output_fn dflags (HsPp sf) maybe_loc
619
	    doCpp dflags True{-raw-} False{-no CC opts-} input_fn output_fn
620
	    return (HsPp sf, dflags, maybe_loc, output_fn)
621

sof's avatar
sof committed
622
623
624
-------------------------------------------------------------------------------
-- HsPp phase 

625
runPhase (HsPp sf) _stop dflags basename suff input_fn get_output_fn maybe_loc
626
  = do if not (dopt Opt_Pp dflags) then
sof's avatar
sof committed
627
628
           -- no need to preprocess, just pass input file along
	   -- to the next phase of the pipeline.
629
          return (Hsc sf, dflags, maybe_loc, input_fn)
sof's avatar
sof committed
630
	else do
631
	    let hspp_opts = getOpts dflags opt_F
Ian Lynagh's avatar
Ian Lynagh committed
632
	    let orig_fn = basename <.> suff
633
	    output_fn <- get_output_fn dflags (Hsc sf) maybe_loc
634
635
	    SysTools.runPp dflags
			   ( [ SysTools.Option     orig_fn
sof's avatar
sof committed
636
637
638
639
640
			     , SysTools.Option     input_fn
			     , SysTools.FileOption "" output_fn
			     ] ++
			     map SysTools.Option hspp_opts
			   )
641
	    return (Hsc sf, dflags, maybe_loc, output_fn)
642

643
644
645
-----------------------------------------------------------------------------
-- Hsc phase

646
647
-- Compilation of a single module, in "legacy" mode (_not_ under
-- the direction of the compilation manager).
648
runPhase (Hsc src_flavour) stop dflags0 basename suff input_fn get_output_fn _maybe_loc 
649
 = do	-- normal Hsc mode, not mkdependHS
650

651
  -- we add the current directory (i.e. the directory in which
652
  -- the .hs files resides) to the include path, since this is
653
  -- what gcc does, and it's probably what you want.
Ian Lynagh's avatar
Ian Lynagh committed
654
655
656
	let current_dir = case takeDirectory basename of
                      "" -> "." -- XXX Hack
                      d -> d
657
	
658
659
	    paths = includePaths dflags0
	    dflags = dflags0 { includePaths = current_dir : paths }
660
	
661
  -- gather the imports and module name
662
        (hspp_buf,mod_name,imps,src_imps) <- 
663
664
665
            case src_flavour of
		ExtCoreFile -> do {  -- no explicit imports in ExtCore input.
			          ; m <- getCoreModuleName input_fn
666
			          ; return (Nothing, mkModuleName m, [], []) }
667

668
		_           -> do { buf <- hGetStringBuffer input_fn
Ian Lynagh's avatar
Ian Lynagh committed
669
			    ; (src_imps,imps,L _ mod_name) <- getImports dflags buf input_fn (basename <.> suff)
670
			    ; return (Just buf, mod_name, imps, src_imps) }
671
672
673
674
675
676
677

  -- Build a ModLocation to pass to hscMain.
  -- The source filename is rather irrelevant by now, but it's used
  -- by hscMain for messages.  hscMain also needs 
  -- the .hi and .o filenames, and this is as good a way
  -- as any to generate them, and better than most. (e.g. takes 
  -- into accout the -osuf flags)
678
	location1 <- mkHomeModLocation2 dflags mod_name basename suff
679
680
681
682
683
684
685
686
687

  -- Boot-ify it if necessary
	let location2 | isHsBoot src_flavour = addBootSuffixLocn location1
		      | otherwise	     = location1 
					

  -- Take -ohi into account if present
  -- This can't be done in mkHomeModuleLocation because
  -- it only applies to the module being compiles
688
689
	let ohi = outputHi dflags
	    location3 | Just fn <- ohi = location2{ ml_hi_file = fn }
690
691
692
693
694
695
696
		      | otherwise      = location2

  -- Take -o into account if present
  -- Very like -ohi, but we must *only* do this if we aren't linking
  -- (If we're linking then the -o applies to the linked thing, not to
  -- the object file for one module.)
  -- Note the nasty duplication with the same computation in compileFile above
697
698
699
	let expl_o_file = outputFile dflags
	    location4 | Just ofile <- expl_o_file
		      , isNoLink (ghcLink dflags)
700
701
702
703
704
705
706
		      = location3 { ml_obj_file = ofile }
		      | otherwise = location3

	    o_file = ml_obj_file location4 	-- The real object file


  -- Figure out if the source has changed, for recompilation avoidance.
707
  --
708
  -- Setting source_unchanged to True means that M.o seems
709
710
  -- to be up to date wrt M.hs; so no need to recompile unless imports have
  -- changed (which the compiler itself figures out).
711
  -- Setting source_unchanged to False tells the compiler that M.o is out of
712
  -- date wrt M.hs (or M.o doesn't exist) so we must recompile regardless.
Ian Lynagh's avatar
Ian Lynagh committed
713
	src_timestamp <- getModificationTime (basename <.> suff)
Simon Marlow's avatar
Simon Marlow committed
714

715
	let force_recomp = dopt Opt_ForceRecomp dflags
716
	source_unchanged <- 
717
          if force_recomp || not (isStopLn stop)
718
719
		-- Set source_unchanged to False unconditionally if
		--	(a) recompilation checker is off, or
720
		-- 	(b) we aren't going all the way to .o file (e.g. ghc -S)
721
722
	     then return False	
		-- Otherwise look at file modification dates
723
	     else do o_file_exists <- doesFileExist o_file
724
		     if not o_file_exists
725
		        then return False	-- Need to recompile
726
			else do t2 <- getModificationTime o_file
727
			        if t2 > src_timestamp
728
729
				  then return True
				  else return False
730

731
  -- get the DynFlags
732
	let hsc_lang = hscMaybeAdjustTarget dflags stop src_flavour (hscTarget dflags)
733
	let next_phase = hscNextPhase dflags src_flavour hsc_lang
734
	output_fn  <- get_output_fn dflags next_phase (Just location4)
735

736
        let dflags' = dflags { hscTarget = hsc_lang,
737
738
			       hscOutName = output_fn,
			       extCoreName = basename ++ ".hcr" }
739

740
	hsc_env <- newHscEnv dflags'
741

742
  -- Tell the finder cache about this module
Simon Marlow's avatar
Simon Marlow committed
743
744
745
746
747
748
749
750
751
752
753
754
	mod <- addHomeModuleToFinder hsc_env mod_name location4

  -- Make the ModSummary to hand to hscMain
	let
	    mod_summary = ModSummary {	ms_mod 	     = mod, 
					ms_hsc_src   = src_flavour,
				 	ms_hspp_file = input_fn,
                                        ms_hspp_opts = dflags,
					ms_hspp_buf  = hspp_buf,
					ms_location  = location4,
					ms_hs_date   = src_timestamp,
					ms_obj_date  = Nothing,
755
756
					ms_imps	     = imps,
					ms_srcimps   = src_imps }
757

758
  -- run the compiler!
759
	mbResult <- hscCompileOneShot hsc_env
760
761
			  mod_summary source_unchanged 
			  Nothing	-- No iface
762
                          Nothing       -- No "module i of n" progress info
763

764
765
	case mbResult of
          Nothing -> throwDyn (PhaseFailed "hsc" (ExitFailure 1))
766
          Just HscNoRecomp
767
768
769
770
771
              -> do SysTools.touch dflags' "Touching object file" o_file
                    -- The .o file must have a later modification date
                    -- than the source file (else we wouldn't be in HscNoRecomp)
                    -- but we touch it anyway, to keep 'make' happy (we think).
                    return (StopLn, dflags', Just location4, o_file)
772
          Just (HscRecomp hasStub)
773
              -> do when hasStub $
Simon Marlow's avatar
Simon Marlow committed
774
                         do stub_o <- compileStub dflags' mod location4
775
776
777
778
779
780
                            consIORef v_Ld_inputs stub_o
                    -- In the case of hs-boot files, generate a dummy .o-boot 
                    -- stamp file for the benefit of Make
                    when (isHsBoot src_flavour) $
                      SysTools.touch dflags' "Touching object file" o_file
                    return (next_phase, dflags', Just location4, output_fn)
781

782
783
784
-----------------------------------------------------------------------------
-- Cmm phase

785
runPhase CmmCpp _stop dflags _basename _suff input_fn get_output_fn maybe_loc
786
  = do
787
       output_fn <- get_output_fn dflags Cmm maybe_loc
788
       doCpp dflags False{-not raw-} True{-include CC opts-} input_fn output_fn	
789
       return (Cmm, dflags, maybe_loc, output_fn)
790

791
runPhase Cmm stop dflags basename _ input_fn get_output_fn maybe_loc
792
  = do
793
	let hsc_lang = hscMaybeAdjustTarget dflags stop HsSrcFile (hscTarget dflags)
794
	let next_phase = hscNextPhase dflags HsSrcFile hsc_lang
795
	output_fn <- get_output_fn dflags next_phase maybe_loc
796

797
        let dflags' = dflags { hscTarget = hsc_lang,
798
799
			       hscOutName = output_fn,
			       extCoreName = basename ++ ".hcr" }
800

801
	ok <- hscCmmFile dflags' input_fn
802
803
804

	when (not ok) $ throwDyn (PhaseFailed "cmm" (ExitFailure 1))

805
	return (next_phase, dflags, maybe_loc, output_fn)
806

807
808
809
810
811
812
-----------------------------------------------------------------------------
-- Cc phase

-- we don't support preprocessing .c files (with -E) now.  Doing so introduces
-- way too many hacks, and I can't say I've ever used it anyway.

813
runPhase cc_phase _stop dflags _basename _suff input_fn get_output_fn maybe_loc
814
   | cc_phase `eqPhase` Cc || cc_phase `eqPhase` Ccpp || cc_phase `eqPhase` HCc
815
   = do	let cc_opts = getOpts dflags opt_c
816
	    hcc = cc_phase `eqPhase` HCc
817

818
       	let cmdline_include_paths = includePaths dflags
819

820
821
822
823
824
825
	-- HC files have the dependent packages stamped into them
	pkgs <- if hcc then getHCFilePackages input_fn else return []

	-- add package include paths even if we're just compiling .c
	-- files; this is the Value Add(TM) that using ghc instead of
	-- gcc gives you :)
826
        pkg_include_dirs <- getPackageIncludePath dflags pkgs
rrt's avatar
rrt committed
827
828
        let include_paths = foldr (\ x xs -> "-I" : x : xs) []
			      (cmdline_include_paths ++ pkg_include_dirs)
829

830
	let (md_c_flags, md_regd_c_flags) = machdepCCOpts dflags
831
        gcc_extra_viac_flags <- getExtraViaCOpts dflags
832
        let pic_c_flags = picCCOpts dflags
833

834
        let verb = getVerbFlag dflags
835

836
	pkg_extra_cc_opts <- getPackageExtraCcOpts dflags pkgs
837

838
839
840
841
842
843
844
#ifdef darwin_TARGET_OS
        pkg_framework_paths <- getPackageFrameworkPath dflags pkgs
        let cmdline_framework_paths = frameworkPaths dflags
        let framework_paths = map ("-F"++) 
                        (cmdline_framework_paths ++ pkg_framework_paths)
#endif

845
846
	let split_objs = dopt Opt_SplitObjs dflags
	    split_opt | hcc && split_objs = [ "-DUSE_SPLIT_MARKERS" ]
sof's avatar
sof committed
847
		      | otherwise         = [ ]
848

Simon Marlow's avatar
Simon Marlow committed
849
850
851
	let cc_opt | optLevel dflags >= 2 = "-O2"
		   | otherwise            = "-O"

852
	-- Decide next phase
853
854
855
	
        let mangle = dopt Opt_DoAsmMangling dflags
            next_phase
856
857
		| hcc && mangle     = Mangle
		| otherwise         = As
858
	output_fn <- get_output_fn dflags next_phase maybe_loc
859

860
861
	let
	  more_hcc_opts =
862
#if i386_TARGET_ARCH
863
864
865
866
	   	-- on x86 the floating point regs have greater precision
	     	-- than a double, which leads to unpredictable results.
		-- By default, we turn this off with -ffloat-store unless
		-- the user specified -fexcess-precision.
867
868
869
		(if dopt Opt_ExcessPrecision dflags 
                        then [] 
                        else [ "-ffloat-store" ]) ++
870
871
872
873
874
875
876
877
878
#endif
		-- gcc's -fstrict-aliasing allows two accesses to memory
		-- to be considered non-aliasing if they have different types.
		-- This interacts badly with the C code we generate, which is
		-- very weakly typed, being derived from C--.
		["-fno-strict-aliasing"]



879
880
881
882
883
	SysTools.runCc dflags (
		-- force the C compiler to interpret this file as C when
		-- compiling .hc files, by adding the -x c option.
		-- Also useful for plain .c files, just in case GHC saw a 
		-- -x c option.
884
885
			[ SysTools.Option "-x", if cc_phase `eqPhase` Ccpp
                                                then SysTools.Option "c++" else SysTools.Option "c"] ++
886
			[ SysTools.FileOption "" input_fn
sof's avatar
sof committed
887
			, SysTools.Option "-o"
sof's avatar
sof committed
888
			, SysTools.FileOption "" output_fn
sof's avatar
sof committed
889
890
891
			]
		       ++ map SysTools.Option (
		          md_c_flags
892
                       ++ pic_c_flags
893
894
895
896
897
898
899
900
901
#ifdef sparc_TARGET_ARCH
        -- We only support SparcV9 and better because V8 lacks an atomic CAS
        -- instruction. Note that the user can still override this
	-- (e.g., -mcpu=ultrasparc) as GCC picks the "best" -mcpu flag
	-- regardless of the ordering.
        --
        -- This is a temporary hack.
                       ++ ["-mcpu=v9"]
#endif
902
		       ++ (if hcc && mangle
903
904
		  	     then md_regd_c_flags
		  	     else [])
905
906
907
908
909
910
911
		       ++ (if hcc
		  	     then if mangle 
                                     then gcc_extra_viac_flags
                                     else filter (=="-fwrapv")
                                                gcc_extra_viac_flags
                                -- still want -fwrapv even for unreg'd
		  	     else [])
912
913
914
		       ++ (if hcc 
			     then more_hcc_opts
			     else [])
Simon Marlow's avatar
Simon Marlow committed
915
		       ++ [ verb, "-S", "-Wimplicit", cc_opt ]
916
		       ++ [ "-D__GLASGOW_HASKELL__="++cProjectVersionInt ]
917
918
919
#ifdef darwin_TARGET_OS
                       ++ framework_paths
#endif
920
		       ++ cc_opts
sof's avatar
sof committed
921
		       ++ split_opt
922
923
		       ++ include_paths
		       ++ pkg_extra_cc_opts
sof's avatar
sof committed
924
		       ))
925

926