DriverPipeline.hs

-----------------------------------------------------------------------------
--
-- GHC Driver
--
-- (c) The University of Glasgow 2005
--
-----------------------------------------------------------------------------

module DriverPipeline (
	-- Run a series of compilation steps in a pipeline, for a
	-- collection of source files.
   oneShot,

	-- Interfaces for the batch-mode driver
   staticLink,

	-- Interfaces for the compilation manager (interpreted/batch-mode)
   preprocess, 
   compile, CompResult(..), 
   link, 

        -- DLL building
   doMkDLL,

   getOptionsFromStringBuffer,	-- used in module GHC
   optionsErrorMsgs,	  	-- ditto
  ) where

#include "HsVersions.h"

import Packages
import GetImports
import DriverPhases
import SysTools		( newTempName, addFilesToClean, getSysMan, copy )
import qualified SysTools	
import HscMain
import Finder
import HscTypes
import Outputable
import Module
import ErrUtils
import DynFlags
import StaticFlags	( v_Ld_inputs, opt_Static, WayName(..) )
import Config
import RdrName		( GlobalRdrEnv )
import Panic
import Util
import StringBuffer	( hGetStringBuffer )
import BasicTypes	( SuccessFlag(..) )
import Maybes		( expectJust )
import Ctype		( is_ident )
import StringBuffer	( StringBuffer(..), lexemeToString )
import ParserCoreUtils	( getCoreModuleName )
import SrcLoc		( srcLocSpan, mkSrcLoc )
import FastString	( mkFastString )
import Bag		( listToBag, emptyBag )

import EXCEPTION
import DATA_IOREF	( readIORef, writeIORef, IORef )
import GLAEXTS		( Int(..) )

import Directory
import System
import IO
import Monad
import Maybe


-- ---------------------------------------------------------------------------
-- Pre-process

-- Just preprocess a file, put the result in a temp. file (used by the
-- compilation manager during the summary phase).
--
-- We return the augmented DynFlags, because they contain the result
-- of slurping in the OPTIONS pragmas

preprocess :: DynFlags -> FilePath -> IO (DynFlags, FilePath)
preprocess dflags filename =
  ASSERT2(isHaskellSrcFilename filename, text filename) 
  runPipeline anyHsc dflags filename Temporary Nothing{-no ModLocation-}

-- ---------------------------------------------------------------------------
-- Compile

-- Compile a single module, under the control of the compilation manager.
--
-- This is the interface between the compilation manager and the
-- compiler proper (hsc), where we deal with tedious details like
-- reading the OPTIONS pragma from the source file, and passing the
-- output of hsc through the C compiler.

-- NB.  No old interface can also mean that the source has changed.

compile :: HscEnv
	-> (Messages -> IO ())	-- error message callback
	-> ModSummary
	-> Maybe Linkable	-- Just linkable <=> source unchanged
        -> Maybe ModIface       -- Old interface, if available
        -> Int -> Int
        -> IO CompResult

data CompResult
   = CompOK   ModDetails 	-- New details
              ModIface		-- New iface
              (Maybe Linkable)	-- a Maybe, for the same reasons as hm_linkable

   | CompErrs 


compile hsc_env msg_act mod_summary maybe_old_linkable old_iface mod_index nmods = do 

   let dflags0     = hsc_dflags hsc_env
       this_mod    = ms_mod mod_summary
       src_flavour = ms_hsc_src mod_summary

       have_object 
	       | Just l <- maybe_old_linkable, isObjectLinkable l = True
	       | otherwise = False

   showPass dflags0 ("Compiling " ++ showModMsg have_object mod_summary)

   let location	  = ms_location mod_summary
   let input_fn   = expectJust "compile:hs" (ml_hs_file location) 
   let input_fnpp = expectJust "compile:hspp" (ms_hspp_file mod_summary)

   debugTraceMsg dflags0 2 ("compile: input file " ++ input_fnpp)

   -- Add in the OPTIONS from the source file
   -- This is nasty: we've done this once already, in the compilation manager
   -- It might be better to cache the flags in the ml_hspp_file field,say
   let hspp_buf = expectJust "compile:hspp_buf" (ms_hspp_buf mod_summary)
       opts = getOptionsFromStringBuffer hspp_buf
   (dflags1,unhandled_flags) <- parseDynamicFlags dflags0 (map snd opts)
   if (not (null unhandled_flags))
	then do msg_act (optionsErrorMsgs unhandled_flags opts input_fn)
		return CompErrs
	else do

   let (basename, _) = splitFilename input_fn

  -- We add the directory in which the .hs files resides) to the import path.
  -- This is needed when we try to compile the .hc file later, if it
  -- imports a _stub.h file that we created here.
   let current_dir = directoryOf basename
       old_paths   = includePaths dflags1
       dflags      = dflags1 { includePaths = current_dir : old_paths }

   -- Figure out what lang we're generating
   let hsc_lang = hscMaybeAdjustTarget dflags StopLn src_flavour (hscTarget dflags)
   -- ... and what the next phase should be
   let next_phase = hscNextPhase dflags src_flavour hsc_lang
   -- ... and what file to generate the output into
   output_fn <- getOutputFilename dflags next_phase 
			Temporary basename next_phase (Just location)

   let dflags' = dflags { hscTarget = hsc_lang,
				hscOutName = output_fn,
				hscStubCOutName = basename ++ "_stub.c",
				hscStubHOutName = basename ++ "_stub.h",
				extCoreName = basename ++ ".hcr" }

   -- -no-recomp should also work with --make
   let do_recomp = dopt Opt_RecompChecking dflags
       source_unchanged = isJust maybe_old_linkable && do_recomp
       hsc_env' = hsc_env { hsc_dflags = dflags' }
       object_filename = ml_obj_file location

   -- run the compiler
   hsc_result <- hscMain hsc_env' msg_act mod_summary
			 source_unchanged have_object old_iface
                         (Just (mod_index, nmods))

   case hsc_result of
      HscFail -> return CompErrs

      HscNoRecomp details iface -> 
	  ASSERT(isJust maybe_old_linkable)
	  return (CompOK details iface maybe_old_linkable)

      HscRecomp details iface stub_h_exists stub_c_exists maybe_interpreted_code 

	| isHsBoot src_flavour	-- No further compilation to do
	-> do	case hsc_lang of
		   HscInterpreted -> return ()
		   _other -> SysTools.touch dflags' "Touching object file" 
					    object_filename
		return (CompOK details iface Nothing)

	| otherwise	-- Normal source file
	-> do
	   maybe_stub_o <- compileStub dflags' stub_c_exists
	   let stub_unlinked = case maybe_stub_o of
				  Nothing -> []
				  Just stub_o -> [ DotO stub_o ]

	   (hs_unlinked, unlinked_time) <-
	     case hsc_lang of

		-- in interpreted mode, just return the compiled code
		-- as our "unlinked" object.
		HscInterpreted
		  -> case maybe_interpreted_code of
#ifdef GHCI
		       Just comp_bc -> return ([BCOs comp_bc], ms_hs_date mod_summary)
			-- Why do we use the timestamp of the source file here,
			-- rather than the current time?  This works better in
			-- the case where the local clock is out of sync
			-- with the filesystem's clock.  It's just as accurate:
			-- if the source is modified, then the linkable will
			-- be out of date.
#endif
		       Nothing -> panic "compile: no interpreted code"

		-- We're in --make mode: finish the compilation pipeline.
		_other
		  -> do	runPipeline StopLn dflags output_fn Persistent
				    (Just location)
				-- The object filename comes from the ModLocation

			o_time <- getModificationTime object_filename
			return ([DotO object_filename], o_time)

	   let linkable = LM unlinked_time this_mod
			     (hs_unlinked ++ stub_unlinked)

	   return (CompOK details iface (Just linkable))

-----------------------------------------------------------------------------
-- stub .h and .c files (for foreign export support)

compileStub dflags stub_c_exists
  | not stub_c_exists = return Nothing
  | stub_c_exists = do
	-- compile the _stub.c file w/ gcc
	let stub_c = hscStubCOutName dflags
	(_, stub_o) <- runPipeline StopLn dflags
			    stub_c Persistent Nothing{-no ModLocation-}
	return (Just stub_o)


-- ---------------------------------------------------------------------------
-- Link

link :: GhcMode			-- interactive or batch
     -> DynFlags		-- dynamic flags
     -> Bool			-- attempt linking in batch mode?
     -> HomePackageTable	-- what to link
     -> IO SuccessFlag

-- For the moment, in the batch linker, we don't bother to tell doLink
-- which packages to link -- it just tries all that are available.
-- batch_attempt_linking should only be *looked at* in batch mode.  It
-- should only be True if the upsweep was successful and someone
-- exports main, i.e., we have good reason to believe that linking
-- will succeed.

#ifdef GHCI
link Interactive dflags batch_attempt_linking hpt
    = do -- Not Linking...(demand linker will do the job)
	 return Succeeded
#endif

link JustTypecheck dflags batch_attempt_linking hpt
   = return Succeeded

link BatchCompile dflags batch_attempt_linking hpt
   | batch_attempt_linking
   = do 
	let 
	    home_mod_infos = moduleEnvElts hpt

	    -- the packages we depend on
	    pkg_deps  = concatMap (dep_pkgs . mi_deps . hm_iface) home_mod_infos

	    -- the linkables to link
	    linkables = map (fromJust.hm_linkable) home_mod_infos

        debugTraceMsg dflags 3 "link: linkables are ..."
        debugTraceMsg dflags 3 (showSDoc (vcat (map ppr linkables)))

	-- check for the -no-link flag
	if isNoLink (ghcLink dflags)
	  then do debugTraceMsg dflags 3 "link(batch): linking omitted (-c flag given)."
	          return Succeeded
	  else do

	debugTraceMsg dflags 1 "Linking ..."

	let getOfiles (LM _ _ us) = map nameOfObject (filter isObject us)
	    obj_files = concatMap getOfiles linkables

	-- Don't showPass in Batch mode; doLink will do that for us.
        staticLink dflags obj_files pkg_deps

        debugTraceMsg dflags 3 "link: done"

	-- staticLink only returns if it succeeds
        return Succeeded

   | otherwise
   = do debugTraceMsg dflags 3 "link(batch): upsweep (partially) failed OR"
        debugTraceMsg dflags 3 "   Main.main not exported; not linking."
        return Succeeded
      

-- -----------------------------------------------------------------------------
-- Compile files in one-shot mode.

oneShot :: DynFlags -> Phase -> [String] -> IO ()
oneShot dflags stop_phase srcs = do
  o_files <- mapM (compileFile dflags stop_phase) srcs
  doLink dflags stop_phase o_files

compileFile :: DynFlags -> Phase -> FilePath -> IO FilePath
compileFile dflags stop_phase src = do
   exists <- doesFileExist src
   when (not exists) $ 
   	throwDyn (CmdLineError ("does not exist: " ++ src))
   
   let
	split     = dopt Opt_SplitObjs dflags
	mb_o_file = outputFile dflags
	ghc_link  = ghcLink dflags	-- Set by -c or -no-link

	-- When linking, the -o argument refers to the linker's output.	
	-- otherwise, we use it as the name for the pipeline's output.
        output
	 | StopLn <- stop_phase, not (isNoLink ghc_link) = Persistent
		-- -o foo applies to linker
	 | Just o_file <- mb_o_file = SpecificFile o_file
		-- -o foo applies to the file we are compiling now
	 | otherwise = Persistent

        stop_phase' = case stop_phase of 
			As | split -> SplitAs
			other      -> stop_phase

   (_, out_file) <- runPipeline stop_phase' dflags
			  src output Nothing{-no ModLocation-}
   return out_file


doLink :: DynFlags -> Phase -> [FilePath] -> IO ()
doLink dflags stop_phase o_files
  | not (isStopLn stop_phase)
  = return ()		-- We stopped before the linking phase

  | otherwise
  = case ghcLink dflags of
	NoLink     -> return ()
	StaticLink -> staticLink dflags o_files link_pkgs
	MkDLL      -> doMkDLL dflags o_files link_pkgs
  where
   -- Always link in the haskell98 package for static linking.  Other
   -- packages have to be specified via the -package flag.
    link_pkgs
	  | ExtPackage h98_id <- haskell98PackageId (pkgState dflags) = [h98_id]
	  | otherwise = []


-- ---------------------------------------------------------------------------
-- Run a compilation pipeline, consisting of multiple phases.

-- This is the interface to the compilation pipeline, which runs
-- a series of compilation steps on a single source file, specifying
-- at which stage to stop.

-- The DynFlags can be modified by phases in the pipeline (eg. by
-- GHC_OPTIONS pragmas), and the changes affect later phases in the
-- pipeline.

data PipelineOutput 
  = Temporary
	-- output should be to a temporary file: we're going to
	-- run more compilation steps on this output later
  | Persistent
	-- we want a persistent file, i.e. a file in the current directory
	-- derived from the input filename, but with the appropriate extension.
	-- eg. in "ghc -c Foo.hs" the output goes into ./Foo.o.
  | SpecificFile FilePath
	-- the output must go into the specified file.

runPipeline
  :: Phase		-- When to stop
  -> DynFlags		-- Dynamic flags
  -> FilePath 		-- Input filename
  -> PipelineOutput	-- Output filename
  -> Maybe ModLocation  -- A ModLocation, if this is a Haskell module
  -> IO (DynFlags, FilePath)	-- (final flags, output filename)

runPipeline stop_phase dflags input_fn output maybe_loc
  = do
  let (basename, suffix) = splitFilename input_fn
      start_phase = startPhase suffix

  -- We want to catch cases of "you can't get there from here" before
  -- we start the pipeline, because otherwise it will just run off the
  -- end.
  --
  -- There is a partial ordering on phases, where A < B iff A occurs
  -- before B in a normal compilation pipeline.

  when (not (start_phase `happensBefore` stop_phase)) $
	throwDyn (UsageError 
		    ("cannot compile this file to desired target: "
		       ++ input_fn))

  -- this is a function which will be used to calculate output file names
  -- as we go along (we partially apply it to some of its inputs here)
  let get_output_fn = getOutputFilename dflags stop_phase output basename

  -- Execute the pipeline...
  (dflags', output_fn, maybe_loc) <- 
	pipeLoop dflags start_phase stop_phase input_fn 
	  	 basename suffix get_output_fn maybe_loc

  -- Sometimes, a compilation phase doesn't actually generate any output
  -- (eg. the CPP phase when -fcpp is not turned on).  If we end on this
  -- stage, but we wanted to keep the output, then we have to explicitly
  -- copy the file.
  case output of
    Temporary -> 
	return (dflags', output_fn)
    _other ->
	do final_fn <- get_output_fn stop_phase maybe_loc
	   when (final_fn /= output_fn) $
		  copy dflags ("Copying `" ++ output_fn ++ "' to `" ++ final_fn
			++ "'") output_fn final_fn
	   return (dflags', final_fn)
	        


pipeLoop :: DynFlags -> Phase -> Phase 
	 -> FilePath  -> String -> Suffix
	 -> (Phase -> Maybe ModLocation -> IO FilePath)
	 -> Maybe ModLocation
	 -> IO (DynFlags, FilePath, Maybe ModLocation)

pipeLoop dflags phase stop_phase 
	 input_fn orig_basename orig_suff 
	 orig_get_output_fn maybe_loc

  | phase `eqPhase` stop_phase		  -- All done
  = return (dflags, input_fn, maybe_loc)

  | not (phase `happensBefore` stop_phase)
	-- Something has gone wrong.  We'll try to cover all the cases when
	-- this could happen, so if we reach here it is a panic.
	-- eg. it might happen if the -C flag is used on a source file that
	-- has {-# OPTIONS -fasm #-}.
  = panic ("pipeLoop: at phase " ++ show phase ++ 
	   " but I wanted to stop at phase " ++ show stop_phase)

  | otherwise 
  = do	{ (next_phase, dflags', maybe_loc, output_fn)
		<- runPhase phase stop_phase dflags orig_basename 
			    orig_suff input_fn orig_get_output_fn maybe_loc
	; pipeLoop dflags' next_phase stop_phase output_fn
		   orig_basename orig_suff orig_get_output_fn maybe_loc }

getOutputFilename
  :: DynFlags -> Phase -> PipelineOutput -> String
  -> Phase{-next phase-} -> Maybe ModLocation -> IO FilePath
getOutputFilename dflags stop_phase output basename
 = func
 where
	hcsuf      = hcSuf dflags
	odir       = outputDir dflags
	osuf       = objectSuf dflags
	keep_hc    = dopt Opt_KeepHcFiles dflags
	keep_raw_s = dopt Opt_KeepRawSFiles dflags
	keep_s     = dopt Opt_KeepSFiles dflags

        myPhaseInputExt HCc    = hcsuf
        myPhaseInputExt StopLn = osuf
        myPhaseInputExt other  = phaseInputExt other

	func next_phase maybe_location
	   | is_last_phase, Persistent <- output     = persistent_fn
	   | is_last_phase, SpecificFile f <- output = return f
	   | keep_this_output	   		     = persistent_fn
     	   | otherwise        	   		     = newTempName dflags suffix
	   where
		is_last_phase = next_phase `eqPhase` stop_phase

		-- sometimes, we keep output from intermediate stages
		keep_this_output = 
     		     case next_phase of
     			     StopLn              -> True
     			     Mangle | keep_raw_s -> True
     			     As     | keep_s     -> True
     			     HCc    | keep_hc    -> True
     			     _other              -> False

		suffix = myPhaseInputExt next_phase

		-- persistent object files get put in odir
	        persistent_fn 
		   | StopLn <- next_phase = return odir_persistent
		   | otherwise            = return persistent

		persistent = basename ++ '.':suffix

		odir_persistent
		   | Just loc <- maybe_location = ml_obj_file loc
		   | Just d <- odir = replaceFilenameDirectory persistent d
		   | otherwise      = persistent


-- -----------------------------------------------------------------------------
-- Each phase in the pipeline returns the next phase to execute, and the
-- name of the file in which the output was placed.
--
-- We must do things dynamically this way, because we often don't know
-- what the rest of the phases will be until part-way through the
-- compilation: for example, an {-# OPTIONS -fasm #-} at the beginning
-- of a source file can change the latter stages of the pipeline from
-- taking the via-C route to using the native code generator.

runPhase :: Phase	-- Do this phase first
	 -> Phase	-- Stop just before this phase
	 -> DynFlags
	 -> String	-- basename of original input source
	 -> String	-- its extension
	 -> FilePath	-- name of file which contains the input to this phase.
	 -> (Phase -> Maybe ModLocation -> IO FilePath)
			-- how to calculate the output filename
	 -> Maybe ModLocation		-- the ModLocation, if we have one
	 -> IO (Phase,	  		-- next phase
		DynFlags,		-- new dynamic flags
		Maybe ModLocation,	-- the ModLocation, if we have one
		FilePath)		-- output filename

	-- Invariant: the output filename always contains the output
	-- Interesting case: Hsc when there is no recompilation to do
	--		     Then the output filename is still a .o file 

-------------------------------------------------------------------------------
-- Unlit phase 

runPhase (Unlit sf) _stop dflags _basename _suff input_fn get_output_fn maybe_loc
  = do let unlit_flags = getOpts dflags opt_L
       -- The -h option passes the file name for unlit to put in a #line directive
       output_fn <- get_output_fn (Cpp sf) maybe_loc

       SysTools.runUnlit dflags 
		(map SysTools.Option unlit_flags ++
       			  [ SysTools.Option     "-h"
 			  , SysTools.Option     input_fn
			  , SysTools.FileOption "" input_fn
			  , SysTools.FileOption "" output_fn
			  ])

       return (Cpp sf, dflags, maybe_loc, output_fn)

-------------------------------------------------------------------------------
-- Cpp phase : (a) gets OPTIONS out of file
--	       (b) runs cpp if necessary

runPhase (Cpp sf) _stop dflags0 basename suff input_fn get_output_fn maybe_loc
  = do src_opts <- getOptionsFromSource input_fn
       (dflags,unhandled_flags) <- parseDynamicFlags dflags0 src_opts
       checkProcessArgsResult unhandled_flags (basename++'.':suff)

       if not (dopt Opt_Cpp dflags) then
           -- no need to preprocess CPP, just pass input file along
	   -- to the next phase of the pipeline.
          return (HsPp sf, dflags, maybe_loc, input_fn)
	else do
	    output_fn <- get_output_fn (HsPp sf) maybe_loc
	    doCpp dflags True{-raw-} False{-no CC opts-} input_fn output_fn
	    return (HsPp sf, dflags, maybe_loc, output_fn)

-------------------------------------------------------------------------------
-- HsPp phase 

runPhase (HsPp sf) _stop dflags basename suff input_fn get_output_fn maybe_loc
  = do if not (dopt Opt_Pp dflags) then
           -- no need to preprocess, just pass input file along
	   -- to the next phase of the pipeline.
          return (Hsc sf, dflags, maybe_loc, input_fn)
	else do
	    let hspp_opts = getOpts dflags opt_F
	    let orig_fn = basename ++ '.':suff
	    output_fn <- get_output_fn (Hsc sf) maybe_loc
	    SysTools.runPp dflags
			   ( [ SysTools.Option     orig_fn
			     , SysTools.Option     input_fn
			     , SysTools.FileOption "" output_fn
			     ] ++
			     map SysTools.Option hspp_opts
			   )
	    return (Hsc sf, dflags, maybe_loc, output_fn)

-----------------------------------------------------------------------------
-- Hsc phase

-- Compilation of a single module, in "legacy" mode (_not_ under
-- the direction of the compilation manager).
runPhase (Hsc src_flavour) stop dflags0 basename suff input_fn get_output_fn _maybe_loc 
 = do	-- normal Hsc mode, not mkdependHS

  -- we add the current directory (i.e. the directory in which
  -- the .hs files resides) to the import path, since this is
  -- what gcc does, and it's probably what you want.
	let current_dir = directoryOf basename
	
	    paths = includePaths dflags0
	    dflags = dflags0 { includePaths = current_dir : paths }
	
  -- gather the imports and module name
        (hspp_buf,mod_name) <- 
            case src_flavour of
		ExtCoreFile -> do {  -- no explicit imports in ExtCore input.
			          ; m <- getCoreModuleName input_fn
			          ; return (Nothing, mkModule m) }

		other -> do { buf <- hGetStringBuffer input_fn
			    ; (_,_,mod_name) <- getImports dflags buf input_fn
			    ; return (Just buf, mod_name) }

  -- Build a ModLocation to pass to hscMain.
  -- The source filename is rather irrelevant by now, but it's used
  -- by hscMain for messages.  hscMain also needs 
  -- the .hi and .o filenames, and this is as good a way
  -- as any to generate them, and better than most. (e.g. takes 
  -- into accout the -osuf flags)
	location1 <- mkHomeModLocation2 dflags mod_name basename suff

  -- Boot-ify it if necessary
	let location2 | isHsBoot src_flavour = addBootSuffixLocn location1
		      | otherwise	     = location1 
					

  -- Take -ohi into account if present
  -- This can't be done in mkHomeModuleLocation because
  -- it only applies to the module being compiles
	let ohi = outputHi dflags
	    location3 | Just fn <- ohi = location2{ ml_hi_file = fn }
		      | otherwise      = location2

  -- Take -o into account if present
  -- Very like -ohi, but we must *only* do this if we aren't linking
  -- (If we're linking then the -o applies to the linked thing, not to
  -- the object file for one module.)
  -- Note the nasty duplication with the same computation in compileFile above
	let expl_o_file = outputFile dflags
	    location4 | Just ofile <- expl_o_file
		      , isNoLink (ghcLink dflags)
		      = location3 { ml_obj_file = ofile }
		      | otherwise = location3

  -- Make the ModSummary to hand to hscMain
	src_timestamp <- getModificationTime (basename ++ '.':suff)
	let
	    unused_field = panic "runPhase:ModSummary field"
		-- Some fields are not looked at by hscMain
	    mod_summary = ModSummary {	ms_mod 	     = mod_name, 
					ms_hsc_src   = src_flavour,
				 	ms_hspp_file = Just input_fn,
					ms_hspp_buf  = hspp_buf,
					ms_location  = location4,
					ms_hs_date   = src_timestamp,
					ms_obj_date  = Nothing,
					ms_imps	     = unused_field,
					ms_srcimps   = unused_field }

	    o_file = ml_obj_file location4 	-- The real object file


  -- Figure out if the source has changed, for recompilation avoidance.
  --
  -- Setting source_unchanged to True means that M.o seems
  -- to be up to date wrt M.hs; so no need to recompile unless imports have
  -- changed (which the compiler itself figures out).
  -- Setting source_unchanged to False tells the compiler that M.o is out of
  -- date wrt M.hs (or M.o doesn't exist) so we must recompile regardless.
	let do_recomp = dopt Opt_RecompChecking dflags
	source_unchanged <- 
          if not do_recomp || not (isStopLn stop)
		-- Set source_unchanged to False unconditionally if
		--	(a) recompilation checker is off, or
		-- 	(b) we aren't going all the way to .o file (e.g. ghc -S)
	     then return False	
		-- Otherwise look at file modification dates
	     else do o_file_exists <- doesFileExist o_file
		     if not o_file_exists
		        then return False	-- Need to recompile
			else do t2 <- getModificationTime o_file
			        if t2 > src_timestamp
				  then return True
				  else return False

  -- get the DynFlags
	let hsc_lang = hscMaybeAdjustTarget dflags stop src_flavour (hscTarget dflags)
	let next_phase = hscNextPhase dflags src_flavour hsc_lang
	output_fn  <- get_output_fn next_phase (Just location4)

        let dflags' = dflags { hscTarget = hsc_lang,
			       hscOutName = output_fn,
		   	       hscStubCOutName = basename ++ "_stub.c",
			       hscStubHOutName = basename ++ "_stub.h",
			       extCoreName = basename ++ ".hcr" }

	hsc_env <- newHscEnv dflags'

  -- Tell the finder cache about this module
	addHomeModuleToFinder hsc_env mod_name location4

  -- run the compiler!
	result <- hscMain hsc_env printErrorsAndWarnings
			  mod_summary source_unchanged 
			  False		-- No object file
			  Nothing	-- No iface
                          Nothing       -- No "module i of n" progress info

	case result of

	    HscFail -> throwDyn (PhaseFailed "hsc" (ExitFailure 1))

            HscNoRecomp details iface -> do
		SysTools.touch dflags' "Touching object file" o_file
			-- The .o file must have a later modification date
			-- than the source file (else we wouldn't be in HscNoRecomp)
			-- but we touch it anyway, to keep 'make' happy (we think).
		return (StopLn, dflags', Just location4, o_file)

	    HscRecomp _details _iface 
		      stub_h_exists stub_c_exists
		      _maybe_interpreted_code -> do

		-- Deal with stubs 
		maybe_stub_o <- compileStub dflags' stub_c_exists
		case maybe_stub_o of
		      Nothing     -> return ()
		      Just stub_o -> consIORef v_Ld_inputs stub_o

		-- In the case of hs-boot files, generate a dummy .o-boot 
		-- stamp file for the benefit of Make
		case src_flavour of
		  HsBootFile -> SysTools.touch dflags' "Touching object file" o_file
		  other	     -> return ()

		return (next_phase, dflags', Just location4, output_fn)

-----------------------------------------------------------------------------
-- Cmm phase

runPhase CmmCpp stop dflags basename suff input_fn get_output_fn maybe_loc
  = do
       output_fn <- get_output_fn Cmm maybe_loc
       doCpp dflags False{-not raw-} True{-include CC opts-} input_fn output_fn	
       return (Cmm, dflags, maybe_loc, output_fn)

runPhase Cmm stop dflags basename suff input_fn get_output_fn maybe_loc
  = do
	let hsc_lang = hscMaybeAdjustTarget dflags stop HsSrcFile (hscTarget dflags)
	let next_phase = hscNextPhase dflags HsSrcFile hsc_lang
	output_fn <- get_output_fn next_phase maybe_loc

        let dflags' = dflags { hscTarget = hsc_lang,
			       hscOutName = output_fn,
		   	       hscStubCOutName = basename ++ "_stub.c",
			       hscStubHOutName = basename ++ "_stub.h",
			       extCoreName = basename ++ ".hcr" }

	ok <- hscCmmFile dflags' input_fn

	when (not ok) $ throwDyn (PhaseFailed "cmm" (ExitFailure 1))

	return (next_phase, dflags, maybe_loc, output_fn)

-----------------------------------------------------------------------------
-- Cc phase

-- we don't support preprocessing .c files (with -E) now.  Doing so introduces
-- way too many hacks, and I can't say I've ever used it anyway.

runPhase cc_phase stop dflags basename suff input_fn get_output_fn maybe_loc
   | cc_phase `eqPhase` Cc || cc_phase `eqPhase` HCc
   = do	let cc_opts = getOpts dflags opt_c
	    hcc = cc_phase `eqPhase` HCc

       	let cmdline_include_paths = includePaths dflags

	-- HC files have the dependent packages stamped into them
	pkgs <- if hcc then getHCFilePackages input_fn else return []

	-- add package include paths even if we're just compiling .c
	-- files; this is the Value Add(TM) that using ghc instead of
	-- gcc gives you :)
        pkg_include_dirs <- getPackageIncludePath dflags pkgs
        let include_paths = foldr (\ x xs -> "-I" : x : xs) []
			      (cmdline_include_paths ++ pkg_include_dirs)

	let (md_c_flags, md_regd_c_flags) = machdepCCOpts dflags
        let pic_c_flags = picCCOpts dflags

        let verb = getVerbFlag dflags

	pkg_extra_cc_opts <- getPackageExtraCcOpts dflags pkgs

	let split_objs = dopt Opt_SplitObjs dflags
	    split_opt | hcc && split_objs = [ "-DUSE_SPLIT_MARKERS" ]
		      | otherwise         = [ ]

	let excessPrecision = dopt Opt_ExcessPrecision dflags

	-- Decide next phase
	
        let mangle = dopt Opt_DoAsmMangling dflags
            next_phase
		| hcc && mangle     = Mangle
		| otherwise         = As
	output_fn <- get_output_fn next_phase maybe_loc

	-- force the C compiler to interpret this file as C when
	-- compiling .hc files, by adding the -x c option.
	let langopt | hcc = [ SysTools.Option "-x", SysTools.Option "c"]
		    | otherwise = [ ]

	SysTools.runCc dflags (langopt ++
			[ SysTools.FileOption "" input_fn
			, SysTools.Option "-o"
			, SysTools.FileOption "" output_fn
			]
		       ++ map SysTools.Option (
		          md_c_flags
                       ++ pic_c_flags
		       ++ (if hcc && mangle
		  	     then md_regd_c_flags
		  	     else [])
		       ++ [ verb, "-S", "-Wimplicit", "-O" ]
		       ++ [ "-D__GLASGOW_HASKELL__="++cProjectVersionInt ]
		       ++ cc_opts
		       ++ split_opt
		       ++ (if excessPrecision then [] else [ "-ffloat-store" ])
		       ++ include_paths
		       ++ pkg_extra_cc_opts
		       ))

	return (next_phase, dflags, maybe_loc, output_fn)

	-- ToDo: postprocess the output from gcc

-----------------------------------------------------------------------------
-- Mangle phase

runPhase Mangle stop dflags _basename _suff input_fn get_output_fn maybe_loc
   = do let mangler_opts = getOpts dflags opt_m

#if i386_TARGET_ARCH
        machdep_opts <- return [ show (stolen_x86_regs dflags) ]
#else
	machdep_opts <- return []
#endif

	let split = dopt Opt_SplitObjs dflags
            next_phase
		| split = SplitMangle
		| otherwise = As
	output_fn <- get_output_fn next_phase maybe_loc

	SysTools.runMangle dflags (map SysTools.Option mangler_opts
		          ++ [ SysTools.FileOption "" input_fn
			     , SysTools.FileOption "" output_fn
			     ]
			  ++ map SysTools.Option machdep_opts)

	return (next_phase, dflags, maybe_loc, output_fn)

-----------------------------------------------------------------------------
-- Splitting phase

runPhase SplitMangle stop dflags _basename _suff input_fn get_output_fn maybe_loc
  = do  -- tmp_pfx is the prefix used for the split .s files
	-- We also use it as the file to contain the no. of split .s files (sigh)
	split_s_prefix <- SysTools.newTempName dflags "split"
	let n_files_fn = split_s_prefix

	SysTools.runSplit dflags
			  [ SysTools.FileOption "" input_fn
			  , SysTools.FileOption "" split_s_prefix
			  , SysTools.FileOption "" n_files_fn
			  ]

	-- Save the number of split files for future references
	s <- readFile n_files_fn
	let n_files = read s :: Int
	writeIORef v_Split_info (split_s_prefix, n_files)

	-- Remember to delete all these files
	addFilesToClean [ split_s_prefix ++ "__" ++ show n ++ ".s"
			| n <- [1..n_files]]

	return (SplitAs, dflags, maybe_loc, "**splitmangle**")
	  -- we don't use the filename

-----------------------------------------------------------------------------
-- As phase

runPhase As stop dflags _basename _suff input_fn get_output_fn maybe_loc
  = do	let as_opts =  getOpts dflags opt_a
        let cmdline_include_paths = includePaths dflags

	output_fn <- get_output_fn StopLn maybe_loc

	-- we create directories for the object file, because it
	-- might be a hierarchical module.
	createDirectoryHierarchy (directoryOf output_fn)

	SysTools.runAs dflags	
		       (map SysTools.Option as_opts
		       ++ [ SysTools.Option ("-I" ++ p) | p <- cmdline_include_paths ]
		       ++ [ SysTools.Option "-c"
		          , SysTools.FileOption "" input_fn
			  , SysTools.Option "-o"
			  , SysTools.FileOption "" output_fn
			  ])

	return (StopLn, dflags, maybe_loc, output_fn)


runPhase SplitAs stop dflags basename _suff _input_fn get_output_fn maybe_loc
  = do  let as_opts = getOpts dflags opt_a