HscMain.hs 72.8 KB
Newer Older
1
{-# LANGUAGE BangPatterns, CPP, MagicHash, NondecreasingIndentation #-}
Simon Marlow's avatar
Simon Marlow committed
2
{-# OPTIONS_GHC -fprof-auto-top #-}
3

dterei's avatar
dterei committed
4 5
-------------------------------------------------------------------------------
--
6
-- | Main API for compiling plain Haskell source code.
7
--
dterei's avatar
dterei committed
8
-- This module implements compilation of a Haskell source. It is
9 10 11 12 13
-- /not/ concerned with preprocessing of source files; this is handled
-- in "DriverPipeline".
--
-- There are various entry points depending on what mode we're in:
-- "batch" mode (@--make@), "one-shot" mode (@-c@, @-S@ etc.), and
dterei's avatar
dterei committed
14
-- "interactive" mode (GHCi). There are also entry points for
15 16 17 18 19 20 21 22
-- individual passes: parsing, typechecking/renaming, desugaring, and
-- simplification.
--
-- All the functions here take an 'HscEnv' as a parameter, but none of
-- them return a new one: 'HscEnv' is treated as an immutable value
-- from here on in (although it has mutable components, for the
-- caches).
--
23 24 25 26 27
-- We use the Hsc monad to deal with warning messages consistently:
-- specifically, while executing within an Hsc monad, warnings are
-- collected. When a Hsc monad returns to an IO monad, the
-- warnings are printed, or compilation aborts if the @-Werror@
-- flag is enabled.
28
--
dterei's avatar
dterei committed
29 30 31 32
-- (c) The GRASP/AQUA Project, Glasgow University, 1993-2000
--
-------------------------------------------------------------------------------

33
module HscMain
dterei's avatar
dterei committed
34
    (
35 36 37 38
    -- * Making an HscEnv
      newHscEnv

    -- * Compiling complete source files
39 40
    , Messager, batchMsg
    , HscStatus (..)
41
    , hscIncrementalCompile
42 43
    , hscCompileCmmFile

44 45 46
    , hscGenHardCode
    , hscInteractive

47
    -- * Running passes separately
Thomas Schilling's avatar
Thomas Schilling committed
48 49 50
    , hscParse
    , hscTypecheckRename
    , hscDesugar
Simon Marlow's avatar
Simon Marlow committed
51
    , makeSimpleDetails
52 53
    , hscSimplify -- ToDo, shouldn't really export this

54 55 56 57
    -- * Safe Haskell
    , hscCheckSafe
    , hscGetSafe

58 59 60 61
    -- * Support for interactive evaluation
    , hscParseIdentifier
    , hscTcRcLookupName
    , hscTcRnGetInfo
dterei's avatar
dterei committed
62
    , hscIsGHCiMonad
63
    , hscGetModuleInterface
64
    , hscRnImportDecls
65
    , hscTcRnLookupRdrName
66
    , hscStmt, hscStmtWithLocation, hscParsedStmt
67
    , hscDecls, hscDeclsWithLocation
68
    , hscTcExpr, TcRnExprMode(..), hscImport, hscKcType
69
    , hscParseExpr
70
    , hscCompileCoreExpr
71 72
    -- * Low-level exports for hooks
    , hscCompileCoreExpr'
Edsko de Vries's avatar
Edsko de Vries committed
73 74
      -- We want to make sure that we export enough to be able to redefine
      -- hscFileFrontEnd in client code
75
    , hscParse', hscSimplify', hscDesugar', tcRnModule'
Edsko de Vries's avatar
Edsko de Vries committed
76
    , getHscEnv
77 78 79
    , hscSimpleIface', hscNormalIface'
    , oneShotMsg
    , hscFileFrontEnd, genericHscFrontend, dumpIfaceStats
Edward Z. Yang's avatar
Edward Z. Yang committed
80 81
    , ioMsgMaybe
    , showModuleIndex
82
    , hscAddSptEntries
83
    ) where
84

85
import Data.Data hiding (Fixity, TyCon)
Simon Marlow's avatar
Simon Marlow committed
86
import Id
87
import GHCi             ( addSptEntry )
88
import GHCi.RemoteTypes ( ForeignHValue )
89
import ByteCodeGen      ( byteCodeGen, coreExprToBCOs )
90
import Linker
91
import CoreTidy         ( tidyExpr )
92 93
import Type             ( Type )
import {- Kind parts of -} Type         ( Kind )
94
import CoreLint         ( lintInteractiveExpr )
95
import VarEnv           ( emptyTidyEnv )
96
import Panic
97
import ConLike
98
import Control.Concurrent
99

100 101
import Module
import Packages
Simon Marlow's avatar
Simon Marlow committed
102 103
import RdrName
import HsSyn
104
import HsDumpAst
105
import CoreSyn
Ian Lynagh's avatar
Ian Lynagh committed
106
import StringBuffer
107
import Parser
108
import Lexer
109 110
import SrcLoc
import TcRnDriver
111
import TcIface          ( typecheckIface )
112
import TcRnMonad
113
import NameCache        ( initNameCache )
114
import LoadIface        ( ifaceStats, initExternalPackageState )
115
import PrelInfo
Simon Marlow's avatar
Simon Marlow committed
116
import MkIface
117 118
import Desugar
import SimplCore
Simon Marlow's avatar
Simon Marlow committed
119
import TidyPgm
120
import CorePrep
121 122
import CoreToStg        ( coreToStg )
import qualified StgCmm ( codeGen )
123 124
import StgSyn
import CostCentre
125
import ProfInit
126 127
import TyCon
import Name
128
import SimplStg         ( stg2stg )
129
import Cmm
130
import CmmParse         ( parseCmmFile )
131
import CmmBuildInfoTables
Edward Z. Yang's avatar
Edward Z. Yang committed
132
import CmmPipeline
133
import CmmInfo
134 135
import CodeOutput
import InstEnv
136
import FamInstEnv
Thomas Schilling's avatar
Thomas Schilling committed
137
import Fingerprint      ( Fingerprint )
138
import Hooks
Edward Z. Yang's avatar
Edward Z. Yang committed
139
import TcEnv
140

141
import DynFlags
142
import ErrUtils
143
import Platform ( platformOS, osSubsectionsViaSymbols )
144

145
import Outputable
eir@cis.upenn.edu's avatar
eir@cis.upenn.edu committed
146
import NameEnv
147
import HscStats         ( ppSourceStats )
148
import HscTypes
149
import FastString
150
import UniqSupply
151
import Bag
Thomas Schilling's avatar
Thomas Schilling committed
152
import Exception
153 154 155
import qualified Stream
import Stream (Stream)

156
import Util
Simon Marlow's avatar
Simon Marlow committed
157

158
import Data.List
Simon Marlow's avatar
Simon Marlow committed
159 160
import Control.Monad
import Data.IORef
161
import System.FilePath as FilePath
162
import System.Directory
163
import System.IO (fixIO)
Alan Zimmerman's avatar
Alan Zimmerman committed
164
import qualified Data.Map as Map
165 166
import qualified Data.Set as S
import Data.Set (Set)
dterei's avatar
dterei committed
167

Thomas Schilling's avatar
Thomas Schilling committed
168
#include "HsVersions.h"
169

170

dterei's avatar
dterei committed
171 172 173 174 175
{- **********************************************************************
%*                                                                      *
                Initialisation
%*                                                                      *
%********************************************************************* -}
176

177
newHscEnv :: DynFlags -> IO HscEnv
178
newHscEnv dflags = do
dterei's avatar
dterei committed
179 180
    eps_var <- newIORef initExternalPackageState
    us      <- mkSplitUniqSupply 'r'
181
    nc_var  <- newIORef (initNameCache us knownKeyNames)
182
    fc_var  <- newIORef emptyInstalledModuleEnv
183 184 185 186 187 188 189 190 191 192 193 194
    iserv_mvar <- newMVar Nothing
    return HscEnv {  hsc_dflags       = dflags
                  ,  hsc_targets      = []
                  ,  hsc_mod_graph    = []
                  ,  hsc_IC           = emptyInteractiveContext dflags
                  ,  hsc_HPT          = emptyHomePackageTable
                  ,  hsc_EPS          = eps_var
                  ,  hsc_NC           = nc_var
                  ,  hsc_FC           = fc_var
                  ,  hsc_type_env_var = Nothing
                  , hsc_iserv        = iserv_mvar
                  }
Thomas Schilling's avatar
Thomas Schilling committed
195

196
-- -----------------------------------------------------------------------------
197

198
getWarnings :: Hsc WarningMessages
dterei's avatar
dterei committed
199
getWarnings = Hsc $ \_ w -> return (w, w)
200 201

clearWarnings :: Hsc ()
dterei's avatar
dterei committed
202
clearWarnings = Hsc $ \_ _ -> return ((), emptyBag)
203 204

logWarnings :: WarningMessages -> Hsc ()
dterei's avatar
dterei committed
205
logWarnings w = Hsc $ \_ w0 -> return ((), w0 `unionBags` w)
206 207

getHscEnv :: Hsc HscEnv
dterei's avatar
dterei committed
208
getHscEnv = Hsc $ \e w -> return (e, w)
209 210 211

handleWarnings :: Hsc ()
handleWarnings = do
dterei's avatar
dterei committed
212 213 214 215
    dflags <- getDynFlags
    w <- getWarnings
    liftIO $ printOrThrowWarnings dflags w
    clearWarnings
216 217 218 219 220

-- | log warning in the monad, and if there are errors then
-- throw a SourceError exception.
logWarningsReportErrors :: Messages -> Hsc ()
logWarningsReportErrors (warns,errs) = do
dterei's avatar
dterei committed
221 222
    logWarnings warns
    when (not $ isEmptyBag errs) $ throwErrors errs
223 224 225 226

-- | Throw some errors.
throwErrors :: ErrorMessages -> Hsc a
throwErrors = liftIO . throwIO . mkSrcErr
227 228 229 230 231

-- | Deal with errors and warnings returned by a compilation step
--
-- In order to reduce dependencies to other parts of the compiler, functions
-- outside the "main" parts of GHC return warnings and errors as a parameter
dterei's avatar
dterei committed
232
-- and signal success via by wrapping the result in a 'Maybe' type. This
233 234 235 236 237 238 239 240 241
-- function logs the returned warnings and propagates errors as exceptions
-- (of type 'SourceError').
--
-- This function assumes the following invariants:
--
--  1. If the second result indicates success (is of the form 'Just x'),
--     there must be no error messages in the first result.
--
--  2. If there are no error messages, but the second result indicates failure
dterei's avatar
dterei committed
242
--     there should be warnings in the first result. That is, if the action
243 244 245
--     failed, it must have been due to the warnings (i.e., @-Werror@).
ioMsgMaybe :: IO (Messages, Maybe a) -> Hsc a
ioMsgMaybe ioA = do
246
    ((warns,errs), mb_r) <- liftIO ioA
dterei's avatar
dterei committed
247 248 249 250
    logWarnings warns
    case mb_r of
        Nothing -> throwErrors errs
        Just r  -> ASSERT( isEmptyBag errs ) return r
251 252 253 254 255

-- | like ioMsgMaybe, except that we ignore error messages and return
-- 'Nothing' instead.
ioMsgMaybe' :: IO (Messages, Maybe a) -> Hsc (Maybe a)
ioMsgMaybe' ioA = do
dterei's avatar
dterei committed
256 257 258
    ((warns,_errs), mb_r) <- liftIO $ ioA
    logWarnings warns
    return mb_r
259 260 261 262

-- -----------------------------------------------------------------------------
-- | Lookup things in the compiler's environment

263
hscTcRnLookupRdrName :: HscEnv -> Located RdrName -> IO [Name]
264 265
hscTcRnLookupRdrName hsc_env0 rdr_name
  = runInteractiveHsc hsc_env0 $
266 267
    do { hsc_env <- getHscEnv
       ; ioMsgMaybe $ tcRnLookupRdrName hsc_env rdr_name }
268 269

hscTcRcLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
270 271 272
hscTcRcLookupName hsc_env0 name = runInteractiveHsc hsc_env0 $ do
  hsc_env <- getHscEnv
  ioMsgMaybe' $ tcRnLookupName hsc_env name
dterei's avatar
dterei committed
273 274 275
      -- ignore errors: the only error we're likely to get is
      -- "name not found", and the Maybe in the return type
      -- is used to indicate that.
276

277
hscTcRnGetInfo :: HscEnv -> Name -> IO (Maybe (TyThing, Fixity, [ClsInst], [FamInst]))
278 279 280 281
hscTcRnGetInfo hsc_env0 name
  = runInteractiveHsc hsc_env0 $
    do { hsc_env <- getHscEnv
       ; ioMsgMaybe' $ tcRnGetInfo hsc_env name }
282

dterei's avatar
dterei committed
283
hscIsGHCiMonad :: HscEnv -> String -> IO Name
Edsko de Vries's avatar
Edsko de Vries committed
284
hscIsGHCiMonad hsc_env name
285
  = runHsc hsc_env $ ioMsgMaybe $ isGHCiMonad hsc_env name
dterei's avatar
dterei committed
286

287
hscGetModuleInterface :: HscEnv -> Module -> IO ModIface
288 289 290
hscGetModuleInterface hsc_env0 mod = runInteractiveHsc hsc_env0 $ do
  hsc_env <- getHscEnv
  ioMsgMaybe $ getModuleInterface hsc_env mod
291 292 293

-- -----------------------------------------------------------------------------
-- | Rename some import declarations
294
hscRnImportDecls :: HscEnv -> [LImportDecl RdrName] -> IO GlobalRdrEnv
295 296 297
hscRnImportDecls hsc_env0 import_decls = runInteractiveHsc hsc_env0 $ do
  hsc_env <- getHscEnv
  ioMsgMaybe $ tcRnImportDecls hsc_env import_decls
298

299
-- -----------------------------------------------------------------------------
Simon Marlow's avatar
Simon Marlow committed
300
-- | parse a file, returning the abstract syntax
301

302
hscParse :: HscEnv -> ModSummary -> IO HsParsedModule
303 304 305
hscParse hsc_env mod_summary = runHsc hsc_env $ hscParse' mod_summary

-- internal version, that doesn't fail due to -Werror
306
hscParse' :: ModSummary -> Hsc HsParsedModule
Edward Z. Yang's avatar
Edward Z. Yang committed
307 308 309
hscParse' mod_summary
 | Just r <- ms_parsed_mod mod_summary = return r
 | otherwise = {-# SCC "Parser" #-}
310 311 312
    withTiming getDynFlags
               (text "Parser"<+>brackets (ppr $ ms_mod mod_summary))
               (const ()) $ do
dterei's avatar
dterei committed
313 314 315
    dflags <- getDynFlags
    let src_filename  = ms_hspp_file mod_summary
        maybe_src_buf = ms_hspp_buf  mod_summary
316

dterei's avatar
dterei committed
317
    --------------------------  Parser  ----------------
318 319 320
    -- sometimes we already have the buffer in memory, perhaps
    -- because we needed to parse the imports out of it, or get the
    -- module name.
dterei's avatar
dterei committed
321 322 323
    buf <- case maybe_src_buf of
               Just b  -> return b
               Nothing -> liftIO $ hGetStringBuffer src_filename
324

dterei's avatar
dterei committed
325
    let loc = mkRealSrcLoc (mkFastString src_filename) 1 1
Edward Z. Yang's avatar
Edward Z. Yang committed
326 327 328
    let parseMod | HsigFile == ms_hsc_src mod_summary
                 = parseSignature
                 | otherwise = parseModule
329

Edward Z. Yang's avatar
Edward Z. Yang committed
330
    case unP parseMod (mkPState dflags buf loc) of
dterei's avatar
dterei committed
331
        PFailed span err ->
Ian Lynagh's avatar
Ian Lynagh committed
332
            liftIO $ throwOneError (mkPlainErrMsg dflags span err)
333

dterei's avatar
dterei committed
334
        POk pst rdr_module -> do
335
            logWarningsReportErrors (getMessages pst dflags)
dterei's avatar
dterei committed
336 337
            liftIO $ dumpIfSet_dyn dflags Opt_D_dump_parsed "Parser" $
                                   ppr rdr_module
338 339
            liftIO $ dumpIfSet_dyn dflags Opt_D_dump_parsed_ast "Parser AST" $
                                   text (showAstData NoBlankSrcSpan rdr_module)
dterei's avatar
dterei committed
340 341
            liftIO $ dumpIfSet_dyn dflags Opt_D_source_stats "Source Statistics" $
                                   ppSourceStats False rdr_module
342 343 344 345 346

            -- To get the list of extra source files, we take the list
            -- that the parser gave us,
            --   - eliminate files beginning with '<'.  gcc likes to use
            --     pseudo-filenames like "<built-in>" and "<command-line>"
Gabor Greif's avatar
Gabor Greif committed
347
            --   - normalise them (eliminate differences between ./f and f)
348 349 350 351 352 353 354 355 356
            --   - filter out the preprocessed source file
            --   - filter out anything beginning with tmpdir
            --   - remove duplicates
            --   - filter out the .hs/.lhs source filename if we have one
            --
            let n_hspp  = FilePath.normalise src_filename
                srcs0 = nub $ filter (not . (tmpDir dflags `isPrefixOf`))
                            $ filter (not . (== n_hspp))
                            $ map FilePath.normalise
357
                            $ filter (not . (isPrefixOf "<"))
358 359 360 361 362 363
                            $ map unpackFS
                            $ srcfiles pst
                srcs1 = case ml_hs_file (ms_location mod_summary) of
                          Just f  -> filter (/= FilePath.normalise f) srcs0
                          Nothing -> srcs0

364 365 366 367 368
            -- sometimes we see source files from earlier
            -- preprocessing stages that cannot be found, so just
            -- filter them out:
            srcs2 <- liftIO $ filterM doesFileExist srcs1

369 370
            return HsParsedModule {
                      hpm_module    = rdr_module,
Alan Zimmerman's avatar
Alan Zimmerman committed
371 372 373 374 375
                      hpm_src_files = srcs2,
                      hpm_annotations
                              = (Map.fromListWith (++) $ annotations pst,
                                 Map.fromList $ ((noSrcSpan,comment_q pst)
                                                 :(annotations_comments pst)))
376
                   }
Simon Marlow's avatar
Simon Marlow committed
377

Thomas Schilling's avatar
Thomas Schilling committed
378 379 380
-- XXX: should this really be a Maybe X?  Check under which circumstances this
-- can become a Nothing and decide whether this should instead throw an
-- exception/signal an error.
dterei's avatar
dterei committed
381
type RenamedStuff =
Simon Marlow's avatar
Simon Marlow committed
382
        (Maybe (HsGroup Name, [LImportDecl Name], Maybe [LIE Name],
383
                Maybe LHsDocString))
Simon Marlow's avatar
Simon Marlow committed
384

Thomas Schilling's avatar
Thomas Schilling committed
385
-- | Rename and typecheck a module, additionally returning the renamed syntax
386
hscTypecheckRename :: HscEnv -> ModSummary -> HsParsedModule
387
                   -> IO (TcGblEnv, RenamedStuff)
dterei's avatar
dterei committed
388
hscTypecheckRename hsc_env mod_summary rdr_module = runHsc hsc_env $ do
Edward Z. Yang's avatar
Edward Z. Yang committed
389
    tc_result <- hscTypecheck True mod_summary (Just rdr_module)
Thomas Schilling's avatar
Thomas Schilling committed
390

391 392 393 394 395 396
        -- This 'do' is in the Maybe monad!
    let rn_info = do decl <- tcg_rn_decls tc_result
                     let imports = tcg_rn_imports tc_result
                         exports = tcg_rn_exports tc_result
                         doc_hdr = tcg_doc_hdr tc_result
                     return (decl,imports,exports,doc_hdr)
Thomas Schilling's avatar
Thomas Schilling committed
397

398
    return (tc_result, rn_info)
Simon Marlow's avatar
Simon Marlow committed
399

Edward Z. Yang's avatar
Edward Z. Yang committed
400 401 402 403 404 405 406 407
hscTypecheck :: Bool -- ^ Keep renamed source?
             -> ModSummary -> Maybe HsParsedModule
             -> Hsc TcGblEnv
hscTypecheck keep_rn mod_summary mb_rdr_module = do
    hsc_env <- getHscEnv
    let hsc_src = ms_hsc_src mod_summary
        dflags = hsc_dflags hsc_env
        outer_mod = ms_mod mod_summary
408 409 410
        mod_name = moduleName outer_mod
        outer_mod' = mkModule (thisPackage dflags) mod_name
        inner_mod = canonicalizeHomeModule dflags mod_name
Edward Z. Yang's avatar
Edward Z. Yang committed
411 412 413 414
        src_filename  = ms_hspp_file mod_summary
        real_loc = realSrcLocSpan $ mkRealSrcLoc (mkFastString src_filename) 1 1
    MASSERT( moduleUnitId outer_mod == thisPackage dflags )
    if hsc_src == HsigFile && not (isHoleModule inner_mod)
415
        then ioMsgMaybe $ tcRnInstantiateSignature hsc_env outer_mod' real_loc
Edward Z. Yang's avatar
Edward Z. Yang committed
416 417 418 419 420 421 422 423
        else
         do hpm <- case mb_rdr_module of
                    Just hpm -> return hpm
                    Nothing -> hscParse' mod_summary
            tc_result0 <- tcRnModule' hsc_env mod_summary keep_rn hpm
            if hsc_src == HsigFile
                then do (iface, _, _) <- liftIO $ hscSimpleIface hsc_env tc_result0 Nothing
                        ioMsgMaybe $
424
                            tcRnMergeSignatures hsc_env hpm tc_result0 iface
Edward Z. Yang's avatar
Edward Z. Yang committed
425 426
                else return tc_result0

427 428 429 430 431 432 433 434
-- wrapper around tcRnModule to handle safe haskell extras
tcRnModule' :: HscEnv -> ModSummary -> Bool -> HsParsedModule
            -> Hsc TcGblEnv
tcRnModule' hsc_env sum save_rn_syntax mod = do
    tcg_res <- {-# SCC "Typecheck-Rename" #-}
               ioMsgMaybe $
                   tcRnModule hsc_env (ms_hsc_src sum) save_rn_syntax mod

435 436 437
    -- See Note [Safe Haskell Overlapping Instances Implementation]
    -- although this is used for more than just that failure case.
    (tcSafeOK, whyUnsafe) <- liftIO $ readIORef (tcg_safeInfer tcg_res)
438
    dflags   <- getDynFlags
439
    let allSafeOK = safeInferred dflags && tcSafeOK
440

441 442 443
    -- end of the safe haskell line, how to respond to user?
    if not (safeHaskellOn dflags) || (safeInferOn dflags && not allSafeOK)
        -- if safe Haskell off or safe infer failed, mark unsafe
444
        then markUnsafeInfer tcg_res whyUnsafe
445

446
        -- module (could be) safe, throw warning if needed
447 448
        else do
            tcg_res' <- hscCheckSafeImports tcg_res
449
            safe <- liftIO $ fst <$> readIORef (tcg_safeInfer tcg_res')
450 451
            when safe $ do
              case wopt Opt_WarnSafe dflags of
452 453 454 455
                True -> (logWarnings $ unitBag $
                         makeIntoWarning (Reason Opt_WarnSafe) $
                         mkPlainWarnMsg dflags (warnSafeOnLoc dflags) $
                         errSafe tcg_res')
456 457
                False | safeHaskell dflags == Sf_Trustworthy &&
                        wopt Opt_WarnTrustworthySafe dflags ->
458 459 460 461
                        (logWarnings $ unitBag $
                         makeIntoWarning (Reason Opt_WarnTrustworthySafe) $
                         mkPlainWarnMsg dflags (trustworthyOnLoc dflags) $
                         errTwthySafe tcg_res')
462
                False -> return ()
463 464 465
            return tcg_res'
  where
    pprMod t  = ppr $ moduleName $ tcg_mod t
466
    errSafe t = quotes (pprMod t) <+> text "has been inferred as safe!"
467 468
    errTwthySafe t = quotes (pprMod t)
      <+> text "is marked as Trustworthy but has been inferred as safe!"
469

Simon Marlow's avatar
Simon Marlow committed
470
-- | Convert a typechecked module to Core
471
hscDesugar :: HscEnv -> ModSummary -> TcGblEnv -> IO ModGuts
472
hscDesugar hsc_env mod_summary tc_result =
Ian Lynagh's avatar
Ian Lynagh committed
473
    runHsc hsc_env $ hscDesugar' (ms_location mod_summary) tc_result
474

Ian Lynagh's avatar
Ian Lynagh committed
475 476
hscDesugar' :: ModLocation -> TcGblEnv -> Hsc ModGuts
hscDesugar' mod_location tc_result = do
dterei's avatar
dterei committed
477
    hsc_env <- getHscEnv
Simon Marlow's avatar
Simon Marlow committed
478 479
    r <- ioMsgMaybe $
      {-# SCC "deSugar" #-}
Ian Lynagh's avatar
Ian Lynagh committed
480
      deSugar hsc_env mod_location tc_result
481

dterei's avatar
dterei committed
482 483 484 485
    -- always check -Werror after desugaring, this is the last opportunity for
    -- warnings to arise before the backend.
    handleWarnings
    return r
Simon Marlow's avatar
Simon Marlow committed
486

dterei's avatar
dterei committed
487
-- | Make a 'ModDetails' from the results of typechecking. Used when
Simon Marlow's avatar
Simon Marlow committed
488
-- typechecking only, as opposed to full compilation.
489 490
makeSimpleDetails :: HscEnv -> TcGblEnv -> IO ModDetails
makeSimpleDetails hsc_env tc_result = mkBootModDetailsTc hsc_env tc_result
Simon Marlow's avatar
Simon Marlow committed
491

492

dterei's avatar
dterei committed
493 494 495 496 497 498 499
{- **********************************************************************
%*                                                                      *
                The main compiler pipeline
%*                                                                      *
%********************************************************************* -}

{-
500 501 502 503
                   --------------------------------
                        The compilation proper
                   --------------------------------

dterei's avatar
dterei committed
504 505 506 507 508 509
It's the task of the compilation proper to compile Haskell, hs-boot and core
files to either byte-code, hard-code (C, asm, LLVM, ect) or to nothing at all
(the module is still parsed and type-checked. This feature is mostly used by
IDE's and the likes). Compilation can happen in either 'one-shot', 'batch',
'nothing', or 'interactive' mode. 'One-shot' mode targets hard-code, 'batch'
mode targets hard-code, 'nothing' mode targets nothing and 'interactive' mode
510
targets byte-code.
dterei's avatar
dterei committed
511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535

The modes are kept separate because of their different types and meanings:

 * In 'one-shot' mode, we're only compiling a single file and can therefore
 discard the new ModIface and ModDetails. This is also the reason it only
 targets hard-code; compiling to byte-code or nothing doesn't make sense when
 we discard the result.

 * 'Batch' mode is like 'one-shot' except that we keep the resulting ModIface
 and ModDetails. 'Batch' mode doesn't target byte-code since that require us to
 return the newly compiled byte-code.

 * 'Nothing' mode has exactly the same type as 'batch' mode but they're still
 kept separate. This is because compiling to nothing is fairly special: We
 don't output any interface files, we don't run the simplifier and we don't
 generate any code.

 * 'Interactive' mode is similar to 'batch' mode except that we return the
 compiled byte-code together with the ModIface and ModDetails.

Trying to compile a hs-boot file to byte-code will result in a run-time error.
This is the only thing that isn't caught by the type-system.
-}


536 537
type Messager = HscEnv -> (Int,Int) -> RecompileRequired -> ModSummary -> IO ()

538 539 540 541 542 543 544 545 546 547 548 549 550 551 552
-- | This function runs GHC's frontend with recompilation
-- avoidance. Specifically, it checks if recompilation is needed,
-- and if it is, it parses and typechecks the input module.
-- It does not write out the results of typechecking (See
-- compileOne and hscIncrementalCompile).
hscIncrementalFrontend :: Bool -- always do basic recompilation check?
                       -> Maybe TcGblEnv
                       -> Maybe Messager
                       -> ModSummary
                       -> SourceModified
                       -> Maybe ModIface  -- Old interface, if available
                       -> (Int,Int)       -- (i,n) = module i of n (for msgs)
                       -> Hsc (Either ModIface (FrontendResult, Maybe Fingerprint))

hscIncrementalFrontend
Simon Marlow's avatar
Simon Marlow committed
553
  always_do_basic_recompilation_check m_tc_result
554
  mHscMessage mod_summary source_modified mb_old_iface mod_index
555
    = do
556
    hsc_env <- getHscEnv
557 558 559 560

    let msg what = case mHscMessage of
                   Just hscMessage -> hscMessage hsc_env mod_index what mod_summary
                   Nothing -> return ()
dterei's avatar
dterei committed
561

562
        skip iface = do
563
            liftIO $ msg UpToDate
564
            return $ Left iface
dterei's avatar
dterei committed
565

566
        compile mb_old_hash reason = do
567 568 569
            liftIO $ msg reason
            result <- genericHscFrontend mod_summary
            return $ Right (result, mb_old_hash)
dterei's avatar
dterei committed
570 571 572 573

        stable = case source_modified of
                     SourceUnmodifiedAndStable -> True
                     _                         -> False
574

575 576 577
    case m_tc_result of
         Just tc_result
          | not always_do_basic_recompilation_check ->
578
             return $ Right (FrontendTypecheck tc_result, Nothing)
579 580 581
         _ -> do
            (recomp_reqd, mb_checked_iface)
                <- {-# SCC "checkOldIface" #-}
582
                   liftIO $ checkOldIface hsc_env mod_summary
583 584 585 586 587 588 589 590
                                source_modified mb_old_iface
            -- save the interface that comes back from checkOldIface.
            -- In one-shot mode we don't have the old iface until this
            -- point, when checkOldIface reads it from the disk.
            let mb_old_hash = fmap mi_iface_hash mb_checked_iface

            case mb_checked_iface of
                Just iface | not (recompileRequired recomp_reqd) ->
Simon Marlow's avatar
Simon Marlow committed
591 592 593 594 595 596 597 598 599 600 601 602 603
                    -- If the module used TH splices when it was last
                    -- compiled, then the recompilation check is not
                    -- accurate enough (#481) and we must ignore
                    -- it.  However, if the module is stable (none of
                    -- the modules it depends on, directly or
                    -- indirectly, changed), then we *can* skip
                    -- recompilation. This is why the SourceModified
                    -- type contains SourceUnmodifiedAndStable, and
                    -- it's pretty important: otherwise ghc --make
                    -- would always recompile TH modules, even if
                    -- nothing at all has changed. Stability is just
                    -- the same check that make is doing for us in
                    -- one-shot mode.
604 605 606 607 608 609 610 611 612 613
                    case m_tc_result of
                    Nothing
                     | mi_used_th iface && not stable ->
                        compile mb_old_hash (RecompBecause "TH")
                    _ ->
                        skip iface
                _ ->
                    case m_tc_result of
                    Nothing -> compile mb_old_hash recomp_reqd
                    Just tc_result ->
614
                        return $ Right (FrontendTypecheck tc_result, mb_old_hash)
615

616
genericHscFrontend :: ModSummary -> Hsc FrontendResult
617 618 619
genericHscFrontend mod_summary =
  getHooked hscFrontendHook genericHscFrontend' >>= ($ mod_summary)

620 621 622
genericHscFrontend' :: ModSummary -> Hsc FrontendResult
genericHscFrontend' mod_summary
    = FrontendTypecheck `fmap` hscFileFrontEnd mod_summary
623

624 625 626 627
--------------------------------------------------------------
-- Compilers
--------------------------------------------------------------

Austin Seipp's avatar
Austin Seipp committed
628
-- Compile Haskell/boot in OneShot mode.
629 630 631 632 633 634 635 636 637 638 639 640 641
hscIncrementalCompile :: Bool
                      -> Maybe TcGblEnv
                      -> Maybe Messager
                      -> HscEnv
                      -> ModSummary
                      -> SourceModified
                      -> Maybe ModIface
                      -> (Int,Int)
                      -- HomeModInfo does not contain linkable, since we haven't
                      -- code-genned yet
                      -> IO (HscStatus, HomeModInfo)
hscIncrementalCompile always_do_basic_recompilation_check m_tc_result
    mHscMessage hsc_env' mod_summary source_modified mb_old_iface mod_index
642
  = do
dterei's avatar
dterei committed
643 644
    -- One-shot mode needs a knot-tying mutable variable for interface
    -- files. See TcRnTypes.TcGblEnv.tcg_type_env_var.
645
    -- See also Note [hsc_type_env_var hack]
dterei's avatar
dterei committed
646 647
    type_env_var <- newIORef emptyNameEnv
    let mod = ms_mod mod_summary
648 649 650 651
        hsc_env | isOneShot (ghcMode (hsc_dflags hsc_env'))
                = hsc_env' { hsc_type_env_var = Just (mod, type_env_var) }
                | otherwise
                = hsc_env'
652

653 654 655 656 657 658
    -- NB: enter Hsc monad here so that we don't bail out early with
    -- -Werror on typechecker warnings; we also want to run the desugarer
    -- to get those warnings too. (But we'll always exit at that point
    -- because the desugarer runs ioMsgMaybe.)
    runHsc hsc_env $ do
    let dflags = hsc_dflags hsc_env
659

660 661 662
    e <- hscIncrementalFrontend always_do_basic_recompilation_check m_tc_result mHscMessage
            mod_summary source_modified mb_old_iface mod_index
    case e of
663 664
        -- We didn't need to do any typechecking; the old interface
        -- file on disk was good enough.
665
        Left iface -> do
666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686
            -- Knot tying!  See Note [Knot-tying typecheckIface]
            hmi <- liftIO . fixIO $ \hmi' -> do
                let hsc_env' =
                        hsc_env {
                            hsc_HPT = addToHpt (hsc_HPT hsc_env)
                                        (ms_mod_name mod_summary) hmi'
                        }
                -- NB: This result is actually not that useful
                -- in one-shot mode, since we're not going to do
                -- any further typechecking.  It's much more useful
                -- in make mode, since this HMI will go into the HPT.
                details <- genModDetails hsc_env' iface
                return HomeModInfo{
                    hm_details = details,
                    hm_iface = iface,
                    hm_linkable = Nothing }
            return (HscUpToDate, hmi)
        -- We finished type checking.  (mb_old_hash is the hash of
        -- the interface that existed on disk; it's possible we had
        -- to retypecheck but the resulting interface is exactly
        -- the same.)
687
        Right (FrontendTypecheck tc_result, mb_old_hash) -> do
Edward Z. Yang's avatar
Edward Z. Yang committed
688 689 690 691 692 693
            (status, hmi, no_change)
                <- case ms_hsc_src mod_summary of
                        HsSrcFile | hscTarget dflags /= HscNothing ->
                            finish              hsc_env mod_summary tc_result mb_old_hash
                        _ ->
                            finishTypecheckOnly hsc_env mod_summary tc_result mb_old_hash
694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709
            liftIO $ hscMaybeWriteIface dflags (hm_iface hmi) no_change mod_summary
            return (status, hmi)

-- Generates and writes out the final interface for a typecheck.
finishTypecheckOnly :: HscEnv
              -> ModSummary
              -> TcGblEnv
              -> Maybe Fingerprint
              -> Hsc (HscStatus, HomeModInfo, Bool)
finishTypecheckOnly hsc_env summary tc_result mb_old_hash = do
    let dflags = hsc_dflags hsc_env
    (iface, changed, details) <- liftIO $ hscSimpleIface hsc_env tc_result mb_old_hash
    let hsc_status =
          case (hscTarget dflags, ms_hsc_src summary) of
            (HscNothing, _) -> HscNotGeneratingCode
            (_, HsBootFile) -> HscUpdateBoot
710
            (_, HsigFile) -> HscUpdateSig
711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751
            _ -> panic "finishTypecheckOnly"
    return (hsc_status,
            HomeModInfo{ hm_details  = details,
                         hm_iface    = iface,
                         hm_linkable = Nothing },
            changed)

-- Runs the post-typechecking frontend (desugar and simplify),
-- and then generates and writes out the final interface. We want
-- to write the interface AFTER simplification so we can get
-- as up-to-date and good unfoldings and other info as possible
-- in the interface file.  This is only ever run for HsSrcFile,
-- and NOT for HscNothing.
finish :: HscEnv
       -> ModSummary
       -> TcGblEnv
       -> Maybe Fingerprint
       -> Hsc (HscStatus, HomeModInfo, Bool)
finish hsc_env summary tc_result mb_old_hash = do
    let dflags = hsc_dflags hsc_env
    MASSERT( ms_hsc_src summary == HsSrcFile )
    MASSERT( hscTarget dflags /= HscNothing )
    guts0 <- hscDesugar' (ms_location summary) tc_result
    guts <- hscSimplify' guts0
    (iface, changed, details, cgguts) <- liftIO $ hscNormalIface hsc_env guts mb_old_hash

    return (HscRecomp cgguts summary,
            HomeModInfo{ hm_details  = details,
                         hm_iface    = iface,
                         hm_linkable = Nothing },
            changed)

hscMaybeWriteIface :: DynFlags -> ModIface -> Bool -> ModSummary -> IO ()
hscMaybeWriteIface dflags iface changed summary =
    let force_write_interface = gopt Opt_WriteInterface dflags
        write_interface = case hscTarget dflags of
                            HscNothing      -> False
                            HscInterpreted  -> False
                            _               -> True
    in when (write_interface || force_write_interface) $
            hscWriteIface dflags iface changed summary
752

753 754 755 756
--------------------------------------------------------------
-- NoRecomp handlers
--------------------------------------------------------------

757
-- NB: this must be knot-tied appropriately, see hscIncrementalCompile
758 759
genModDetails :: HscEnv -> ModIface -> IO ModDetails
genModDetails hsc_env old_iface
760
  = do
dterei's avatar
dterei committed
761
    new_details <- {-# SCC "tcRnIface" #-}
762
                   initIfaceLoad hsc_env (typecheckIface old_iface)
763
    dumpIfaceStats hsc_env
dterei's avatar
dterei committed
764
    return new_details
765

766 767 768 769
--------------------------------------------------------------
-- Progress displayers.
--------------------------------------------------------------

770 771
oneShotMsg :: HscEnv -> RecompileRequired -> IO ()
oneShotMsg hsc_env recomp =
dterei's avatar
dterei committed
772
    case recomp of
773
        UpToDate ->
774 775
            compilationProgressMsg (hsc_dflags hsc_env) $
                   "compilation IS NOT required"
776
        _ ->
777 778
            return ()

779 780
batchMsg :: Messager
batchMsg hsc_env mod_index recomp mod_summary =
dterei's avatar
dterei committed
781
    case recomp of
782 783 784
        MustCompile -> showMsg "Compiling " ""
        UpToDate
            | verbosity (hsc_dflags hsc_env) >= 2 -> showMsg "Skipping  " ""
dterei's avatar
dterei committed
785
            | otherwise -> return ()
786
        RecompBecause reason -> showMsg "Compiling " (" [" ++ reason ++ "]")
dterei's avatar
dterei committed
787
    where
Ian Lynagh's avatar
Ian Lynagh committed
788
        dflags = hsc_dflags hsc_env
789
        showMsg msg reason =
Ian Lynagh's avatar
Ian Lynagh committed
790
            compilationProgressMsg dflags $
791
            (showModuleIndex mod_index ++
Ian Lynagh's avatar
Ian Lynagh committed
792
            msg ++ showModMsg dflags (hscTarget dflags)
793 794
                              (recompileRequired recomp) mod_summary)
                ++ reason
795

796 797 798
--------------------------------------------------------------
-- FrontEnds
--------------------------------------------------------------
799

800 801
-- | Given a 'ModSummary', parses and typechecks it, returning the
-- 'TcGblEnv' resulting from type-checking.
802
hscFileFrontEnd :: ModSummary -> Hsc TcGblEnv
Edward Z. Yang's avatar
Edward Z. Yang committed
803
hscFileFrontEnd mod_summary = hscTypecheck False mod_summary Nothing
804 805

--------------------------------------------------------------
806
-- Safe Haskell
807 808
--------------------------------------------------------------

809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828
-- Note [Safe Haskell Trust Check]
-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
-- Safe Haskell checks that an import is trusted according to the following
-- rules for an import of module M that resides in Package P:
--
--   * If M is recorded as Safe and all its trust dependencies are OK
--     then M is considered safe.
--   * If M is recorded as Trustworthy and P is considered trusted and
--     all M's trust dependencies are OK then M is considered safe.
--
-- By trust dependencies we mean that the check is transitive. So if
-- a module M that is Safe relies on a module N that is trustworthy,
-- importing module M will first check (according to the second case)
-- that N is trusted before checking M is trusted.
--
-- This is a minimal description, so please refer to the user guide
-- for more details. The user guide is also considered the authoritative
-- source in this matter, not the comments or code.


829 830 831
-- Note [Safe Haskell Inference]
-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
-- Safe Haskell does Safe inference on modules that don't have any specific
Gabor Greif's avatar
Gabor Greif committed
832
-- safe haskell mode flag. The basic approach to this is:
833 834 835 836 837 838 839
--   * When deciding if we need to do a Safe language check, treat
--     an unmarked module as having -XSafe mode specified.
--   * For checks, don't throw errors but return them to the caller.
--   * Caller checks if there are errors:
--     * For modules explicitly marked -XSafe, we throw the errors.
--     * For unmarked modules (inference mode), we drop the errors
--       and mark the module as being Unsafe.
840 841 842
--
-- It used to be that we only did safe inference on modules that had no Safe
-- Haskell flags, but now we perform safe inference on all modules as we want
843 844
-- to allow users to set the `-Wsafe`, `-Wunsafe` and
-- `-Wtrustworthy-safe` flags on Trustworthy and Unsafe modules so that a
845 846 847 848 849 850 851
-- user can ensure their assumptions are correct and see reasons for why a
-- module is safe or unsafe.
--
-- This is tricky as we must be careful when we should throw an error compared
-- to just warnings. For checking safe imports we manage it as two steps. First
-- we check any imports that are required to be safe, then we check all other
-- imports to see if we can infer them to be safe.
852 853 854 855 856 857 858 859 860


-- | Check that the safe imports of the module being compiled are valid.
-- If not we either issue a compilation error if the module is explicitly
-- using Safe Haskell, or mark the module as unsafe if we're in safe
-- inference mode.
hscCheckSafeImports :: TcGblEnv -> Hsc TcGblEnv
hscCheckSafeImports tcg_env = do
    dflags   <- getDynFlags
861
    tcg_env' <- checkSafeImports dflags tcg_env
862
    checkRULES dflags tcg_env'
863

dterei's avatar
dterei committed
864
  where
865 866 867 868 869 870 871 872 873 874 875 876 877 878 879
    checkRULES dflags tcg_env' = do
      case safeLanguageOn dflags of
          True -> do
              -- XSafe: we nuke user written RULES
              logWarnings $ warns dflags (tcg_rules tcg_env')
              return tcg_env' { tcg_rules = [] }
          False
                -- SafeInferred: user defined RULES, so not safe
              | safeInferOn dflags && not (null $ tcg_rules tcg_env')
              -> markUnsafeInfer tcg_env' $ warns dflags (tcg_rules tcg_env')

                -- Trustworthy OR SafeInferred: with no RULES
              | otherwise
              -> return tcg_env'

Ian Lynagh's avatar
Ian Lynagh committed
880 881 882
    warns dflags rules = listToBag $ map (warnRules dflags) rules
    warnRules dflags (L loc (HsRule n _ _ _ _ _ _)) =
        mkPlainWarnMsg dflags loc $
883
            text "Rule \"" <> ftext (snd $ unLoc n) <> text "\" ignored" $+$
dterei's avatar
dterei committed
884
            text "User defined rules are disabled under Safe Haskell"
885

886 887 888 889 890 891
-- | Validate that safe imported modules are actually safe.  For modules in the
-- HomePackage (the package the module we are compiling in resides) this just
-- involves checking its trust type is 'Safe' or 'Trustworthy'. For modules
-- that reside in another package we also must check that the external pacakge
-- is trusted. See the Note [Safe Haskell Trust Check] above for more
-- information.
892
--
893 894 895 896 897
-- The code for this is quite tricky as the whole algorithm is done in a few
-- distinct phases in